[数值计算] [讨论]批处理set /a语句报错“此时不应有……”的原因?

mxxcgzxxx

set /a 进行数值计算是一个非常实用的指令,特别在FOR内可以不用开启变量延时非常强大

set a=0
set b=0
for /l %%1 in (1,1,5) do set /a a=((b+=a)+%%1)*5 &set /a a+=1 
echo %a% %b%
pause>nul
复制代码

从上面这几句中就可以看出set /a的强大
但是在相同效果的另一句中却出现了异外!
执行下面这段代码!问题出现了!为什么?

set a=0
set b=0
for /l %%1 in (1,1,5) do (
        set /a a=((b+=a)+%%1)*5 
        set /a a+=1
        ) 
echo %a% %b%
pause>nul
复制代码

提示:此处不应有 +%1)*5
是因为+%1的问题吗?

set a=0
set b=0
for /l %%1 in (1,1,5) do (
        set /a a=((b+=a)+a)*5 
        set /a a+=1
        ) 
echo %a% %b%
pause>nul
复制代码

结果还是:此处不应有 +a)*5
再改:

set a=0
set b=0
for /l %%1 in (1,1,5) do (
        set /a a=((b+=a^)+%%1^)*5 
        set /a a+=1
        ) 
echo %a% %b%
pause>nul
复制代码

通过!原来是后)要转义,
改成  set/a "a=((b+=a)+%%1)*5"  也通过!
那么是FOR闯的祸吗?

set a=0
set b=0
(
set /a a=((b+=a)+a)*5 
set /a a+=1
) 
echo %a% %b%
pause>nul
复制代码

结果还是一样!
那么为什么转入字块后 SET /A 就出错呢?
大家一起来说说!

mxxcgzxxx

我想是不是因为第一个")"与字块的"("进行了匹配所以出错了?
有没有相关的教程说明?
特别做了一个测试:

@echo off
set a=1
set b=1
for /l %%1 in (1,1,5) do (
      echo %a% %b%
      set /a a=(b+=a) 
      set /a a+=1
      echo %a% %b%
      ) 

pause>nul
复制代码

虽然一直提示:括弧不对称,却正确执行了
从结果可以看出,确实是与字块的"("进行了匹配!


前一个 echo %a% %b% 由于没开变量延时所以只显示1
而后一个echo %a% %b% 是在字块外了,显示了正确值,而且只运行了一次不在循环内!

applba

是不是第二个等号引起的

mxxcgzxxx

是不是第二个等号引起的
applba 发表于 2011-6-10 16:34

@echo off
set a=1
set b=1
for /l %%1 in (1,1,5) do (
      echo %a% %b%
      set /a a=((b+a)+a)*5 
      set /a a+=1
      echo %a% %b%
      ) 

pause>nul
复制代码

依然出错:此处不应有 +a)*5

Demon

set /a中的括号跟前面的括号配对了。