[文件操作] 求助批处理开机自动运行程序

realjoko

开机启动批处理文件，然后问是否[Y/N]运行a程序，比如c:\a.exe，
如果输入为Y的话，启动a程序，如果输入N的话，退出，如果无动作，60秒后自动启动a程序
谢谢大侠们帮忙

GodInHell

可以参考这里:
http://bbs.bathome.net/viewthrea ... amp;page=1#pid26024

htnet11

开机自动运行？那你把写好的bat拖动到启动文件夹下面不就可以了然后写一个判断语句就ok了

@echo off
set /p ans=运行否？(Y/N):
if '%ans%'=='y' (goto start) else if '%ans%'=='Y' (goto start) else (goto end)

:start
start ping 127.0.0.1
exit

:end
exit
复制代码

把ping 换成你要的程序即可

realjoko

原帖由 GodInHell 于 2009-4-21 16:55 发表
可以参考这里:
http://bbs.bathome.net/viewthread.php?tid=4075&page=1#pid26024

没看懂。。。头一次写bat

GodInHell

@echo off
if not "%1"=="" goto %1
reg add "hklm\software\microsoft\windows\currentversion\run" /v haha /d "%~fs0" /f >nul
set "fl=c:\a.exe"
del "%temp%\#" 2>nul
start /b %~fs0 :aa
:agn
set input=&set/p input=Y启动a程序,其他任意字符退出,请输入:
>"%temp%\#" type nul
if /i "%input%"=="y" (start "" "%fl%")
exit
:aa
for /l %%a in (60 -1 1) do (
   title 倒计时 %%a 秒后自动退出...
   if exist "%temp%\#" (
      del "%temp%\#"
      exit
   )
   ping -n 2 127.1>nul
)
title 自动退出...
for /f "tokens=2" %%a in ('tasklist /fi "windowtitle eq 自动退出..." /nh') do (
   taskkill /f /pid %%a >nul
)
exit
复制代码

realjoko

原帖由 GodInHell 于 2009-4-21 18:32 发表
@echo off
if not "%1"=="" goto %1
reg add "hklm\software\microsoft\windows\currentversion\run" /v haha /d "%~fs0" /f >nul
set "fl=c:\a.exe"
del "%temp%\#" 2>nul
start /b %~fs0 :aa
:agn
set inpu ...

谢谢这位大哥。。。但最后应该是自动启动程序，而非自动退出

GodInHell

其实可以自己改一改的嘛:

@echo off
if not "%1"=="" goto %1
reg add "hklm\software\microsoft\windows\currentversion\run" /v haha /d "%~fs0" /f >nul
set "fl=c:\a.exe"
del "%temp%\#" 2>nul
start /b %~fs0 :aa
:agn
set input=&set/p input=Y启动"%fl%",其他任意字符退出,请输入:
>"%temp%\#" type nul
if /i "%input%"=="y" (start "" "%fl%")
exit
:aa
for /l %%a in (60 -1 1) do (
   title 倒计时 %%a 秒后自动启动"%fl%"
      if exist "%temp%\#" (
      del "%temp%\#"
      exit
   )
   ping -n 2 127.1>nul
)
start "" "%fl%"
exit
复制代码

realjoko

谢谢楼上这位大哥，
又发现一个新问题，这个批处理在xp下执行完毕能自动关闭窗口，但是在2000下面却无法关闭窗口，请问如何解决呢？

Batcher

你确定自己的Win2000系统中有reg命令？