本帖最后由 CrLf 于 2011-9-2 18:43 编辑
很有意思，我试试：- @echo off&setlocal enabledelayedexpansion
- for %%a in (米线 卷粉 面条 饵丝 饺子) do (
- set /a a+=1
- set a!a!=%%a
- )
- ::主食
- set b=@小中大
- ::份量
- for %%a in (杂酱 焖肉 牛肉 猪脚 三鲜) do (
- set /a c+=1
- set c!c!=%%a
- )
- ::配料
-
- set -=------------------------------------------------------------------------------
- for /l %%a in () do (
- setlocal&echo;&echo !-:~-35! 菜 单 !-:~-35!
- for /l %%a in (1 1 23) do set k= !k!
- for /f %%a in ('findstr /b "[0-9][0-9][0-9]=" %0') do (
- set J%%a
- for /f "delims==" %%b in ("%%a") do (
- set @=%%b
- for /f "tokens=1-3" %%c in ("!@:~,1! !@:~1,1! !@:~2,1!") do (
- if %%c neq !last! (
- if defined echo echo !echo!
- echo !-!
- for %%f in (tn echo) do set %%f=
- set last=%%c
- )
- set /a tn+=1,t=tn%%2
- set na=%%b:!c%%e!!a%%c!（!b:~%%d,1!）!k!
- set mo=!k:~-8!!J%%b:~,-1!.!J%%b:~-1! 元
- set echo=!echo! !na:~,15!!mo:~-7!
- if !t!==0 echo !echo!&set echo=
- )
- )
- )
- echo !-!
- rem 输出菜单
-
- echo;
- set /p in=请输入菜单：（可以同时多选）^
-
-
- echo;
- for %%b in (!in!) do (
- if defined J%%b (
- set @=%%b
- for /f "tokens=1-3" %%c in ("!@:~,1! !@:~1,1! !@:~2,1!") do (
- set na=%%b:!c%%e!!a%%c!（!b:~%%d,1!）!k!
- set mo=!k:~-8!!J%%b:~,-1!.!J%%b:~-1! 元
- echo !na:~,20!!mo:~-7!
- set /a $+=!J%%b!
- )
- ) else echo %%b: [无此条目]
- )
- if defined @ (
- echo;
- set $=!k!!$:~,-1!.!$:~-1! 元
- echo !k![总价：!$:~-6!]!k:~-14!!date! !time!
- )
- pause>nul
- for /l %%a in (1 1 4) do echo;
- endlocal
- )
- ::菜单输入、计算和输出
-
- ::以下为菜目编号与价格（以角为单位，方便计算）
- 111=35
- 112=40
- 113=40
- 114=40
- 115=35
-
- 211=35
- 212=40
- 213=40
- 214=40
- 215=35
-
- 311=40
- 312=45
- 313=45
- 314=45
- 315=40
-
- 411=40
- 412=45
- 413=45
- 414=45
- 415=40
-
- 511=45
- 512=45
- 513=45
效果如下：- -------------------------------- 菜 单 --------------------------------------
- ------------------------------------------------------------------------------
- 111:杂酱米线（小） 3.5 元 112:焖肉米线（小） 4.0 元
- 113:牛肉米线（小） 4.0 元 114:猪脚米线（小） 4.0 元
- 115:三鲜米线（小） 3.5 元
- ------------------------------------------------------------------------------
- 211:杂酱卷粉（小） 3.5 元 212:焖肉卷粉（小） 4.0 元
- 213:牛肉卷粉（小） 4.0 元 214:猪脚卷粉（小） 4.0 元
- 215:三鲜卷粉（小） 3.5 元
- ------------------------------------------------------------------------------
- 311:杂酱面条（小） 4.0 元 312:焖肉面条（小） 4.5 元
- 313:牛肉面条（小） 4.5 元 314:猪脚面条（小） 4.5 元
- 315:三鲜面条（小） 4.0 元
- ------------------------------------------------------------------------------
- 411:杂酱饵丝（小） 4.0 元 412:焖肉饵丝（小） 4.5 元
- 413:牛肉饵丝（小） 4.5 元 414:猪脚饵丝（小） 4.5 元
- 415:三鲜饵丝（小） 4.0 元
- ------------------------------------------------------------------------------
- 511:杂酱饺子（小） 4.5 元 512:焖肉饺子（小） 4.5 元
- ------------------------------------------------------------------------------
-
- 请输入菜单：（可以同时多选）
- 112 122 313 214 512 415
-
- 112:焖肉米线（小） 4.0 元
- 122: [无此条目]
- 313:牛肉面条（小） 4.5 元
- 214:猪脚卷粉（小） 4.0 元
- 512:焖肉饺子（小） 4.5 元
- 415:三鲜饵丝（小） 4.0 元
-
- [总价：21.0 元] 2011/09/01 周四 23:11:31.32
| 
发表于 2011-9-1 16:10
| 
发表于 2011-9-1 17:56
| 