[其他] [已解决]批处理怎么实现按任意键退出，倒计时执行后面的代码？

asdfghasdfgh

怎么可以实现按任意键退出，倒计时执行后面的代码？坛子里的代码SET/P会影响后面的执行。
不用第三方命令。
1、有倒计时
2、在倒计时过程中可以按任意键退出
3、倒计时结束自动执行后面的代码
4、执行后面的代码时不再受按任意键退出的影响[]

[ 本帖最后由 asdfghasdfgh 于 2011-1-29 21:50 编辑 ]

zcydez

如果不用第三方……很难做到
至少我做不到

liion631818

给你一段本论坛的代码：

@echo off
if not "%1"=="" goto %1
del "%temp%\#" 2>nul
start /b %~fs0 :aa
:agn
set/p=按任意键退出...<nul&pause>nul
>"%temp%\#" type nul
exit
:aa
for /l %%a in (10 -1 1) do (
   title 倒计时 %%a 秒后自动退出...
   if exist "%temp%\#" (
      del "%temp%\#"
      exit
   )
   ping -n 2 127.1>nul
)
title 自动退出...
for /f "tokens=2" %%a in ('tasklist /fi "windowtitle eq 自动退出..." /nh') do (
   taskkill /f /pid %%a >nul
)
exit
复制代码

原帖http://www.bathome.net/redirect. ... amp;goto=nextnewset

asdfghasdfgh

原帖由 liion631818 于 2011-1-25 17:06 发表
给你一段本论坛的代码：@echo off
if not "%1"=="" goto %1
del "%temp%\#" 2>nul
start /b %~fs0 :aa
:agn
set/p=按任意键退出...nul
>"%temp%\#" type nul
exit
:aa
for /l %%a in (10 -1 1) do (
   ti ...

此代码用的SET/P，如果倒计时不是退出而是执行后面的代码，会出问题！

tmplinshi

@echo off
if "%~1"=="按任意键退出" goto :%1

>"%temp%\.sub" cd.
start "" /b %0 按任意键退出
set 退格键=

for /l %%a in (10 -1 1) do (
    set /p =%退格键%%%a 秒后开始备份文件... [按任意键退出] <nul
    if not exist "%temp%\.sub" exit
    ping -n 2 127.1 >nul
)

echo,
echo 备份完成。

echo 按任意键退出...
exit

:按任意键退出
pause >nul
del "%temp%\.sub"
exit
复制代码

[ 本帖最后由 tmplinshi 于 2011-1-26 21:03 编辑 ]

liion631818

原帖由 tmplinshi 于 2011-1-26 01:34 发表
@echo off
if "%~1"=="按任意键退出" goto :%1

>"%temp%\.sub" cd.
start "" /b %0 按任意键退出
set 退格键=

for /l %%a in (10 -1 1) do (
    set /p =%退格 ...

厉害，这段代码确实好用，以前都没想到，学习了~~

asdfghasdfgh

原帖由 tmplinshi 于 2011-1-26 01:34 发表
@echo off
if "%~1"=="按任意键退出" goto :%1

>"%temp%\.sub" cd.
start "" /b %0 按任意键退出
set 退格键=

for /l %%a in (10 -1 1) do (
    set /p =%退格 ...

这个代码执行完了必须要按一下任意键才能退出，可否直接就退出呢？

Batcher

顶楼不是说要实现按任意键退出吗，怎么现在又变了？

asdfghasdfgh

原帖由 Batcher 于 2011-1-26 12:53 发表
顶楼不是说要实现按任意键退出吗，怎么现在又变了？

没有变，我再叙述一遍：
1、有倒计时
2、在倒计时过程中可以按任意键退出
3、倒计时结束自动执行后面的代码
4、执行后面的代码时不再受按任意键退出的影响

谢谢，可能是之前没表诉清楚。

asdfghasdfgh

自己顶一下 求解！！

Batcher

那就在顶楼重新表述一下吧

tmplinshi

@echo off
if "%~1"=="按任意键退出" goto :%1

>"%temp%\.sub" cd.
start "" /b %0 按任意键退出
set 退格键=

for /l %%a in (10 -1 1) do (
    set /p =%退格键%%%a 秒后开始备份文件... [按任意键退出] <nul
    if not exist "%temp%\.sub" exit
    ping -n 2 127.1 >nul
)

echo,
echo 备份完成。

del "%temp%\.sub"
title 正在退出...
taskkill /im cmd.exe /fi "windowtitle eq 正在退出..."

:按任意键退出
pause >nul
del "%temp%\.sub"
exit
复制代码

[ 本帖最后由 tmplinshi 于 2011-1-26 20:29 编辑 ]

wc726842270

版主的退格符用的真是巧秒啊,学习了

acaigg

学习一下，顶一下，增加人气。

asdfghasdfgh

自己对代码的不熟悉，其实在大家的帮助下问题早就解决，谢谢各位！