[文本处理] [已解决]批处理或者VBS如何把UTC时间转换为本地时间？

Batcher

20090416143849.156000+480

我想把这个UTC时间转换为本地时间。我遇到的问题在于，不知道如何获取本机所处的时区。如果能够用批处理或者VBS获取本机所处的时区（比如北京时间：GMT+8），那就好办了，给UTC时间加上对应的小时数就行了。

我尝试过修改本机时区，并监控注册表，发现系统修改了HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\TimeZoneInformation\下面的几个键值，但是我看不出这些数值的改变和时区的改变之间有什么对应关系。也就是说，不知道UTC时间加上几个小时才能得到本机系统时间。

操作系统：WinXP
系统语言：中文、英文等所有可能出现的语言

Google、论坛搜索无果。望各位指点迷津，用BAT或者VBS实现均可，多谢。

zqz0012005

Batcher 还在探究此问题啊，值得学习。
刚好前不久在verybat看到过一个WMI对象与时间有关

strUTCTime = "20090416143849.156000+480"
Set objSWbemDateTime = CreateObject("WbemScripting.SWbemDateTime")
objSWbemDateTime.Value = strUTCTime
dtmLocalTime = objSWbemDateTime.GetVarDate(true) '参数为true可以自动转换为本地时区
wsh.echo dtmLocalTime
复制代码

关于WbemScripting.SWbemDateTime的详细资料：
http://msdn.microsoft.com/en-us/library/aa393687(VS.85).aspx

everest79

20090416143849.156000+480

UTC 20090416143849.156000
GMT +8*60  +480

wmic timezone get bias的值就是时区偏移量
20090416143849.156000+480表示已经在UTC时间添加了480分的时区偏移

Batcher

感谢两位指点，受益良多。

在这个实际应用中的代码是否可以精简呢？

'cscript /nologo test.vbs
'获取上次关机的日期和时间
'我知道读取系统事件日志的方法可能显得简单些，此处不再赘述，纯粹为了学习更多知识。
strValueName = "HKLM\SYSTEM\CurrentControlSet\Control\Windows\ShutdownTime"
Set objShell = CreateObject("WScript.Shell")
intArray = objShell.RegRead(strValueName)
intTerm = intArray(7)*(2^56) + intArray(6)*(2^48) + intArray(5)*(2^40) + intArray(4)*(2^32) + intArray(3)*(2^24) + intArray(2)*(2^16) + intArray(1)*(2^8) + intArray(0)
intDays = intTerm/(1E7*86400)
dtmShutdownUTC = CDate(DateSerial(1601, 1, 1) + intDays)
'WScript.Echo dtmShutdownUTC

Set objSWbemDateTime = CreateObject("WbemScripting.SWbemDateTime")
objSWbemDateTime.SetVarDate(dtmShutdownUTC)
dtmShutdownGMT = objSWbemDateTime.GetVarDate(false)
'WScript.Echo dtmShutdownGMT

intBias = DateDiff("h", dtmShutdownGMT, dtmShutdownUTC)
'WScript.Echo intBias

dtmShutdownLocal = DateAdd("h", intBias, dtmShutdownUTC)
WScript.Echo dtmShutdownLocal
复制代码

fastslz

二者互转

 
'本地时间转换为UTC
Set SWDT = CreateObject("WbemScripting.SWbemDateTime")
SWDT.SetVarDate Now, True
Wscript.Echo SWDT
 
'UTC转换为本地时间
aNow = SWDT.GetVarDate(True)
Wscript.Echo aNow
复制代码

Batcher

这样只能进行格式转换，并未进行时区转换。
4楼的意图是时区转换，有何捷径否？

C:\Test>cscript /nologo test.vbs 20090418032409.000000+480 4/18/2009 3:24:09 AM

[ 本帖最后由 Batcher 于 2009-4-18 03:24 编辑 ]

fastslz

strValueName = "HKLM\SYSTEM\CurrentControlSet\Control\Windows\ShutdownTime"
Set objShell = CreateObject("WScript.Shell")
intArray = objShell.RegRead(strValueName)
intTerm = intArray(7)*(2^56) + intArray(6)*(2^48) + intArray(5)*(2^40) + intArray(4)*(2^32) + intArray(3)*(2^24) + intArray(2)*(2^16) + intArray(1)*(2^8) + intArray(0)
intDays = intTerm/(1E7*86400)
dtmShutdownUTC = CDate(DateSerial(1601, 1, 1) + intDays)
'WScript.Echo dtmShutdownUTC

Set SWDT = CreateObject("WbemScripting.SWbemDateTime")
SWDT.SetVarDate dtmShutdownUTC, True
SWDT.Value = Left(SWDT,21)&"+000"
dtmShutdownLocal = SWDT.GetVarDate(True)
Wscript.Echo dtmShutdownLocal
复制代码

这样也不算捷径

Batcher

感觉这个才是SWDT的直接用法，学习了。我那个太绕弯子了。

dahual

碰巧遇到这个问题要解决，就到这里来了。。。
Batcher提供的信息很有用，楼上的几个也说明了原理。通过再次搜索，了解了真相，如下。

'参考：
'http://www.windowsitpro.com/article/windows-2000/where-do-windows-2000-and-windows-nt-store-time-zone-information-.aspx
'http://www.realsoftware.com/listarchives/realbasic-nug/2004-12/msg01260.html
Option Explicit

Function GetNetTime(ByVal Url)
    Dim Bias	'时间偏移（分钟）
    Dim objHttp,objReg
    Dim DateLine,tmpDate
    Dim GTime,LocalTime
    
    'On Error Resume Next
    Set objReg=CreateObject("WScript.Shell")
    '[ActiveTimeBias]:该键值存储当前系统时间相对格林尼治标准时间的偏移（以分钟为单位）
    '[Bias]:该键值存储当前本地时间相对格林尼治标准时间的偏移（以分钟为单位）
    Bias=objReg.RegRead("HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Control\TimeZoneInformation\ActiveTimeBias")
    Set objReg=Nothing
    
	Set objHttp=CreateObject("MSXML2.XMLHTTP")
    'Set objHttp=CreateObject("Microsoft.XMLHTTP")
    With objHttp
    	.open "HEAD",Url,False
    	.send
    	DateLine=.getResponseHeader("Date")
    End With
    Set objHttp = Nothing
   	DateLine=Left(DateLine,InStr(1,DateLine,"GMT",vbTextCompare)-2)
   	'MsgBox DateLine
    tmpDate=Split(DateLine,",")
    GTime=tmpDate(1)
    LocalTime=DateAdd("n",-CLng(Bias),GTime)	'北京时间：GMT+8
    GetNetTime=LocalTime
End Function
MsgBox GetNetTime("http://www.microsoft.com")
复制代码

dahual

存储的键值相当于：Hex(DateDiff("n",Now,GTime))