[文件操作] 批处理如何根据txt文本列出的文件名批量查找指定文件夹里的文件并复制到新的文件夹

vuonge

请帮忙：批处理如何批量查找文件夹并复制到指定文件夹
问题描述
1、D:\文件夹1(含有子文件夹)
2、需要查找的文件名字列表已经存储在1.txt文档中了。
3、按1.txt文档中文件名字列表批量查找文件，并复制到d:\文件夹2中。
4、如果1.txt文档中某个文件没有在D:\文件夹1(含有子文件夹)中找到，将文件名复制到另2.txt

请教该怎么写？

老刘1号

FOR+FORFILES搞定
想代写请左转有偿区或联系我。

taofan712

@echo off
for /f "delims=" %%a in (1.txt) do (
for /f "delims=" %%i in ('dir /a-d /s /b "D:\文件夹1\%%a"') do (
if "%%i"=="找不到文件" (
echo;%%a>>2.txt
set n+=1
) else (
copy /y "%%~fi" D:\文件夹2\ 
set m+=1
)
)
)
echo;找到%m%个，有%n%个没找到
pause>nul
复制代码

新手作业

45894365

回复 3# taofan712


    按照您的做法，文件是能找到，但找不到的文件没有显示到2.txt里哦，请大神再帮帮忙，谢谢！

45894365

楼主的第4点三楼貌似不能实现，请再帮帮忙~

taofan712

@echo off
for /f "delims=" %%a in (1.txt) do (
    for /f "delims=" %%i in ('dir /a-d /s /b "D:\文件夹1\%%a"^|^|echo;%%a^>^>2.txt') do copy /y "%%~fi" D:\文件夹2\ 
)
pause>nul
复制代码

nidnil

@echo off
call :t D:\1.txt D:\文件夹1 D:\文件夹2 D:\2.txt

goto :eof
:t
    for /f "usebackq delims=" %%a in (%1) do (
        for /r "%~f2" %%b in (
            "%%~nxa"
        ) do copy "%%~b" %3
        if not exist "%~3\%%~nxa" echo %%a >> %4
    )
    goto :eof

45894365

回复 7# nidnil


    完美成功了，感谢大神帮忙！！！好人一生平安。

45894365

回复 6# taofan712


    感谢大哥，成功了，好人一生平安！

pcl_test

@echo off
powershell ^
    $fileList='1.txt';^
    $notExists='2.txt';^
    $srcFolder='D:\文件夹1\';^
    $desFolder='D:\文件夹2\4567';^
    $m=@{};$s='';^
    if(-not (Test-Path -Literal $desFolder)){md $desFolder^|out-null};^
    gc $fileList^|?{$_ -notmatch '^^\s*$'}^|%%{if(!$m[$_.trim().ToLower()]){$m[$_.trim().ToLower()]=1;}};^
    dir -Literal $srcFolder -r^|?{$_ -is [System.IO.FileInfo]}^|%%{^
        $tmp=$_.Name.ToLower();^
        if($m[$tmp]){^
            if($m[$tmp] -le 1){^
                cp -Literal $_.FullName $desFolder -Force;^
            }else{^
                 ^<#处理同名文件#^>^
                $newname=$_.BaseName+'_('+($m[$tmp]-1)+')'+$_.Extension;^
                cp -Literal $_.FullName (Join-Path $desFolder $newname) -Force;^
            };^
            $m[$tmp]+=1;^
    };};^
    foreach($a in $m.keys){if($m[$a] -eq 1){$s+=$a+\"`r`n\";}};^
    if($s){Set-Content $notExists -value $s}
pause
复制代码

libin1n

请教大神：批处理如何批量查找文件夹并复制到指定文件夹
问题描述
1、D:\文件夹1(含有子文件夹)
2、需要查找的文件夹名字列表已经存储在1.txt文档中了。
3、按1.txt文档中文件夹名字列表批量查找文件夹，并复制到d:\文件夹2中。
4、如果1.txt文档中某个文件没有在D:\文件夹1(含有子文件夹)中找到，将文件名复制到另2.txt

请教该怎么写？按照上面代码复制的单独文件，现在需要复制文件夹

wudidi

回复 11# libin1n


    @echo off
for /f "tokens=*" %%a in (1.txt) do (
  if exist D:\文件夹1\%%a" (
    xcopy  D:\文件夹1\%%a" "D:\文件夹2\%%a" /Y /E /I /Q
  )
)
pause




这个是复制过去了  ，查找不到的没有列举出来