terse

你是每个文件单独处理的
这样解决问题倍觉累啊
你最好把整个问题表述清楚
弄了两个代码 再去合并运行  会有很多问题 比如 变量问题
猜想你  是否想整个合并的文件排序
那样你最后SORT 反倒觉得前面不需要排序 只管写入好了

terse

回复 15# lateol
帮你整合在一起试吧
里面有重复处理 影响效率 看你的处理量了

@echo off
cls
for /l %%i in (1,1,3) do echo.
color 1A
ECHO 　　　　　 　 ┏━━━━━━━━━━━━━━━━━━━━┓
ECHO 　　　　　    ┃ 　　　　　　　　　　　　　　　　       ┃
ECHO 　  ┏━━━━┫     当前选择： 有规则程序自动合成      ┣━━━━┓
ECHO 　  ┃　 　   ┃　　　　　　　　　　　　　　　 　     　┃　　    ┃
ECHO   　┃　      ┗━━━━━━━━━━━━━━━━━━━━┛　　    ┃
echo     ┃                       ==处理说明↓==                       ┃
echo.    ┃                                                            ┃
ECHO 　  ┃    ┗━━直接按回车默认选择“==NC==”文件夹处理━━┛      ┃
echo.    ┃                                                            ┃
echo.    ┏------------------------------------------------------------┓
echo     ┣    ★★★★★★====默认选择==NC==处理。====★★★★★★    ┫
echo.    ┗------------------------------------------------------------┛
echo.    ┃                                                            ┃
echo.    ┣= 请保证该所有程序内刀具无重复即可完成处理=  【0查看说明】  ┫
echo.    ┃                                                            ┃
set /p DJFL=
IF /I '%DJFL%'=='0' GOTO zdhcsm
echo     ┏━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┓
echo     ┃              ===正在处理...以下为刀具信息！====            ┃
pushd "==NC==\"
@echo off&setlocal enabledelayedexpansion
for /f "tokens=1,2* delims=:" %%i in ('findstr /ic:"TOOL NAME = " /c:"(Cutter Name:" /c:"( DIA. = " /c:"(  Dia:" /c:"(Tool Name:" *.nc') do (
    if "!%%i!" == "" (
       set "str="
       if "%%k" == "" for /f "tokens=2-6 delims==,)" %%a in ("%%j") do (
          if "%%c" =="" (
             set D=%%a&set "R=%%b"
          ) else set D=%%c&set "R=%%e"
       ) else for /f "tokens=1-6 delims=:) " %%a in ("%%k") do (
                   if "%%d" neq "" (
                      set D=%%a&set "R=%%d"
                   ) else set "str=%%a"
               )

                if "!str!" == "" for %%f in (D R) do for /f %%h in ("!%%f!") do (
                    set "%%f=%%h"
                    for /l %%e in (1 1 6) do (
                        if "!%%f:~-1!" == "0" set "%%f=!%%f:~,-1!"
                    )

                    if "!%%f!" neq "0." (
                       if "!%%f:~-1!" == "." set "%%f=!%%f:~,-1!"
                       if "!%%f!" neq "" set "%%f=%%f!%%f!"
                    ) else set "%%f="
                      set "str=!D!!R!"
                )
::==========================修正DxRx==========================
                   set strD=!str:~0,1!
                   if "!strD!" equ "R" (
                      for /f "tokens=1 delims=R" %%h in ("!str!") do set /a strJS=%%h*"2"
                      set str=D!strJS!!str!
                   )
::==========================此为按规则合并参数========================
                    md "!str!" 2>nul
                    set "f=%%~ni"
                    set "f=!f:~-2!"
                    set "s=-G"
                    for %%a in (A R1 F1 -1) do if "!f:%%a=!" neq "!f!" set "s="
                    (
                    for /f "tokens=* delims=:" %%l in ('findstr /ic:G54.1P %%i') do (
                         if not defined %%i-!str!!s! (
                            set "var=%%l"
                            for /f "delims=G " %%l in ("!var:*G54.1P=!") do (
                                set "var= %%l"
                                echo !var:~-2! %%i
                                set %%i-!str!!s!=i
                            )
                         )
                    )
                    )>>"1-!str!!s!.lat"
                    >$.t sort <"1-!str!!s!.lat"
                    move $.t "1-!str!!s!.lat"
  )
)

echo     ┠──────────────────────────────┨
echo     ┃               ===【刀具分类模拟完成！】===                 ┃
ECHO     ┗━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━┛
pause
复制代码

lateol

回复 17# terse


    好的，感谢一直帮忙，是这样的，
我是 打算把*.nc 根据文本信息分类且进行按程序名第一个程序相合并，如程序名尾部包含A R1 F1 就合并。
如果直接用 copy 合并，也许顺序就有些混乱，所以就想到， 读取文本信息某特征作为排序特征。
1  R126B17-3.nc 写入对应的.TXT  再对文本进行排序，顺便也想了解了解 是如何完成排序的。呵呵
再利用FOR 提取 每个写入好的txt  提取他的文件名按顺序逐行合并起来就可以了。

terse

如果 lat文件都是刚刚生成的 和没有别的lat文件 那就可以到代码最后再另排序 那样效率可以提高点

lateol

回复 17# terse


    这个排序 可以 不过有点BUG
2 13124A3D.nc
3 13124A1D.nc
4 13124A1DD.nc
5 002H12-R3.nc
5 002H12-R3.nc
6 002H12-R3.nc
6 002H12-R3.nc
10 002H12-F3.nc
10 002H12-F3.nc
11 002H12-F3.nc
11 002H12-F3.nc

002H12-R3.nc 和 02H12-F3.nc这两个文件里面有两个 G54.1PXX  

002H12-R3.nc 里有 G54.1P5和G54.1P6
02H12-F3.nc  里有 G54.1P10和G54.1P11
取他们第一个就好。

处理后效果如
2 13124A3D.nc
3 13124A1D.nc
4 13124A1DD.nc
5 002H12-R3.nc
10 002H12-F3.nc

lateol

回复 19# terse


    今天信息量蛮大的 让您费神了。  领教了 呵呵，

terse

回复 21# lateol
修正在 17楼

lateol

回复 22# terse


    完美！
               set %%i-!str!!s!=i
                    )>>"1-!str!!s!.lat"
                    >$.t sort <"1-!str!!s!.lat"
                    move $.t "1-!str!!s!.lat"
这4行代码可以 详解一下吗？
set %%i-!str!!s!=i  赋值了个 i 吗？
这里的 >$.t   和   sort <"1-!str!!s!.lat"是什么情况。
谢谢

terse

set %%i-!str!!s!=i  赋值  i 与 变量 %%i-!str!!s!
>$.t   和   sort <"1-!str!!s!.lat" 排序文件 1-!str!!s!.lat 并把结果 写进$.t
move $.t "1-!str!!s!.lat" 这个应该清楚吧 可以 move /?  可以等同于剪切理解 ok？ 也就是1-!str!!s!.lat内容替换为 $.t 的内容