cjiabing

回复 15# Perl

    人比较笨没办法！~
    你学得蛮细的嘛~！我习惯了这种传统的做工，所以没法去了解dir>txt这样也得，佩服兄了！~

terse

不知道这个18在这里是随机的还是固定的

@echo off&setlocal enabledelayedexpansion
set M=18
for /f "delims=" %%i in ('dir /b /a-d *.*') do (
    set /a Num=N/M,D=N%%M,N+=1
    if !D! EQU 0 MD "New_!Num!" 2>NUL
    copy "%%i"  "New_!Num!" >NUL
)
pause
复制代码

523066680

回复 13# cjiabing


    他那个for好像会把批处理也复制进去吧……
filetest>dir *.bat  /s /b
filetest\fo.bat
filetest\test.bat
filetest\test2.bat
filetest\MyFolder_21\fo.bat
filetest\MyFolder_21\test.bat
filetest\MyFolder_21\test2.bat

jiabing的文件列表选在了文本里，避开了这个问题。

terse

回复  cjiabing


    他那个for好像会把批处理也复制进去吧……
filetest>dir *.bat  /s /b
filetes ...
523066680 发表于 2012-2-24 19:55

看前面代码 应该没避开哦
本应添加 IF "%%i" neq "%~nx0" 的  即可

523066680

回复 19# terse


恩，也可以  dir 的时候 ^|find /v "%~nx0"
还可以选择把批处理放在文件夹外部~  不过，还是看楼主具体要求了。也许批处理本身进去也无所谓

今晚真热闹


也写了，不见得好

@echo off &setlocal enabledelayedexpansion
set /a n=18,folder=0
for /f "tokens=*" %%a in ('dir /b /a-d * ^|find /v "%~nx0"') do (
	if !n! lss 18 (
		set /a n+=1
	) else (
		set /a n=1,folder+=1
		md fold_!folder!
	)
	copy "%%a" fold_!folder!\
)
pause
复制代码

cjiabing

回复 20# 523066680


    看官，那是昨晚的事情了！~
    昨晚的代码比较潦草些，现在修改完善如下：

 @echo off&setlocal enabledelayedexpansion
::文件分类管理：按每18个文件装进一个文件夹整理。
echo;&echo;    开始整理……&echo;
set newf=0
set numf=0
set conf=0
if not exist New!newf! md New!newf!
for /f "tokens=*" %%a in ('dir /b /a-d') do (
    if !numf! geq 18 set numf=0&set /a newf+=1&md New!newf!
    if not "%%~na"=="%~n0" copy "%%~a" New!newf!&set /a numf+=1
    set /a conf=!newf!*18+!numf!
)
echo;&echo;    整理完成，共 !conf! 个文件，请注意检查！&pause>nul
复制代码