[日期时间] 批处理怎样输出两个指定日期之间的所有日期？

DAIC

开始日期：1810-01-01
结束日期：2010-01-01
希望得到的结果（总共73050行）：
1810-01-01
1810-01-02
1810-01-03
...
2010-01-01

15楼的结果：
c:\Test>timeit test.bat
Elapsed Time:     0:00:34.590
Process Time:     0:00:23.212

28楼的结果：
c:\Test>timeit test.bat
Elapsed Time:     0:00:19.345
Process Time:     0:00:11.778

mxxcgzxxx

参考:http://bbs.bathome.net/thread-12558-1-1.html
可以把日期看成一个大数18990101~19990101之间的数去较对正误就行了!
一个FOR+一个CALL把他们的程序拿来就行了呵

batman

直接输出还是不要用call，call太影响效率了。。。

mxxcgzxxx

@echo off
set 正模式=
set "正模式=%正模式% ^[1-2][0-9][0-9][0-9]0[1-9]0[1-9]$"
set "正模式=%正模式% ^[1-2][0-9][0-9][0-9]0[1-9]1[0-9]$"
set "正模式=%正模式% ^[1-2][0-9][0-9][0-9]0[^02]2[0-9]$"
set "正模式=%正模式% ^[1-2][0-9][0-9][0-9]022[0-8]$"
set "正模式=%正模式% ^[1-2][0-9][0-9][0-9]0[13578]3[0-1]$"
set "正模式=%正模式% ^[1-2][0-9][0-9][0-9]0[469]30$"
set "正模式=%正模式% ^[1-2][0-9][0-9][0-9]1[0-2]0[1-9]$"
set "正模式=%正模式% ^[1-2][0-9][0-9][0-9]1[0-2][12][0-9]$"
set "正模式=%正模式% ^[1-2][0-9][0-9][0-9]1[02]3[0-1]$"
set "正模式=%正模式% ^[1-2][0-9][0-9][0-9]1130$"
set "正模式=%正模式% ^[1-2][0-9][13579][26]0229$"
set "正模式=%正模式% ^[1-2][0-9][2468][048]0229$"
set "正模式=%正模式% ^[1-2][0-9][02468][48]0229$"
set "正模式=%正模式% ^[02468][048]000229$"
set "正模式=%正模式% ^[13579][26]000229$"
 
 
:loop
set /p 开始日期=按yyyymmdd格式输入开始日期:
echo.%开始日期%|findstr "%正模式%">nul && set "a=%开始日期%" || goto :loop
:loop1
set /p 结束日期=按yyyymmdd格式输入结束日期:
echo.%开始日期%|findstr "%正模式%">nul && cls || goto :loop1
if %结束日期% lss %开始日期% echo 结束日期小于开始日期! & goto:loop1
 
:1
if %a:~4,2%==13 set /a a=a/10000*10000+9999 
if %a:~6,2%==32 set /a a=a/100*100+99
echo.%a%|findstr "%正模式%">nul && echo %a% 
if %a%==%结束日期% goto :2
set /a a+=1        
goto :1
:2
pause>nul
goto :loopCOPY

CrLf

@echo off & setlocal enabledelayedexpansion

set 正模式=
set "正模式=%正模式% ^[1-2][0-9][0-9][0-9]0[1-9]0[1-9]$"
set "正模式=%正模式% ^[1-2][0-9][0-9][0-9]0[1-9]1[0-9]$"
set "正模式=%正模式% ^[1 ...
mxxcgzxxx 发表于 2011-6-4 11:21

提示一下，可以这样输出：

(@for /l %%a in (start 1 end) do @echo %%a)|findstr "正则"COPY

如果日期很多的话，这应该是效率最高的办法了
另一种思路是也许可以用for /l嵌套，采用年循环、月循环、日循环的方式一次性输出正确日期，日期比较少时应该野不慢

mxxcgzxxx

我没采用FOR是因为13~99月那里很浪费时间，现在改了下取消了变量延时开关会更快点吧

DAIC

4# mxxcgzxxx


这个代码运行了六七分钟，才刚刚跑到1926年，怎样才能提高速度呢？

namejm

看看这个帖子：
按日期早晚顺序列出指定范围内的所有日期
http://bbs.bathome.net/viewthread.php?tid=7526

CrLf

这个非常快

@echo off
(cmd /q /v:on /c "for /l %%a in (1990 1 2012) do (for /l %%b in (1 1 12) do (for /l %%c in (1 1 31) do ((set "m=10%%b"&set "d=10%%c")&echo %%a!m:~-2!!d:~-2!)))")|findstr /ve "0[2469]31 0230 1131 [02468][048]0229 [13579][26]0229 [02468][048]000229 [13579][26]000229"
pauseCOPY

为了省些代码只好弄成这个样子了...易读性不是很强，但是思路其实很简单，就是先输出所有有可能合法的日期，再用findstr排除不合法日期...

DAIC

8# namejm


http://bbs.bathome.net/viewthrea ... muid=38107#pid49141
这个代码看不懂，能否教一下怎么设置开始日期和结束日期？

DAIC

9# zm900612


有问题：
19000228
19000230
19000301

CrLf

漏了排除2月30，已修正

batman

9# zm900612
写个setlocal enabledelayedexpansion就这么难？非要用cmd /vn，效率我想前者还是要快一点点点吧。。。

20000229非法，哈哈。。。

CrLf

13# batman


通道之前存在语块时，语块中的内容相当于直接输入到cmd窗口中运行，此时变量延迟是没有效果的，若要用!str!这样的变量，唯有使用cmd /vn来作为语块执行的媒介，而cmd /c是以参数的形式接收要执行的内容，所以无法换行...

整百年份有判断，不过逻辑错误，好像判断反了

batman

老实人做老实事：

@echo off&setlocal enabledelayedexpansion
echo,&set /p start=请输入开始日期（形如2000-03-21）：
echo,&set /p end=请输入结束日期（形如2000-03-21）：
cls&echo,&echo,&echo,&echo,&echo         程序正在运行中，请稍候。。。
set /a sy=%start:~,4%,sm=1%start:~5,2%%%100,sd=1%start:~8,2%%%100,ey=%end:~,4%,em=1%end:~5,2%%%100,ed=1%end:~8,2%%%100,a=31
for %%a in (1 3 5 7 8 10 12 4 6 9 11) do (
  if %%a equ 4 set /a a-=1
  set /a _%%a=a
)
(for /l %%a in (%sy%,1,%ey%) do (
  set /a "_2=^!(%%a%%4)&^!(^!(%%a%%100))|^!(%%a%%400)+28"
  set /a a=1,b=12
  if "%%a" equ "%sy%" set /a a=sm
  if "%%a" equ "%ey%" set /a b=em
  for /l %%b in (!a!,1,!b!) do (
    set /a c=1,d=_%%b
    if "%%a%%b" equ "%sy%%sm%" set /a c=sd
    if "%%a%%b" equ "%ey%%em%" set /a d=ed
    for /l %%c in (!c!,1,!d!) do (
      for %%d in (%%b %%c) do set ".%%d=0%%d"&set ".%%d=!.%%d:~-2!"
      echo %%a-!.%%b!-!.%%c!
    )
  )
))>list.txt
start list.txt      COPY