[文本处理] 【已解决】批处理压缩文件时的进度显示开关如何关闭？

ztxby

在批处理压缩过程中,假如要压缩的文件里包含几千个文件,那样的话在命令行窗口中就会一直跳动文件1被压缩,文件2被压缩.....文件N被压缩...
请问这样的显示可以用参数关掉吗?

 
@echo off
rem 请根据自己的实际情况修改WinRAR的路径
set rarPath=C:\Program Files\WinRAR
rem 假设系统日期格式是yyyy-mm-dd
set ThisYear=%date:~0,4%
set ThisMonth=%date:~5,2%
set ThisDay=%date:~8,2%
call :DateToDays %ThisYear% %ThisMonth% %ThisDay% ThisDays
set /a DstDays=%ThisDays%-1%ThisDay%+100
call :DaysToDate %DstDays% DstYear DstMonth DstDay
for /l %%a in (1,1,5) do (
  "%rarPath%\rar.exe" a "F:\bak\AAA%%a[%DstMonth%].rar" "F:\AAA%%a\%DstYear%\%DstMonth%"
  ping -n 1800 127.1 >nul
)
goto :eof
:DateToDays %yy% %mm% %dd% days
setlocal ENABLEEXTENSIONS
set yy=%1&set mm=%2&set dd=%3
if 1%yy% LSS 200 if 1%yy% LSS 170 (set yy=20%yy%) else (set yy=19%yy%)
set /a dd=100%dd%%%100,mm=100%mm%%%100
set /a z=14-mm,z/=12,y=yy+4800-z,m=mm+12*z-3,j=153*m+2
set /a j=j/5+dd+y*365+y/4-y/100+y/400-2472633
endlocal&set %4=%j%&goto :EOF
:DaysToDate %days% yy mm dd
setlocal ENABLEEXTENSIONS
set /a a=%1+2472632,b=4*a+3,b/=146097,c=-b*146097,c/=4,c+=a
set /a d=4*c+3,d/=1461,e=-1461*d,e/=4,e+=c,m=5*e+2,m/=153,dd=153*m+2,dd/=5
set /a dd=-dd+e+1,mm=-m/10,mm*=12,mm+=m+3,yy=b*100+d-4800+m/10
(if %mm% LSS 10 set mm=0%mm%)&(if %dd% LSS 10 set dd=0%dd%)
endlocal&set %2=%yy%&set %3=%mm%&set %4=%dd%&goto :EOF
复制代码

[ 本帖最后由 ztxby 于 2009-4-18 13:38 编辑 ]

Batcher

请把你的完整的压缩代码更新到顶楼

ztxby

代码已更新到顶楼! 麻烦观察观察

namejm

　　请仔细查找rar的帮助信息，里面有这方面的开关的：

id[c,d,p,q]   禁用信息显示

　　当然，这个帮助信息太简略了点，具体信息还得参考WinRAR安装目录下的rar.txt文件：

    -id[c,d,p,q]
            禁用消息。

            开关 -idc 禁用版权字符串。
            开关 -idd 在操作结束禁止显示“完成”字符串。
            开关 -idp 禁止百分比指示。
            开关 -idq 打开安静模式, 仅错误消息和问题能被显示。
            允许一次使用数个修饰,
            如果开关 -idcdp 是正确的。

ztxby

谢谢,这个参数可以关闭!