批处理无3方显示“打开文件对话框”

raymai97 · 发表于 2011-11-15 23:42:20

特点：NO临时文件，只一个批处理文件，HTA+BAT集于一身
原理：调用mshta打开自己，并把结果通过注册项反馈给批处理，批处理检测后会删除注册项

不多说，代码上：

@echo off
goto a
<html>
<body>
<input type='file' id='f' />
<script type='text/javascript'>
var f = document.getElementById('f');
f.click();
var shell = new ActiveXObject('WScript.Shell');
shell.RegWrite('HKEY_CURRENT_USER\\Volatile Environment\\msg', f.value);
window.close();
</script>
</body>
</html>
:a
set -reg=reg delete "HKCU\Volatile Environment" /v "msg" /f
echo,任意键选择文件
echo,
pause>nul
%-reg%>nul 2>nul
mshta "%~dpnx0"
for /f "tokens=2*" %%i in ('reg query "HKCU\Volatile Environment" /v "msg"') do (
set fname=%%j
)
::不能if x==x (x) else (y)，否则选择有括号的文件时就会KO
if "%fname%"=="" echo,你没有选择文件
if not "%fname%"=="" echo,你选择了%fname%。
%-reg%>nul 2>nul
echo,
pause>nul

复制代码

920168 · 发表于 2011-11-16 09:09:10

特来支持！！

garyng · 发表于 2011-11-16 09:55:03

还是一句：RayMai究竟是RayMai啊！

收藏了。。

是HTML+BAT吧？

raymai97 · 发表于 2011-11-16 11:57:17

回复 3# garyng

hta来的，改成html就不能写入注册表了

garyng · 发表于 2011-11-16 12:09:50

回复 4# raymai97

哦哦～
我对这东不解啊。。。

defanive · 发表于 2011-11-16 13:10:17

@echo off
for /f %%a in ('^(type "%~f0"^&echo;x^)^|find /c /v ""') do set "nLine=%%a"
setlocal enabledelayedexpansion
(for /l %%a in (2,1,%nLine%) do set /p Line_%%a=&set "Exec=!Exec!&echo;^!Line_%%a^!")<"%~f0"
:loop
>"%~f0" (type nul%Exec%)
mshta vbscript:execute("set oDlg=CreateObject(""MSComDlg.CommonDialog""):oDlg.MaxFileSize=260:oDlg.Flags=4:oDlg.Action=1:CreateObject(""Scripting.FileSystemObject"").OpenTextFile(""%~f0"",8).Write(""_""&oDlg.FileName):self.close")
<"%~f0" (for /l %%a in (1,1,%nLine%) do set /p Data=)
echo File Path: %Data:~1%
pause
goto :loop
::Data

复制代码

稍微写了一段，批处理自身应该不算临时文件吧，

canyuexiaolang · 发表于 2011-11-16 13:10:26

win2003.....有点慢...该机子事？

defanive · 发表于 2011-11-16 13:12:02

6L的代码基于清除批处理自身最后一行的研究成果，将批处理自己作为临时文件使用

raymai97 · 发表于 2011-11-16 13:37:33

回复 8# defanive

defanive你是用xp吧？commondialog我不是没有试过，在win7下不行啊~

raymai97 · 发表于 2011-11-16 13:38:35

回复 7# canyuexiaolang

这个会调用到ie的东西，所以会比较慢~

defanive · 发表于 2011-11-16 23:19:56

回复 9# raymai97
Win7…回去改一下换成html控件执行好了

xj7199 · 发表于 2011-11-17 12:28:43

支持大大，能不能写一个保存的文件对话框呀。

cjiabing · 发表于 2011-11-17 14:07:42

有创意，不过有个问题必须解决，就是如何把结果传回批处理，而不显示那些多余的东西？

任意键选择文件

错误: 系统找不到指定的注册表项或值
你没有选择文件

cjiabing · 发表于 2011-11-17 14:07:49

有创意，不过有个问题必须解决，就是如何把结果传回批处理，而不显示那些多余的东西？

任意键选择文件

错误: 系统找不到指定的注册表项或值
你没有选择文件

cjiabing · 发表于 2011-11-17 16:08:11

复制代码

没学过JS，搞了蛮久，还是不得。不懂如何document.write输出到文本。

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

[文件管理] 批处理无3方显示“打开文件对话框”