[文件操作] [已解决]求助批处理，文件重命名和统计行数

shimuren

怎么实现批量获取文件夹下面txt文件行数，并在 txt文件名 后面添加对应文件行数值？

pcl_test

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /a-d/b/s *.txt') do (
    for /f "tokens=3 delims=:" %%b in ('find /c /v "" "%%a"') do set n=%%b
    ren "%%a" "%%~na_!n: =!%%~xa"
)
pause
复制代码

回家路上

@echo off & setlocal enabledelayedexpansion
%1(for /f "delims=" %%i in ('%~0 :^|sort') do ren %%i)& pause & exit /b
for /f "tokens=1,* delims= " %%i in ('find /c /v "" *.txt') do (
	set info=%%j
	set ln=!info:*:=!
	for /f "delims=" %%a in ("!ln!") do set fn=!info::%%a=!
	echo;"!fn!" "!fn:~,-4!!ln:~1!.txt"
)
复制代码

shimuren

回复 2# pcl_test


“存在一个重名文件，或是找不到文件。”
运行后出现这个情况

pcl_test

回复 4# shimuren

测试没有问题，打包附件上传你的测试文件

shimuren

回复 5# pcl_test


    问题已经解决 谢谢朋友

shimuren

回复 3# 回家路上


        问题已经解决 谢谢朋友

shimuren

回复 3# 回家路上


    继续求助：如何让该bat支持文件拖拽呢，比如将文本拖拽到bat图标上，就自动统计该txt的行数？
谢谢朋友~

回家路上

回复 8# shimuren

@echo off
:deal
for /f "tokens=3 delims=:" %%i in ('find /c /v "" "%~1"') do set n=%%i
echo;%~1     %n: =%
shift
if "%~1" neq "" goto deal
pause & exit /b
复制代码