[文本处理] [已解决]批处理怎样中找到2－40这个字符串的行数后，再向下运行5行？

iq301

请大家帮忙看下一段BAT代码，
原意是在txt文本中找到2－40这个字符串的行数后，再向下运行5行，然后结束,在文档里循环。我搞了一上午都搞不定。。麻躁了。。

@echo on&SetLocal ENABLEDELAYEDEXPANSION
set a=0
for /f "delims=: tokens=1,2" %%a in ('findstr /n .* Q:\Ray\routine\M2_20140601.txt^|findstr "2-40"') do ( set a=%%a)
set /a aa=%a%+5 
for /f "delims=: tokens=1*" %%c in ('findstr /n .* Q:\Ray\routine\M2_20140601.txt') do (
set c=%%c
if %a%==%c%(
echo %%d&set /a c+=1
)
if "!c!"=="%aa%" goto :EOF 
)
goto :EOFpause
复制代码

iq301

文本里有很多内容，但我只要读取其中的几行就行了，附件上的2－40包括2－40以下那几行就是我想要的，

terse

@echo off & setlocal enabledelayedexpansion
findstr /in .* "M2_20140601.txt">$
for /f "delims=:" %%i in ('findstr /i "\<2-40\>" $') do set /a n=%%i,m=n+5
for /L %%i in (%n%,1,%m%) do set "str=!str! %%i:"
(for /f "tokens=1*delims=:" %%i in ('findstr /ib "%str%" $') do echo;%%j)>tmp.txt
start "" tmp.txt&del $
复制代码

iq301

回复 3# terse

我测试了下你的代码，只能显示一次结果，结果是对的，但文档里面有很多2-40的，能不能全部找出来？

CrLf

sed -n "/2-40/{N;N;N;N;N;p;q}" a.txt
复制代码

iq301

回复 5# CrLf


    没有sed命令噶，公司电脑不允许使用任何第三方软件，哎。。

terse

回复 4# iq301

@echo off & setlocal enabledelayedexpansion
for /f "delims=:" %%i in ('findstr /n "\<2-40\>" M2_20140601.txt') do (
    set /a n=%%i,m=n+5
    for /L %%j in (!n! 1 !m!) do set $%%j=1
)
(for /f "tokens=1*delims=:" %%i in ('findstr /in .* "M2_20140601.txt"') do if defined $%%i echo;%%j)>tmp.txt
start "" tmp.txt
复制代码

CrLf

@echo off
(for /f %%a in ('findstr /n . a.txt') do (
   setlocal enabledelayedexpansion
   set /p "str="
   if not !str:2-40!==!str! (
      echo;!str!
      for /l %%a in (1 1 5) do set /p "str[%%a]="&echo;!str[%%a]!
   )
   endlocal
))<a.txt
复制代码

iq301

谢谢各位，非常感谢各位的帮助，解决了。上面的terse方法可行，哈哈，CrLf的就好像不大行哦。无限循环了，不过还是谢谢你们。

CrLf

回复 9# iq301


    ？？无限循环？本机测试无误啊