[文件操作] 求助 用批处理新建一个DOCX文件

ykhqxx

经常用新建WORD文件，有点麻烦，

想能不能通知 批处理命令自动建立 WORD文件

新的WORD文件名为  8位日期-6位时间-
同时间在代码里指定这个WORD文件的上下左右边距为2CM  页眉页脚为1CM

谢谢

wujunkai

docx文件是二进制文件，bat操作起来有点麻烦
可以考虑先保存一个WORD文件，上下左右边距为2CM  页眉页脚为1CM
然后每次新建的时候copy到相应位置。当然，copy的时候可以指定新文件名

a20150604

除了楼上说的copy方式, 另外就是把你设置好的  docx 文件内嵌进 bat, 在解出它时用时间戳命名即可

要求 win7 以上系统, 因为要调用 CertUtil 工具, 低版系统没有它
下面 代码没有内嵌一个正确的 docx 文件， 而是内嵌了一个 NUL 字符的文件(因最小的非默认空白 DOCX(0字节) 也有数 KB)

@echo off & setlocal enabledelayedexpansion
chcp 936
cd /d "%~dp0"

if "%~1" neq "" (
    CertUtil -f -encode "%~f1" b64.txt
    echo;gen BASE64 done
    pause
    exit
)

for /f %%x in ('wmic path win32_localtime get /format:list ^| findstr "="') do (
    for /f "tokens=1-2 delims==" %%a in ("%%x") do (
        set "_%%a=0000%%b"
    )
)
set "YYYYmmdd_HHiiss=%_Year:~-4%%_Month:~-2%%_Day:~-2%_%_Hour:~-2%%_Minute:~-2%%_Second:~-2%"

CertUtil -f -decode "%~f0" %YYYYmmdd_HHiiss%.docx

pause

exit

用下面的命令行(也可以把 设置好格式的docx文件 拖到本 bat 文件图标上)
CertUtil -f -encode 已经设置好格式的docx文件路径 b64.txt
将新生成的 b64.txt 的全部内容替换此行下面的全部内容

下面内容不是一个正确的 docx 文件， 而是内嵌了一个 NUL 字符的文件(因最小的非默认空白 DOCX(0字节) 也有数 KB)
-----BEGIN CERTIFICATE-----
AA==
-----END CERTIFICATE-----
复制代码