[文本处理] 【已解决】如何用批处理将特定文字内容分两列写入excel文件？

Lumiere

我有一个文本，内容很有规律，写在一个名为1.txt的文本文件中，内容如下：
……………………………………
……………………………………
耔晶取向 seed orientation
籽晶生长 seeded growth
均质核化 homogeneous nucleation
异质核化 heterogeneous nucleation
均匀化热处理 homogenization heat treatment
……………………………………
……………………………………
……………………………………

基本都是这样的专业术语，如果我想用批处理把他们分成两列对应写入一个名为1.xlsx的excel文件的话，纯批处理能做到吗？不能的话应该借助什么其他脚本呢？如果可能，请在其他脚本的代码处给出相应的注释，谢谢！

Batcher

@echo off
(for /f "tokens=1*" %%i in (1.txt) do (
    echo %%i,%%j
))>1.csv
复制代码

Lumiere

回复 2# Batcher


    我想再问下，如果两列之间没有空格，就是英文和中文直接链接在一起的，比如从“中文english”这样的格式，怎么能方便的用代码实现分离，并且做成那样的excel文件？有没有简单的命令能区分中文和英文字符然后把字符串截断的命令？

tmplinshi

回复 3# Lumiere

@echo off
call :txt2csv "1.txt" >1.csv
exit /b

:txt2csv <InputFile>
	SetLocal EnableDelayedExpansion
	
	for /f "usebackq tokens=*" %%i in ("%~1") do (
		set str_full=%%i
		for /f "delims=abcdefghijklmnopqrstuvwxyz" %%a in ("%%i") do (
			echo %%~nxa,!str_full:*%%a=!
		)
	)
	
	EndLocal
goto :eof
复制代码

Lumiere

回复 4# tmplinshi


经测试完美运行，非常感谢。代码基本都懂，但是还有三个点需要帮忙解疑：
1. csv文件是excel类型文件，为什么能用批处理写入内容形成这种文件却不能写成xlsx文件？
2. 为什么在两部分内容之间加入逗号“，”就可以实现将两部分写在同一行相邻的两个单元格？可以用其他的字符代替么？
3. for结构里最后一条为什么是%%~nxa，这个不是扩展成一个文件名和扩展名的意思吗？不是直接用%%a就可以了吗？

tmplinshi

回复 5# Lumiere

1. csv文件是excel类型文件，为什么能用批处理写入内容形成这种文件却不能写成xlsx文件？

因为批处理只能输出纯文本，而 xlsx 其实是 zip 压缩文件。

2. 为什么在两部分内容之间加入逗号“，”就可以实现将两部分写在同一行相邻的两个单元格？可以用其他的字符代替么？

因为 csv 的格式就是这样——用逗号分隔。可以用 Tab 符号代替，但是文件格式要保存为 UTF-16 LE。

3. for结构里最后一条为什么是%%~nxa，这个不是扩展成一个文件名和扩展名的意思吗？不是直接用%%a就可以了吗？

%%~nxa 可以去掉末尾的空格

Lumiere

回复 6# tmplinshi


    谢谢耐心的回复，这个%%~nxa既然说扩展为文件名和扩展名，这个不是跟文件相关的概念么，怎么用在字符串上了，是巧用吗？还有其他的用途么？我先把帖子结了。

tmplinshi

是的，巧用。

Lumiere

回复 8# tmplinshi

谢谢，无疑问了，多谢解答，结贴了。