[文本处理] 【已解决】BAT：如何颠倒一组数据，使最后一行变成第一行

思想之翼

见附件，1.txt文本里有一组数据，数据最后一行下面有若干tab空格，或略这些tab空格，颠倒这组数据，使最后一行数据变成第一行，最后第二行数据变成第二行...
同理，若有1.txt  2.txt ...1000.txt  欲批量颠倒这些txt文本里的数据，这样的代码如何写？恳望得到帮助。
另：
sort /r *.txt >(降序)*.txt
此代码需有一列顺序排列的数据方才适用，而对于附件里无规则的数据组，则不适用。

batman

请楼主节约论坛空间，尽量用文字来描述自己的问题，不要动不动就传附件上来好吗？
顶楼的附件我已帮楼主删除，因为我认为这个问题完全可以用文字描述清楚，不用上传附件。

batman

@echo off
for %%a in (*.txt) do (
  setlocal enabledelayedexpansion
  for /f "usebackq delims=" %%b in ("%%a") do set /a n+=1&set "_!n!=%%b"
  (for /l %%b in (!n!,-1,1) do echo,!_%%b!)>$
  move $ "%%a"
  endlocal
)
复制代码

思想之翼

回复 3# batman

感谢关注！
您的代码，经测试，结果却将所有txt文本数据全部删除。

foxJL

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%i in (a.txt) do (set /a n+=1 & set str_!n!=%%i)
for /l %%j in (!n!,-1,1) do (echo,!str_%%j!>>b.txt)
pause
复制代码

batman

回复 4# 思想之翼


    打错一个字符，再测试。。。

思想之翼

回复 6# batman

谢谢，可以用了。
只是不能批量进行置换，双击一下颠倒一个文本，再双击，再颠倒一个
末尾的空行排在了第1、第2、第3排...或略空行，将最后一排数据排在第1排就好了

terse

楼主有没试过这样

sort /+1024 a.txt> "(降序)a.txt"
复制代码

思想之翼

回复 5# foxJL

感谢您的帮助！
您写的代码要是能够批量置换就更好了（一次置换若干txt文本）。

思想之翼

回复 8# terse

谢谢帮助。
1024什么意思？

foxJL

回复 9# 思想之翼

批量转换

@echo off&setlocal enabledelayedexpansion
for %%a in (*.txt) do (
	set "n="
	for /f "usebackq delims=" %%i in ("%%a") do (set /a n+=1 & set str_!n!=%%i)
	for /l %%j in (!n!,-1,1) do (echo,!str_%%j!>>%%~na_b.txt)
)
pause
复制代码