[文本处理] 批处理怎么实现按自己定义的顺序排序

daychen

几百行的TXT的文本
批处理怎么实现按自己定义的顺序排序
例如
231231
2323
334343
7868678
345ffffffffff435
09098
09
234
556565767
dafsdfsdfetrt
erthhgfh

把每行按 0 7 2 5 3 开头这样排序(这里的顺序可以自定义)
第一位相同的按从小到大排序
09
09098
7868678
234
2323
231231
556565767
345ffffffffff435
dafsdfsdfetrt
erthhgfh

CrLf

如果只是第一位，那还好办点：

@echo off
sort a.txt>tmp.txt
(for %%a in (0 7 2 5 3) do (
   findstr /bc:"%%a" tmp.txt
))>b.txt
复制代码

不过看不懂楼主给的示例中

234
2323
231231
复制代码

这里的排序为什么是逆序的

daychen

回复 2# CrLf



   
谢谢 第一位就好
其他位按从小大到
例子里我乱打的 是巧合
是不是你那样就可以了

daychen

回复 2# CrLf


    后边两行的字母没了？字母字符串也要保留 不过可以不用参与排序

CrLf

忘了保留，已修改：

@echo off
sort a.txt>tmp.txt
set "key=0 7 2 5 3"
(for %%a in (0 7 2 5 3) do (
   findstr /b "%%a" tmp.txt
)
findstr /vb "[%key: =%]" tmp.txt
)>b.txt
pause
复制代码

或用这个更通用的，但会多生成一个临时文件：

@echo off
sort a.txt>tmp.txt
set "key=0 7 2 5 3"
(for %%a in (0 7 2 5 3) do (
   findstr /b "%%a" tmp.txt
)
)>tmp2.txt
copy /y tmp2.txt b.txt>nul
findstr /vbg:tmp2.txt tmp.txt>>b.txt
pause
复制代码

再来个常见思路的，速度会快一些：

@echo off
set "文件名=b.txt"
set "key=0 7 2 5 3">"%文件名%"
(for /f "delims="eol^= %%a in ('sort a.txt') do (
   set "str=%%a"
   setlocal enabledelayedexpansion
   for %%b in (%key%) do (
      if "!str:~,1!"=="%%b" (
         echo !str!>>"%文件名%"
         set "str="
      )
   )
   if defined str echo;!str!
   endlocal
))>tmp.txt
type tmp.txt>>"%文件名%"
pause
复制代码

daychen

回复 5# CrLf
09
09098
7868678
231231
2323
234
556565767
334343
345ffffffffff435

dafsdfsdfetrt
erthhgfh

通过 但为什么又多了一个空行 能删掉吗

CrLf

回复 6# daychen


    因为你原文件里就有空行，要去除空行用五楼第三个代码（刚加上的）

daychen

回复 7# CrLf



   
很牛逼 十分感谢

daychen

回复 7# CrLf



   
很牛逼 十分感谢

daychen

回复 7# CrLf


第三个代码在大文件里测试没反应 几行数据就行
我用第一个代码能够处理大文件
我的TXT文本有30M

daychen

回复 7# CrLf


    第一个代码却变大了 处理后 原本28.5M变成了34M