caruko

仔细看了下netbenton的代码，对五子棋规则了解很深，大大节省了代码提升了效率。
而且很多地方的字符串设计的很巧妙，集判断处理多种结果于一身。

最近我重新改写了五子棋核心代码，使用了别的算法；
返回最高评分坐标集合，判断棋型禁手布局，计算时间大约0.5-1秒，只是如果要完成计算3步棋，时间花费可能达到10秒，当然保存几个计算的走子结果，在电脑“意料中”的走棋将直接读取或者从布局查找，估计电脑“思考”时间将1-10秒不等。

只是我写的代码都有点其它语言的遗留传统，在BAT本身特性的了解方面，还差很远啊。

BillGates

嘻嘻，准确的说是蜂鸣器啦，别让蜂鸣器发出滴滴滴的声音，你那个五子棋哦，下一个子，会滴一声，我觉得这个似乎没必要吧。嘎嘎。

caruko

最近改写的程序如下，并没有多少特征字串，完全使用算法思考。
已经用它执白跟netbenton兄的程序对弈过，走了3次，都是20-30多步后不小心下错坐标罢手了，但至少一直防守没有错漏。

当前只有核心代码，很粗糙，界面，悔棋等都没有做，很多都处在调试阶段，但是已经可以下棋了。

以后将会更新：
1，动态调整k1,k2值，使得电脑在判断当前局面后不至于一味防守或者进攻，只是判断标准目前还没确定，简单的以当前最高得分的落子点分值判断，还是以 “二，三，四”的数量综合评分来判断。
2，禁手，查找分值串，可以很容易判断 多行交叉的禁手，只是长连禁手还得考虑下是否放入特征串。
3，开局棋谱，目前没有加入，所以测试都是用电脑做后手。如果要电脑先手，调整为k1=10,k2=7。
4，走棋预判，以目前的计算速度看，每一步评分的时间为0.5秒，那么考虑3步需要大量时间。代码框架已经完备，以后试着添加这个功能。
5，胜负判断还没做=。=

@echo off
setlocal enabledelayedexpansion
set "tzk=11111_9999999 011110_300000 11110_2500 01111_2500 11101_3000 10111_3000 11011_2600 0011100_3000 11100_500 00111_500 010110_800 011010_800 10011_600 11001_600 10101_550 00011000_650 11000_150 00011_150 0010100_250 010010_200"
set "p_tzk=22222_9999999 022220_300000 22220_2500 02222_2500 22202_3000 20222_3000 22022_2600 0022200_3000 22200_500 00222_500 020220_800 022020_800 20022_600 22002_600 20202_550 00022000_650 22000_250 00022_250 0020200_250 020020_200"
rem 默认走白棋,k1<k2侧重防守（后手），k1>k2侧重进攻（先手）。k1,k2值可在判断双方局面评分后动态调整。
set /a k1=7,k2=10
set error1=坐标应为“x,y”形式，并且1-x-15,1-y-15。
set error2=x,y坐标越界。
set error3=该坐标已有棋子，无法在指定坐标下子。
:初始化棋盘
for /l %%i in (1 1 15) do (
        set "Display_%%i=┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼"
)
for /l %%i in (1 1 15) do for /l %%j in (1 1 15) do set QP[%%i][%%j]=0

:loop
call :显示棋盘
call :玩家走 ||(echo,!error%ERRORLEVEL%!&goto :loop)
call :显示棋盘
call :判断胜负
call :电脑走
call :显示棋盘
call :判断胜负
goto :loop
:玩家走
set /a zq=0
set /p P_zb=请输入坐标{1-15,1-15}:
for /f "tokens=1,2 delims=," %%a in ("!P_zb!") do (
        if %%a GTR 0 if %%a LSS 16 set /a zq+=1
        if %%b GTR 0 if %%b LSS 16 set /a zq+=1
        if "!QP[%%a][%%b]!"=="0" set /a zq+=1
        if "!zq!"=="3" call :设置坐标 %%a %%b 2
)
if "!P_zb!"=="exit" exit
if !zq! EQU 0 exit /b 1
if !zq! EQU 1 exit /b 2
if !zq! EQU 2 exit /b 3
exit /b 0
goto :eof

:电脑走
set /a 最高分=0
for /l %%x in (1 1 15)  do (
        for /l %%y in (1 1 15) do (
                if defined C_soce[%%x][%%y] (
                        set "m=!C_soce[%%x][%%y]!"
                        set "n=!P_soce[%%x][%%y]!"
                        set /a m=!m!,n=!n!,mn=m*!k1!+n*!k2!
                        if !最高分! EQU !mn! set "坐标集=!坐标集! [%%x][%%y]"
                        if !最高分! LSS !mn! (
                                set /a 最高分=!mn!
                                set "坐标集=[%%x][%%y]"
                        )
                )
        )
)
rem 坐标集可能含有多个坐标，以后应用在αβ剪枝算法中，现在只取第一个。
for /f "tokens=1,2 delims=[]" %%i in ("!坐标集!") do (
        call :设置坐标 %%i %%j 1
)        
goto :eof

:判断胜负
rem 还没做。
goto :eof
:显示棋盘
for /l %%i in (15 -1 1) do (
        echo,%%i !Display_%%i!
)
echo,Y↑X→ 1 2 3 4 5 6 7 8 9 0 1 2 3 4 5
goto :eof


:设置坐标 [X为90°，Y为0°，Y-X为45°，Y+X为135°]
set /a QP[%1][%2]=%3,x=%1,y=%2,z=%3,cut1=x-1,cut2=x,最高分=0
if !z! equ 1 (set "cr=●") else (set "cr=○")
set "str1=!Display_%y%:~0,%cut1%!"
set "str2=!Display_%y%:~%cut2%!"
set "Display_!y!=!str1!!cr!!str2!"
set "C_str[%1][%2]="
set "C_soce[%1][%2]="
set "P_soce[%1][%2]="
set "P_str[%1][%2]="

::落子点估值
for /l %%i in (1 1 4) do (
        for %%j in (%%i_0 %%i_-%%i 0_-%%i -%%i_-%%i -%%i_+0 -%%i_+%%i 0_%%i %%i_%%i) do (
                for /f "tokens=1,2 delims=_" %%x in ("%%j") do (
                        set /a xx=x+%%x,yy=y+%%y
                        for /f "tokens=1,2" %%a in ("!xx! !yy!") do (
                                if defined QP[%%a][%%b] if !QP[%%a][%%b]! EQU 0 (

rem 更新双方字串并评分，没有的则重新创建，只更新 x-4 => x+4 范围且在一条直线上的评分。
set /a a=%%a,b=%%b,c=1
if "!C_str[%%a][%%b]!"=="" (
        set /a c_str1=c,c_str2=c,c_str3=c,c_str4=c,p_str1=2,p_str2=2,p_str3=2,p_str4=2
        for /l %%I in (-1 -1 -4) do (
                set /a xxx=a+%%I,yyy=b+%%I,lj1=0
                if !xxx! LSS 1 (
                        set /a lj1=1
                        set "c_str1=x!c_str1!"
                        set "p_str1=x!p_str1!"
                ) else (
                        for /f "tokens=1,2" %%A in ("!xxx! !b!") do (
                                set "c_str1=!QP[%%A][%%B]!!c_str1!"
                                set "p_str1=!QP[%%A][%%B]!!p_str1!"
                        )
                )
                if !yyy! LSS 1 (
                        set /a lj1=1
                        set "c_str2=x!c_str2!"
                        set "p_str2=x!p_str2!"
                ) else (
                        for /f "tokens=1,2" %%A in ("!a! !yyy!") do (
                                set "c_str2=!QP[%%A][%%B]!!c_str2!"
                                set "p_str2=!QP[%%A][%%B]!!p_str2!"
                        )
                )
                if !lj1! EQU 1 (
                        set "c_str3=x!c_str3!"
                        set "p_str3=x!p_str3!"
                ) else (
                        for /f "tokens=1,2" %%A in ("!xxx! !yyy!") do (
                                set "c_str3=!QP[%%A][%%B]!!c_str3!"
                                set "p_str3=!QP[%%A][%%B]!!p_str3!"
                        )
                )
                set /a xxx=a+%%I,yyy=b-%%I,lj1=0
                if !xxx! LSS 1 set /a lj1=1
                if !yyy! GTR 15 set /a lj1=1
                if !lj1! EQU 1 (
                        set "c_str4=x!c_str4!"
                        set "p_str4=x!p_str4!"
                ) else (
                        for /f "tokens=1,2" %%A in ("!xxx! !yyy!") do (
                                set "c_str4=!QP[%%A][%%B]!!c_str4!"
                                set "p_str4=!QP[%%A][%%B]!!p_str4!"
                        )
                )
        )
        for /l %%I in (1 1 4) do (
                set /a xxx=a+%%I,yyy=b+%%I,lj1=0
                if !xxx! GTR 15 (
                        set /a lj1=1
                        set "c_str1=!c_str1!x"
                        set "p_str1=!p_str1!x"
                ) else (
                        for /f "tokens=1,2" %%A in ("!xxx! !b!") do (
                                set "c_str1=!c_str1!!QP[%%A][%%B]!"
                                set "p_str1=!p_str1!!QP[%%A][%%B]!"
                        )
                )
                if !yyy! GTR 15 (
                        set /a lj1=1
                        set "c_str2=!c_str2!x"
                        set "p_str2=!p_str2!x"
                ) else (
                        for /f "tokens=1,2" %%A in ("!a! !yyy!") do (
                                set "c_str2=!c_str2!!QP[%%A][%%B]!"
                                set "p_str2=!p_str2!!QP[%%A][%%B]!"
                        )
                )
                if !lj1! EQU 1 (
                        set "c_str3=!c_str3!x"
                        set "p_str3=!p_str3!x"
                ) else (
                        for /f "tokens=1,2" %%A in ("!xxx! !yyy!") do (
                                set "c_str3=!c_str3!!QP[%%A][%%B]!"
                                set "p_str3=!p_str3!!QP[%%A][%%B]!"
                        )
                )
                set /a xxx=a+%%I,yyy=b-%%I,lj1=0
                if !xxx! GTR 15 set /a lj1=1
                if !yyy! LSS 1 set /a lj1=1
                if !lj1! EQU 1 (
                        set "c_str4=!c_str4!x"
                        set "p_str4=!p_str4!x"
                ) else (
                        for /f "tokens=1,2" %%A in ("!xxx! !yyy!") do (
                                set "c_str4=!c_str4!!QP[%%A][%%B]!"
                                set "p_str4=!p_str4!!QP[%%A][%%B]!"
                        )
                )
        )
        set /a soce1=0,soce2=0,soce3=0,soce4=0
        for %%X in (!tzk!) do (
                for /f "tokens=1,2 delims=_" %%A in ("%%X") do (
                        for /l %%W in (1 1 4) do (
                                if not "!c_str%%W!"=="!c_str%%W:%%A=@!" if !soce%%W! LSS %%B set /a soce%%W=%%B
                        )
                )
        )
        set "C_str[!a!][!b!]=!c_str1!,!c_str2!,!c_str3!,!c_str4!"
        set "C_soce[!a!][!b!]=!soce1!+!soce2!+!soce3!+!soce4!"
        set /a soce1=0,soce2=0,soce3=0,soce4=0
        for %%X in (!p_tzk!) do (
                for /f "tokens=1,2 delims=_" %%A in ("%%X") do (
                        for /l %%W in (1 1 4) do (
                                if not "!p_str%%W!"=="!p_str%%W:%%A=@!" if !soce%%W! LSS %%B set /a soce%%W=%%B
                        )
                )
        )
        set "P_str[!a!][!b!]=!p_str1!,!p_str2!,!p_str3!,!p_str4!"
        set "P_soce[!a!][!b!]=!soce1!+!soce2!+!soce3!+!soce4!"
rem end 创建。
) else (
rem 更新字串及评分，已存在的点会加快效率。
        if %%x NEQ 0 (
                set /a cut1=5-%%x-1,cut2=5-%%x,tk=1,pd=%%x+%%y
                if !pd! EQU 0 (
                        set /a cut1=cut1+30,cut2=cut2+30,tk=4
                )
                if %%x EQU %%y (
                        set /a cut1=cut1+20,cut2=cut2+20,tk=3
                )
        ) else (
                set /a cut1=15-%%y-1,cut2=15-%%y,tk=2
        )
        for /f "tokens=1,2" %%X in ("!cut1! !cut2!") do (
                set "C_str[%%a][%%b]=!C_str[%%a][%%b]:~0,%%X!!z!!C_str[%%a][%%b]:~%%Y!"
                set "P_str[%%a][%%b]=!P_str[%%a][%%b]:~0,%%X!!z!!P_str[%%a][%%b]:~%%Y!"
        )
        for /f "tokens=1-4 delims=+" %%A in ("!C_soce[%%a][%%b]!") do (
                set /a soce1=%%A,soce2=%%B,soce3=%%C,soce4=%%D
        )
        set /a soce=0,ttk=tk*10-10
        for %%T in (!ttk!) do (
                set "t_str=!C_str[%%a][%%b]:~%%T,9!"
        )
        for %%Q in (!tzk!) do (
                for /f "tokens=1,2 delims=_" %%A in ("%%Q") do (
                        if not "!t_str!"=="!t_str:%%A=@!" (
                                if !soce! LSS %%B set /a soce=%%B
                        )
                )
        )
        set /a soce!tk!=!soce!
        set "C_soce[%%a][%%b]=!soce1!+!soce2!+!soce3!+!soce4!"
rem 更新player评分
        for /f "tokens=1-4 delims=+" %%A in ("!P_soce[%%a][%%b]!") do (
                set /a soce1=%%A,soce2=%%B,soce3=%%C,soce4=%%D
        )
        set /a soce=0
        for %%T in (!ttk!) do (
                set "t_str=!P_str[%%a][%%b]:~%%T,9!"
        )
        for %%Q in (!p_tzk!) do (
                for /f "tokens=1,2 delims=_" %%A in ("%%Q") do (
                        if not "!t_str!"=="!t_str:%%A=@!" (
                                if !soce! LSS %%B set /a soce=%%B
                        )
                )
        )
        set /a soce!tk!=!soce!
        set "P_soce[%%a][%%b]=!soce1!+!soce2!+!soce3!+!soce4!"
)
rem end更新


                                )
                        )
                )
        )
)
复制代码

[ 本帖最后由 caruko 于 2011-1-26 15:17 编辑 ]

caruko

=。= 做了测试，发现防守还可以，进攻却缺少章法，不够犀利。

只有想办法加入“定式”，完善预判来提高智能了。

caruko

重复了。。看楼下。

[ 本帖最后由 caruko 于 2011-1-26 21:11 编辑 ]

caruko

已经完善了禁手判断，胜负判断，增加选择先后手。
对于匹配“定式”，走棋预判，已经有了思路。
有空完善后参上。

@echo off
setlocal enabledelayedexpansion
::初始变量
set "tzk=11111_9999999 011110_300000 11110_2500 01111_2500 0011100_3000 11101_3000 10111_3000 11011_2600  11100_500 00111_500 010110_800 011010_800 10011_600 11001_600 10101_550 00011000_650 11000_150 00011_150 0010100_250 010010_200"
set "p_tzk=22222_9999999 022220_300000 22220_2500 02222_2500 0022200_3000 22202_3000 20222_3000 22022_2600 22200_500 00222_500 020220_800 022020_800 20022_600 22002_600 20202_550 00022000_650 22000_250 00022_250 0020200_250 020020_200"
set "禁手=0011100_三 011010_三 010110_三 011100_#三 001110_@三 01111_四 11110_四 10111_四 11011_四  11101_四 11111_五 111111_长连 "
set "error1=坐标应为“x,y”形式，并且1-x-15,0-y-15。"
set "error2=x,y坐标越界。"
set "error3=该坐标已有棋子，无法在指定坐标下子。"
set /a 步=0
::初始化棋盘
for /l %%i in (1 1 15) do (
        set "Display_%%i=┼┼┼┼┼┼┼┼┼┼┼┼┼┼┼"
)
for /l %%i in (1 1 15) do for /l %%j in (1 1 15) do set QP[%%i][%%j]=0
call :显示棋盘
::设置先手
:xs
set /p 先手=请选择先手(玩家Player：P，电脑Computer：C）
if "!先手!"=="C" (set "行动方=Computerr" & set /a k1=10,k2=7 & set "先手=C" & set "qizi1=○" & set "qizi2=●")
if "!先手!"=="c" (set "行动方=Computer" & set /a k1=10,k2=7 & set "先手=C" & set "qizi1=○" & set "qizi2=●")
if "!先手!"=="p" (set "行动方=Player" & set /a k1=7,k2=10 & set "先手=P" & set "qizi1=●" & set "qizi2=○")
if "!先手!"=="P" (set "行动方=Player" & set /a k1=7,k2=10 & set "先手=P" & set "qizi1=●" & set "qizi2=○")
if not defined 先手 goto :xs
if "!先手!"=="C" (call :设置坐标 8 8 1) else (call :设置坐标 8 8 2 &goto :loop2)
:loop
call :显示棋盘
call :玩家走 ||(echo,!error%ERRORLEVEL%!&goto :loop)
:loop2
call :显示棋盘
call :电脑走
goto :loop
:玩家走
set "行动方=Player"
set /a zq=0
set /p P_zb=请输入坐标{1-15,1-15}:
for /f "tokens=1,2 delims=," %%a in ("!P_zb!") do (
        if %%a GTR 0 if %%a LSS 16 set /a zq+=1
        if %%b GTR 0 if %%b LSS 16 set /a zq+=1
        if "!QP[%%a][%%b]!"=="0" set /a zq+=1
        if "!zq!"=="3" call :设置坐标 %%a %%b 2
)
if "!P_zb!"=="exit" exit
if !zq! EQU 0 exit /b 1
if !zq! EQU 1 exit /b 2
if !zq! EQU 2 exit /b 3
exit /b 0
 
:电脑走
set "行动方=Computer"
set /a 最高分=0
for /l %%x in (1 1 15)  do (
        for /l %%y in (1 1 15) do (
                if defined C_soce[%%x][%%y] (
                        set "m=!C_soce[%%x][%%y]!"
                        set "n=!P_soce[%%x][%%y]!"
                        set /a m=!m!,n=!n!,mn=m*!k1!+n*!k2!
                        if !最高分! EQU !mn! set "坐标集=!坐标集! [%%x][%%y]"
                        if !最高分! LSS !mn! (
                                set /a 最高分=!mn!
                                set "坐标集=[%%x][%%y]"
                        )
                )
        )
)
rem 坐标集可能含有多个坐标，以后应用在αβ剪枝算法中，现在只取第一个。
for /f "tokens=1,2 delims=[]" %%i in ("!坐标集!") do (
        call :设置坐标 %%i %%j 1
)
goto :eof

:胜利
call :显示棋盘
if "%1"=="禁手" (
  echo !行动方!范"!禁!"禁手，该局判负！
) else (
  echo !行动方!五子连珠，赢得该局胜利！
)
set /p =按任意键结束游戏！<nul
pause>nul
exit
goto :eof

:显示棋盘
for /l %%i in (15 -1 1) do (
    echo %%i !Display_%%i!
)
echo,Y↑X→ 1 2 3 4 5 6 7 8 9 0 1 2 3 4 5
goto :eof
 
:设置坐标 [x] [y] [1,2]
set /a QP[%1][%2]=%3,x=%1,y=%2,z=%3,cut1=x-1,cut2=x,最高分=0,fens=0,步+=1
set "cr=!qizi%3!"
set "Display_!y!=!Display_%y%:~0,%cut1%!!cr!!Display_%y%:~%cut2%!"
set "第!步!步=%1,%2"
::判断禁手，“三四” “成五” 不算禁手，@三#三看似不是活三，两个一起构不成活四,但是跟别的活三,四搭配仍然是活三。
set "禁="
if "!行动方:~0,1!"=="!先手!" (
   for %%D in (!禁手!) do (
      for /f "tokens=1,2 delims=_" %%E in ("%%D") do (
        if not "!%先手%_str[%1][%2]!"=="!%先手%_str[%1][%2]:%%E=@!" set "禁=!禁!%%F"
      )
   )
)
if "!禁!"=="三四" set "禁="
if not "!禁!"=="!禁:#=!" if not "!禁!"=="!禁:@=!" set "禁="
if not "!禁!"=="!禁:五=!" if "!禁!"=="!禁:长连=!" set "禁="
if "!禁:~1,1!"=="" set "禁="
if defined 禁 call :胜利 禁手
::判断是否5连，断定胜负
if !步! GTR 1 if "!行动方!"=="Computer" (set /a fens=!C_soce[%1][%2]!) else (set /a fens=!P_soce[%1][%2]!)
if !fens! GEQ 9999999 call :胜利
set "C_str[%1][%2]="
set "C_soce[%1][%2]="
set "P_soce[%1][%2]="
set "P_str[%1][%2]="
::落子点估值
for /l %%i in (1 1 4) do (
        for %%j in (%%i_0 %%i_-%%i 0_-%%i -%%i_-%%i -%%i_+0 -%%i_+%%i 0_%%i %%i_%%i) do (
                for /f "tokens=1,2 delims=_" %%x in ("%%j") do (
                        set /a xx=x+%%x,yy=y+%%y
                        for /f "tokens=1,2" %%a in ("!xx! !yy!") do (
                                if defined QP[%%a][%%b] if !QP[%%a][%%b]! EQU 0 (

rem 更新双方字串并评分，没有的则重新创建，只更新 x-4 => x+4 范围且在一条直线上的评分。
set /a a=%%a,b=%%b,c=1
if "!C_str[%%a][%%b]!"=="" (
        set /a c_str1=c,c_str2=c,c_str3=c,c_str4=c,p_str1=2,p_str2=2,p_str3=2,p_str4=2
        for /l %%I in (-1 -1 -4) do (
                set /a xxx=a+%%I,yyy=b+%%I,lj1=0
                if !xxx! LSS 1 (
                        set /a lj1=1
                        set "c_str1=x!c_str1!"
                        set "p_str1=x!p_str1!"
                ) else (
                        for /f "tokens=1,2" %%A in ("!xxx! !b!") do (
                                set "c_str1=!QP[%%A][%%B]!!c_str1!"
                                set "p_str1=!QP[%%A][%%B]!!p_str1!"
                        )
                )
                if !yyy! LSS 1 (
                        set /a lj1=1
                        set "c_str2=x!c_str2!"
                        set "p_str2=x!p_str2!"
                ) else (
                        for /f "tokens=1,2" %%A in ("!a! !yyy!") do (
                                set "c_str2=!QP[%%A][%%B]!!c_str2!"
                                set "p_str2=!QP[%%A][%%B]!!p_str2!"
                        )
                )
                if !lj1! EQU 1 (
                        set "c_str3=x!c_str3!"
                        set "p_str3=x!p_str3!"
                ) else (
                        for /f "tokens=1,2" %%A in ("!xxx! !yyy!") do (
                                set "c_str3=!QP[%%A][%%B]!!c_str3!"
                                set "p_str3=!QP[%%A][%%B]!!p_str3!"
                        )
                )
                set /a xxx=a+%%I,yyy=b-%%I,lj1=0
                if !xxx! LSS 1 set /a lj1=1
                if !yyy! GTR 15 set /a lj1=1
                if !lj1! EQU 1 (
                        set "c_str4=x!c_str4!"
                        set "p_str4=x!p_str4!"
                ) else (
                        for /f "tokens=1,2" %%A in ("!xxx! !yyy!") do (
                                set "c_str4=!QP[%%A][%%B]!!c_str4!"
                                set "p_str4=!QP[%%A][%%B]!!p_str4!"
                        )
                )
        )
        for /l %%I in (1 1 4) do (
                set /a xxx=a+%%I,yyy=b+%%I,lj1=0
                if !xxx! GTR 15 (
                        set /a lj1=1
                        set "c_str1=!c_str1!x"
                        set "p_str1=!p_str1!x"
                ) else (
                        for /f "tokens=1,2" %%A in ("!xxx! !b!") do (
                                set "c_str1=!c_str1!!QP[%%A][%%B]!"
                                set "p_str1=!p_str1!!QP[%%A][%%B]!"
                        )
                )
                if !yyy! GTR 15 (
                        set /a lj1=1
                        set "c_str2=!c_str2!x"
                        set "p_str2=!p_str2!x"
                ) else (
                        for /f "tokens=1,2" %%A in ("!a! !yyy!") do (
                                set "c_str2=!c_str2!!QP[%%A][%%B]!"
                                set "p_str2=!p_str2!!QP[%%A][%%B]!"
                        )
                )
                if !lj1! EQU 1 (
                        set "c_str3=!c_str3!x"
                        set "p_str3=!p_str3!x"
                ) else (
                        for /f "tokens=1,2" %%A in ("!xxx! !yyy!") do (
                                set "c_str3=!c_str3!!QP[%%A][%%B]!"
                                set "p_str3=!p_str3!!QP[%%A][%%B]!"
                        )
                )
                set /a xxx=a+%%I,yyy=b-%%I,lj1=0
                if !xxx! GTR 15 set /a lj1=1
                if !yyy! LSS 1 set /a lj1=1
                if !lj1! EQU 1 (
                        set "c_str4=!c_str4!x"
                        set "p_str4=!p_str4!x"
                ) else (
                        for /f "tokens=1,2" %%A in ("!xxx! !yyy!") do (
                                set "c_str4=!c_str4!!QP[%%A][%%B]!"
                                set "p_str4=!p_str4!!QP[%%A][%%B]!"
                        )
                )
        )
        set /a soce1=0,soce2=0,soce3=0,soce4=0
        for %%X in (!tzk!) do (
                for /f "tokens=1,2 delims=_" %%A in ("%%X") do (
                        for /l %%W in (1 1 4) do (
                                if not "!c_str%%W!"=="!c_str%%W:%%A=@!" if !soce%%W! LSS %%B set /a soce%%W=%%B
                        )
                )
        )
        set "C_str[!a!][!b!]=!c_str1!,!c_str2!,!c_str3!,!c_str4!"
        set "C_soce[!a!][!b!]=!soce1!+!soce2!+!soce3!+!soce4!"
        set /a soce1=0,soce2=0,soce3=0,soce4=0
        for %%X in (!p_tzk!) do (
                for /f "tokens=1,2 delims=_" %%A in ("%%X") do (
                        for /l %%W in (1 1 4) do (
                                if not "!p_str%%W!"=="!p_str%%W:%%A=@!" if !soce%%W! LSS %%B set /a soce%%W=%%B
                        )
                )
        )
        set "P_str[!a!][!b!]=!p_str1!,!p_str2!,!p_str3!,!p_str4!"
        set "P_soce[!a!][!b!]=!soce1!+!soce2!+!soce3!+!soce4!"
rem end 创建。
) else (
rem 更新字串及评分，已存在的点会加快效率。
        if %%x NEQ 0 (
                set /a cut1=5-%%x-1,cut2=5-%%x,tk=1,pd=%%x+%%y
                if !pd! EQU 0 (
                        set /a cut1=cut1+30,cut2=cut2+30,tk=4
                )
                if %%x EQU %%y (
                        set /a cut1=cut1+20,cut2=cut2+20,tk=3
                )
        ) else (
                set /a cut1=15-%%y-1,cut2=15-%%y,tk=2
        )
        for /f "tokens=1,2" %%X in ("!cut1! !cut2!") do (
                set "C_str[%%a][%%b]=!C_str[%%a][%%b]:~0,%%X!!z!!C_str[%%a][%%b]:~%%Y!"
                set "P_str[%%a][%%b]=!P_str[%%a][%%b]:~0,%%X!!z!!P_str[%%a][%%b]:~%%Y!"
        )
        for /f "tokens=1-4 delims=+" %%A in ("!C_soce[%%a][%%b]!") do (
                set /a soce1=%%A,soce2=%%B,soce3=%%C,soce4=%%D
        )
        set /a soce=0,ttk=tk*10-10
        for %%T in (!ttk!) do (
                set "t_str=!C_str[%%a][%%b]:~%%T,9!"
        )
        for %%Q in (!tzk!) do (
                for /f "tokens=1,2 delims=_" %%A in ("%%Q") do (
                        if not "!t_str!"=="!t_str:%%A=@!" (
                                if !soce! LSS %%B set /a soce=%%B
                        )
                )
        )
        set /a soce!tk!=!soce!
        set "C_soce[%%a][%%b]=!soce1!+!soce2!+!soce3!+!soce4!"
rem 更新player评分
        for /f "tokens=1-4 delims=+" %%A in ("!P_soce[%%a][%%b]!") do (
                set /a soce1=%%A,soce2=%%B,soce3=%%C,soce4=%%D
        )
        set /a soce=0
        for %%T in (!ttk!) do (
                set "t_str=!P_str[%%a][%%b]:~%%T,9!"
        )
        for %%Q in (!p_tzk!) do (
                for /f "tokens=1,2 delims=_" %%A in ("%%Q") do (
                        if not "!t_str!"=="!t_str:%%A=@!" (
                                if !soce! LSS %%B set /a soce=%%B
                        )
                )
        )
        set /a soce!tk!=!soce!
        set "P_soce[%%a][%%b]=!soce1!+!soce2!+!soce3!+!soce4!"
)
rem end更新
 
 
                                )
                        )
                )
        )
)
复制代码

[ 本帖最后由 caruko 于 2011-1-27 20:53 编辑 ]

netbenton

21楼，一开始就提示，找不到操作数，

下子无法对齐，请检查下看

才一个四，就提示四四禁手

就这样了

caruko

=.= 检查了一下， 操作数那个错误是下面这句
if "!行动方!"=="Computer" (set /a fens=!C_soce[%1][%2]!) else (set /a fens=!P_soce[%1][%2]!)
胜负判断放在估值前，导致第一次运行调用的变量没有。

至于禁手那个错误，我只惦记 2-4个符合的情况，竟然忘记了只有一个时不是禁手。
代码修改过了。。

至于对齐没发现问题啊。。

另外电脑也可能自己走出禁手，因为考虑禁手的多层的搜索算法还没写好。
主要是在 :设置坐标 函数基础上做部分修改，预判走棋的搜索范围进一步减小，因为在循环中不使用call，判断条件比较多，只能使用重复代码来写。

"定式"的算法想好了，只是定式字串还没找到资料参考，如下
set "定式=_[8][8][7][9][7][7][9][9]..._[8][8][7][9][9][7][7][7]..._....."
然后记录连续下子的坐标set jilu=!jilu![!x!][!y!]，
比如第一步下[8][8]，第2步下的[7][9]，求第3步；
那么set !定式:%记录%=@! ，如果替换成功，表示有符合该棋路的定式
然后用替换后的字符串 "_@[7][7][9][9]_@[9][7][7][7]_.."
for /f "tokens=2,3 delims=@[]" 得到坐标值，如果替换后是@_，或者没有替换成功，那就表示以后都不需要检查定式了。

[ 本帖最后由 caruko 于 2011-1-27 21:23 编辑 ]

caruko

还考虑过用相对坐标设计定式 =。= 如 set "定式=[-1][1][-2][-1][-2][-2]"
具体还要测试了。。

ShenMian

回复 12# netbenton


    我觉得这所谓的智能好像还有点问题，三子一线都不理，自己在一边乱下。不管各种技巧，这应该是基本吧。