[文本处理] 如何批量删除文件名最后两个字符之前的所有字符并以递增序号的方式处理重名文件？

wzf1024

有很多txt文件：
123.txt
1234.txt
12345.txt
……
----------------
只想保留文件名最后两个字：
23.txt
34.txt
45.txt
……

-------------------
大侠，如何实现

ivor

回复 1# wzf1024

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b *.txt') do (
	set "name=%%a"
	rename "%%a" !name:~-6!
)
pause
复制代码

代码很容易，但是你的文件很多，只留两个字符，很容易会文件名重复


刚出炉的新代码：有多少重复的都没问题

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /b *.txt') do (
	set "name=%%a"
	rename "%%a" "!name:~-6!" 2>nul || call :repeat
)
echo 已经全部处理...... & pause>nul
goto :EOF
:repeat
set /a num+=1
rename "!name!" "!name:~-6,2!(!num!)!name:~-4!" && goto :EOF || goto :repeat
复制代码

bailong360

ren2 -f ".*(..)(\.txt)" "$1$2"
复制代码

wzf1024

回复 2# ivor


    原来的条件，如果需要在出现重复文件名时后面加递增序号如何解决，
如：
1234.txt
2234.txt
替换后：
34.txt
34(1).txt

--------------------
如何实现、谢谢

wzf1024

回复 3# bailong360


    大侠，这不是批处理吧，需要什么软件吗？谢谢

CrLf

回复 2# ivor


    -6好像不对吧

bailong360

回复 5# wzf1024
第三方ren2

ivor

回复 1# wzf1024


    2楼代码已更新

顺便附带测试专用代码

@echo off&setlocal enabledelayedexpansion
rem 测试专用,生成100个xxxx66.txt
for /l %%a in (1,1,100) do (
	echo.>!random!66.txt
)
复制代码

ivor

回复 6# CrLf


    没错啊，我都测试过了

CrLf

回复 9# ivor


    噢，是我晕了，还要算上 .