[分享]根据网上文章做了个修改Win7登陆界面背景图的批处理

MantisLin · 发表于 2011-9-7 16:28:22

根据文章 http://liangruijun.blog.51cto.com/3061169/634917 做了个批处理
发出来，大家看看有什么可改进的地方

rem 将与此批处理同目录下的 backgroundDefault.jpg
rem 文件设置成为Win7登陆界面的背景图
rem 本在于Win7下测试通过，当然，只适用于Win7
echo off & cls
SETLOCAL ENABLEDELAYEDEXPANSION
set "JPGNAME=backgroundDefault.jpg"
set "MAXSIZE=250"
set "JPGPATH=%windir%\System32\oobe\info\backgrounds"
set "num=0"
rem 检测文件是否存在
echo.
if not exist "%JPGNAME%". (
echo.　设置用的JPG文件不存在，无法设置，按任意键退出！
goto :thend
) else (
echo.　已找到 JPG 文件：%JPGNAME%！
)
rem 检测文件大小
echo.
for /f "tokens=3,4 delims= " %%a in ('dir "%~sdp0%JPGNAME%"') do (
if "%%b" equ "%JPGNAME%" (
for /f "tokens=1,2 delims=," %%c in ("%%a") do (
set /a num=%%c * 1000 + %%d
set /a num=!num! / 1024
set /a abc=%MAXSIZE% - 1
if !num! geq !abc! (
echo.　文件超过 %MAXSIZE% KB！不能设置，按任意键退出！
goto :thend
) else (
echo.　文件不超过 %MAXSIZE% KB！符合要求，可以设置！
)
)
)
)
rem 修改注册表
echo.
call :setReg
rem 建立文件夹
echo.
if not exist "%JPGPATH%". (
echo.　backgrounds 文件夹不存在，正在建立……
md "%JPGPATH%"
if errorlevel 0 (
echo.　建立 backgrounds 文件夹成功！
) else (
echo.　建立 backgrounds 文件夹失败！
call :setRegBack
echo.　已还原注册表设置！按任意键退出！
goto :thend
)
)
echo.　欲设置的文件夹确认完成！
rem 复制文件
echo.
for /f "tokens=2 delims= " %%a in ('copy /y "%~sdp0%JPGNAME%" "%JPGPATH%"') do (
if not %%a equ 0 (
echo.　%JPGNAME% 复制成功！
) else (
echo.　%JPGNAME% 复制失败！
call :setRegBack
goto :thend
)
)
echo.
echo.　完成设置，按任意键退出！
:thend
ENDLOCAL
pause >nul
exit/b
:setReg
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\LogonUI\Background" /v "OEMBackground" /t REG_DWORD /d 1 /f >nul 2>nul
if errorlevel 0 (
echo.　注册表修改成功！
) else (
echo.　注册表修改失败！
)
goto :EOF
:setRegBack
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Authentication\LogonUI\Background" /v "OEMBackground" /t REG_DWORD /d 0 /f >nul 2>nul
if errorlevel 0 (
echo.　已还原注册表设置！按任意键退出！
) else (
echo.　无法还原注册表设置！按任意键退出！
)
goto :EOF

复制代码

JooKin · 发表于 2011-9-7 17:40:39

感觉有一些地方可以简化：
1、13到18行可以这样，类似的地方也都可以这样
if not exist "%JPGNAME%" goto :thend
echo.　已找到 JPG 文件：%JPGNAME%！
2、24到26行的set/a可以连续赋值
3、setReg和setRegBack可以合并，然后用call带进参数

MantisLin · 发表于 2011-9-10 17:03:29

回复 2# JooKin
谢谢你的宝贵意见，不过关于第二点，简化那几个 "set /a" ，这个我感觉有难度（可能是基础没学好），能否请你帮我简化一下，把这几行简化后的代码帖出来？

Batcher · 发表于 2011-9-10 19:26:45

回复 3# MantisLin

试试这样行不行：

set /a num=(%%c*1000+%%d)/1024, abc=MAXSIZE-1

复制代码

MantisLin · 发表于 2011-9-13 09:35:43

本帖最后由 MantisLin 于 2011-9-13 09:37 编辑

回复 4# Batcher

　　你好，Batcher，根据你的代码试了一下，结果输出错误提示

此时不应有 /1024。

复制代码

不好意思这几天忙着过中秋没看论坛，回答得久了点

CrLf · 发表于 2011-9-13 11:13:55

回复 5# MantisLin

把每条算式各自加上双引号，或者直接用转义符将括号转义即可

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[系统相关] [分享]根据网上文章做了个修改Win7登陆界面背景图的批处理

评分

评分

评分