[系统相关] 批处理选择菜单中输入双引号闪退

不知道是谁

在选择菜单中，输入双引号“，会直接闪退
倒是让我找到一个解决方法，那就是开启变量延迟。这里想请教下还有什么方法能解决这个问题？

示例代码：

@echo off
:1
cls
set n=
set /p n=请输入数字（1 2）：
if "%n%"=="1" (set test=测试一)
if "%n%"=="2" (set test=测试二)
if defined test (
echo 结果是 %test%，按任意键退出. . .
pause >nul&exit
)
goto 1
复制代码

解决方法：

@echo off
setlocal enabledelayedexpansion
:1
cls
set n=
set /p n=请输入数字（1 2）：
if "!n!"=="1" (set test=测试一)
if "!n!"=="2" (set test=测试二)
if defined test (
echo 结果是 %test%，按任意键退出. . .
pause >nul&exit
)
goto 1
复制代码

/zhqsystem/zhq

set /p "a=输入怎么不退?气死你哈哈
echo,%a%

1055367558

不一定要用变量延迟。。直接改用if，else搭配就行了
@echo off
:1
cls
set n=
set /p n=请输入数字（1 2）：
if "%n%"=="1" (set test=测试一)
if "%n%"=="2" (set test=测试二) else (echo 输入错误 &ping 127.1 -n 2 >nul)
if defined test (
echo 结果是 %test%，按任意键退出. . .
pause >nul&exit
)
goto 1

不知道是谁

回复 3# 1055367558


    这个没用，输入双引号还是会闪退的，你可以测试一下
除了用变量延迟外，暂时没发现有其他什么方法

还有，行数较多的代码最好用 [code] 标记起来，被发现了说不定要扣分的

yu2n

替换双引号：

set "n=%n:"=%"
复制代码

修改后：

@echo off
:1
cls
set n=
set /p "n=请输入数字（1 2）："
set "n=%n:"=%"
if "%n%"=="1" (set test=测试一)
if "%n%"=="2" (set test=测试二)
if defined test (
echo 结果是 %test%，按任意键退出. . .
pause >nul&exit
)
goto 1
复制代码

老刘1号

回复 5# yu2n


    不严谨，比如输入""""1也会判断为一
If判断时只要"在""中成对出现就可以正常判断
所以应该是 set "var=%var:"=""%"
不改变变量内容的话，应该直接在if中予以判断
If "%var:"=""%" equ "xxx" command
同时这样还可以应对其它特殊字符

1055367558

是不是说只能开变量延迟了。。。

不知道是谁

回复 7# 1055367558


    开变量延迟是目前我已知的最简单的方法