[文本处理] [已解决]批处理怎样删除连续空行？

honghong33

有一个文件
1



2

3


4

5

6
变成
1

2
3

4
5
6
当只有一个空行是删除空行，空行数大于一时，保留一个空行。

pcl_test

回复 1# honghong33
假设有test.txt

@echo off
setlocal enabledelayedexpansion
set n=0
for /f "tokens=1* delims=:" %%a in ('findstr /n .* "test.txt"') do (
set "str=%%b"
if !n! lss 2 if not "!str!" == "" (
>>$ echo,!str!
set n=0
)
if !n! gtr 1 if not "!str!" == "" (
>>$ echo.
>>$ echo,!str!
set n=0
)
if not "!n!" == "0" if "!str!" == "" (
set /a n+=1
)
if "!n!" == "0" if "!str!" == "" (
set /a n+=1
)
)
move $ "test.txt"
pause
复制代码

慕夜蓝化

@echo off&SETLOCAL ENABLEDELAYEDEXPANSION
(FOR /f "tokens=1* delims=[]" %%i in ('type "a.txt"^|find /v /n ""') do (
    if not "!str!"=="" (
        if not "%%j"=="" (
            echo,%%j)
    ) else ( echo,%%j
    )
    set "str=%%j"
)) >$
more /s $ >b.txt&del /q $
复制代码

CrLf

回复 3# 慕夜蓝化


    用 tokens=1* 更通用一点

慕夜蓝化

回复 4# CrLf


    嗯嗯，已经更改。

DAIC

如果只需要删除连续空行，不需要删除原有的单个空行，会比较简单：

sed -i "/./,/^$/!d" 1.txt
复制代码

honghong33

回复 3# 慕夜蓝化


    非常感谢

honghong33

回复 2# pcl_test


    非常感谢

honghong33

回复 6# DAIC


    非常感谢

honghong33

回复 4# CrLf


    非常感谢