[其他] 批处理版mysql服务器

happy886rr

自己做的mysql精简版，已含maridb，4个版本共10M。平均每个版本不足3M,还包含最新版maridb的精简版，包括日志查看器，内附自己编写的mysql管理器，可以实现非常多的管理功能，虽然是批处理，但很绿色，解压即可使用。一下子拥有4个版本的mysql，还有一个强悍的管理器，mysql5.1~mysql5.7和maridb，管理器可以3秒内重置密码，已做了兼容authentication_string，通用任何版本mysql。

下载地址：点击进入下载－MySQL精简版合集.7z

::设置窗体
mode con cols=45 lines=11
::设置颜色
color 0f
::设置MySQL控制台路径
pushd ".\bin"
::设置MySQL端口
set "po=3306"


:main
cls
echo   ______________________________
echo  ^|                              ^| 
echo  ^|#####    MySQL管理工具   #####^|
echo  ^|______________________________^|
echo   1启动   2关闭   3日志   0密码
echo.
set "cho="
set /p cho=-^> 请选择:
goto main%cho%

:main1
cls
echo   ______________________________
echo  ^|                              ^| 
echo    ###  正在启动MySQL ...
echo  ^|______________________________^|.
echo  正在检测端口占用...
netstat -ano|find "0.0.0.0:%po% " && goto warning
start .\mysqld.exe --defaults-file="..\my.ini" --port=%po%
goto main
::
:warning
echo 警告：一、可能是端口被占用，请修改bat设置
echo       二、或似MySQL已运行，查看任务管理器
pause>nul
exit

:main2
cls
echo   ______________________________
echo  ^|                              ^| 
echo    ###  准备关闭MySQL
echo  ^|______________________________^|.
set "pass="
set /p pass=-^> 请输入密码:
.\mysqladmin -P%po% -uroot -p%pass% shutdown || echo =^> 关闭MySQL失败 && pause>nul && goto main
del ..\data\%computername%.pid
goto main

:main3
start ..\tail.exe -f ..\data\%USERDOMAIN%.err
goto main

:main0
cls
echo   ______________________________
echo  ^|                              ^| 
echo    ###  修改MySQL密码
echo  ^|______________________________^|.
set "passnew="
set /p passnew=-^> 新密码:
echo   ______________^|_______________
echo  ^|                              ^| 
echo    A输原密码         B直接重置 
choice /c:AB
if %errorlevel%==1 goto passnew1
if %errorlevel%==2 goto passnew2
::
:passnew1
set "pass="
set /p pass=-^> 原密码:
.\mysqladmin -P%po% -uroot -p%pass% password %passnew% || echo =^>修改密码失败 && pause>nul && exit
goto main
::
:passnew2
if not exist ..\data\%computername%.pid (goto core)
set /p mypid=<..\data\%computername%.pid
taskkill /f /pid %mypid%
::
:core
set string=password
cls
echo   ______________________________
echo  ^|                              ^| 
echo    ###  重置MySQL密码    牢记！
echo  ^|______________________________^|.
if /i "%passnew%"=="" exit
start .\mysqld.exe --skip-grant-tables
::
:authen
echo use mysql;>.\temp
echo update user set %string%=password("%passnew%") where user="root";>>.\temp
echo flush privileges;>>.\temp
echo quit>>.\temp
mysql<.\temp || set string=authentication_string && goto authen
del .\temp
.\mysqladmin -P%po% -uroot -p%passnew% shutdown || echo =^>重置密码失败 && pause>nul && goto main
cls
choice /c:yn /m 在%po%端口上启动MySQL
if %errorlevel%==1 goto main1
if %errorlevel%==2 goto main
复制代码

codegay

效率不要太高

codegay

maridb 你自己编译的、？

happy886rr

回复 3# codegay
编译不难，难的是自己写个数据库出来。

老刘1号

XP党请自备CHOOISE……刚被坑了……

happy886rr

回复 5# 老刘1号
mysql官方说新版将不再支持xp系统，所以建议还在使用xp的用户尽快换到win7及以上系统，以达到mysql的最佳性能。另外choice高仿版可自行编译，支持0.1秒的延迟，做动画更方便。

yu2n

回复 6# happy886rr


    建議樓主還是加入 CHOOISE 吧，這樣適用性高點。

    據說 maridb 可直接替代 mysql，不置可否。

    不過現在很少玩 Apache + PHP + MySQL 了，在樓主這裡看到了 PHPnow（現改名ServKit） 的影子。

happy886rr

回复 7# yu2n
好眼力。之前写过一个choice 源码 http://www.bathome.net/thread-42591-1-1.html

老刘1号

回复 6# happy886rr


    厉害了，先赞下
会考虑升级的，感谢提醒