went

文件夹按照9-10行的格式添加
set "linkFolderName序号=路径"

@echo off
REM Admin
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","REM",,"runas",1)(window.close)&exit
REM search drivers
set "drivers=C D E F G H I J K L M N O P Q R S T U V W X Y Z"
REM exe foldername
set "exeFolderName=TOOLS1112222"
REM main foldername
set "linkFolderName1=C:\Users\lenovo\Desktop\1"
set "linkFolderName2=C:\Users\lenovo\Desktop\2"
REM start
for %%i in (%drivers%) do if exist "%%i:\" ( 
	set /p="check:%%i:\%exeFolderName%   "<nul 
	if exist "%%i:\%exeFolderName%" (
		echo OK!
		set "folder=%%i:\%exeFolderName%" 
		goto :done
	) else echo not found!
)
echo -------------
for %%i in (%drivers%) do (
	cd /d "%%i:\" 2>nul && (
		echo search %%i: please wait...
		for /r /d %%a in ("*") do (
			if "%%~na" equ "%exeFolderName%" (
				set "folder=%%~a"
				goto :done
			)
		)
	)
)
:done
if "%folder%"=="" echo %exeFolderName% not found! & pause&exit
echo -------------
echo "folder=%folder%"
echo -------------
for /r "%folder%" %%i in ("*.exe") do (
	echo mklink: %%~i
	call set "exe=%%~i"
	for /f "tokens=2 delims==" %%a in ('set linkFolderName') do (
		call set "link=%%a\%exeFolderName%\%%exe:%folder%\=%%"
		call mkdir "%%link:%%~nxi=%%" >nul 2>nul
		call mklink "%%link:~0,-4%%" "%%~i" >nul
	)
)
pause&exit
复制代码

大地

回复 16# went

大神  ：

  从搜索到的TOOLS1112222的文件夹的EXE发送快捷方式至 "桌面" 和 "所有程序" 后，我还想
  从TOOLS1112222这个总文件夹中 挑选 其中三个特定的文件的快捷方式到桌面上

  TOOLS1112222\分区工具\DG.exe
                         \截图工具\nap.exe
                               \其它\QQ.exe
                                 ................

该如何添加？

大地

回复 16# went


  从搜索到的TOOLS1112222的文件夹的EXE发送快捷方式至 "桌面" 和 "所有程序" 后，我还想
  从TOOLS1112222这个总文件夹中 挑选 其中三个特定的文件的快捷方式到桌面上

  TOOLS1112222\分区工具\DG.exe
                         \截图工具\nap.exe
                               \其它\QQ.exe
                                 ................

该如何添加？

大神再帮我解决一下吧  再次感谢!!

went

回复 18# 大地
16楼代码
10行下面加上以下代码,这是特殊exe的相对路径,?分隔

REM esp exe
set "espExe=\分区工具\DG.exe?\截图工具\nap.exe?\其它\QQ.exe?\新建文件夹\handle64.exe?\新建文件夹\CPU-V.exe"
复制代码

39行下面加上以下代码

call echo %espExe% | call findstr /i /C:"%%exe:%folder%\=%%" >nul 2>nul && (
		call echo add %userprofile%\desktop
		mklink "%userprofile%\desktop\%%~ni" "%%~i" >nul
	)
复制代码

ANSI保存

大地

回复 19# went


老师  加入上面的两个代码 运行闪屏不反应，  没有加入上面两个代码时仍运行正常

went

回复 20# 大地


    ANSI编码

大地

回复 21# went



按ANSI保存不能运行无反应
按UTF-8保存，能运行，但显示在C盘根目录找不到，但实际在C盘根目录上有该文件夹
按BOM的UTF-8保存，运行一直滚动不停止
上述操作在完整版的WIN10中试也不行

went

ANSI保存,再不行我也没招了

@echo off
REM Admin
%1 start "" mshta vbscript:createobject("shell.application").shellexecute("""%~0""","REM",,"runas",1)(window.close)&exit
REM search drivers
set "drivers=C D E F G H I J K L M N O P Q R S T U V W X Y Z"
REM exe foldername
set "exeFolderName=TOOLS1112222"
REM main foldername
set "linkFolderName1=C:\Users\lenovo\Desktop\1"
set "linkFolderName2=C:\Users\lenovo\Desktop\2"
REM esp exe
set "espExe=\分区工具\DG.exe?\截图工具\nap.exe?\其它\QQ.exe"
REM start
for %%i in (%drivers%) do if exist "%%i:\" ( 
	set /p="check:%%i:\%exeFolderName%   "<nul 
	if exist "%%i:\%exeFolderName%" (
		echo OK!
		set "folder=%%i:\%exeFolderName%" 
		goto :done
	) else echo not found!
)
echo -------------
for %%i in (%drivers%) do (
	cd /d "%%i:\" 2>nul && (
		echo search %%i: please wait...
		for /r /d %%a in ("*") do (
			if "%%~na" equ "%exeFolderName%" (
				set "folder=%%~a"
				goto :done
			)
		)
	)
)
:done
if "%folder%"=="" echo %exeFolderName% not found! & pause&exit
echo -------------
echo "folder=%folder%"
echo -------------
for /r "%folder%" %%i in ("*.exe") do (
	echo mklink: %%~i
	call set "exe=%%~i"
	call echo %espExe% | call findstr /i /C:"%%exe:%folder%\=%%" >nul 2>nul && (
		call echo add %userprofile%\desktop
		mklink "%userprofile%\desktop\%%~ni" "%%~i" >nul
	)
	for /f "tokens=2 delims==" %%a in ('set linkFolderName') do (
		call set "link=%%a\%exeFolderName%\%%exe:%folder%\=%%"
		call mkdir "%%link:%%~nxi=%%" >nul 2>nul
		call mklink "%%link:~0,-4%%" "%%~i" >nul
	)
)
pause&exit
复制代码

大地

回复 23# went

大师：
这个版本很好，很实用，很方便，就是能不能用Shortcut.exe替换mklink，一个是mklink版本，一个是shortcut版本，多一个版本，多一个选择。相互取长补短，适应不同的环境，不同的系统。

went

回复 24# 大地

这是第三方工具,具体没用过