【已解决】批处理提取全盘指定文件类型出错

woxingwoshu007

大虾们,急救:以下的这个批处理是提取全盘中的mp3的文件并把内容写入music.txt

1:
@echo off
for %%a in (c d e f) do for /r  %%a:\  %%b in(*.mp3) do echo %%b
>music.txt


那里出错了?
如果把写成:
2:
@echo off
for /r f:\ %%i in (*.mp3) do echo %%i>>music.txt
pause>nul
就可以:

帮忙解决下1中的问题

[ 本帖最后由 woxingwoshu007 于 2009-4-15 11:57 编辑 ]

tireless

改成：

for %%a in (c d e f) do %%a:&for /r %%b in(*.mp3) do echo %%b

或者： dir /s/b/a c:\*.mp3 d:\*.mp3 e:\*.mp3 f:\*.mp3 > music.txt

woxingwoshu007

for %%a in (c d e f) do %%a:&for /r %%b in(*.mp3) do echo %%b
我试过了不行的..求助ing

lxzzr

 
@echo off
for /f "usebackq skip=2 delims=" %%a in (
       `"wmic logicaldisk where 'drivetype=3' get name"`
       ) do (
       call :sub %%a
)
exit
:sub
for /r %1\ %%a in (*.mp3) do echo %%a>>music.txt
goto :eof
复制代码

Batcher

@echo off
(for %%a in (c d e f) do (
  pushd %%a:\
  for /r  %%b in (*.mp3) do (
    echo %%b
  )
  popd
))>music.txt
复制代码

zqz0012005

wmic datafile where "Extension='mp3'" get Name
复制代码

cim_datafile类对有些文件无法找到，闻lxzzr兄对WMI颇有研究，不知是否知悉确切原因。

lxzzr

zqz0012005兄能举个例子来看下吗，说句实话，这个我倒是没遇到过，我这边也测试了很多的例子都是正常的.

woxingwoshu007

`"wmic logicaldisk where 'drivetype=3' get name"`
新手..苦闷学了一个多月了.还是看不明白.麻烦解释
thanks

woxingwoshu007

嗯,,确实不同凡响,你的代码确实简单实用..在原来的基础上加以改进:只提取全盘中的mp3名字,不需要显示路径??

Batcher

有些系统不支持WMIC，不存在那个代码更实用的问题，根据自己的需要，选择最合适的即可。
参考：批处理全盘搜索指定文件获取其完整路径
http://bbs.bathome.net/thread-3465-1-1.html

woxingwoshu007

谢谢,各位朋友的帮助..我自己电脑上mp3文件通过以下批处理已经处理完毕了:
  @echo off
(for %%a in (c d e f) do (
  pushd %%a:\
  for /r  %%b in (*.mp3) do (
    echo %%b
  )
  popd
))>1.txt
for /f  "tokens=4* delims=\"   %%i in (1.txt) do echo %%i   %%j >>music.txt

pause>nul