【分享】批处理版用户资料转移（个性定义）

netbenton

本程序只有一个文件，在xp系统使用
可以把用户资料复制到按用户定义的新目录，
并且修改注册表指向新目录，
因为支持个性定义，所以操作时要小心和三思

=================

支持拖拽，单项定义。

选定主目录后，

再输入编号，可继续修改单项定义

单项定义时，单项可恢复到 原来目录b 或 新目录r

 
@echo off&setlocal enabledelayedexpansion
if "%~1" equ "" goto :ag
for %%a in ("%~1") do set user=%%~dpna\
if exist "%user%\." goto :ok
:ag
set /p dec=输入要转移到目录：
if not defined dec goto :ag
for %%a in ("!dec!\") do set user=%%~dpa
if not exist "!user!." (
echo 目录不存在，要新建吗？
set /p in=输入y确认，或n重新输入，其它退出。
if /i "!in!" equ "y" goto :md
if /i "!in!" equ "n" goto :ag
goto :eof
)
goto :ok
:md
md "!user!"
if errorlevel 1 (
echo 目录格式错误，请重新运行本程序。
pause
goto :eof
)
:ok
set Tab=        &rem 这里请改为Tab键
set "@Cache=共享文档"
set "@Desktop=桌面"
set "@Favorites=常用资料"
set "@Personal=我的文档"
set "@My Music=音乐"
set "@My Pictures=图片"
set "@my Video=视频"
set "@Recent=打开记录"
set "@Cookies=Cookise数据"
set "@Store Root=电子邮件"
set "@Download Directory=下载目录"
set "@History=历史记录"
set "@Temp=临时文件"
::需要保存的项定义
set n=0
for /f "tokens=1,2* delims=%Tab%" %%a in ('echo;Temp!Tab!.!Tab!%temp%^&^
reg query "HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /s^&^
reg query "HKEY_USERS\.DEFAULT\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders" /s^&^
reg query "HKEY_CURRENT_USER\Identities\{F4E98C86-4D9A-463F-920C-1DF555C3B434}\Software\Microsoft\Outlook Express\5.0" /s') do (
for /f "tokens=*" %%d in ("%%a") do (
  set v=@%%d
  if defined !v! set/a n+=1&set "@!@%%d!=%%c"&set "!@%%d!=!user!%%~nxc"&set @!n!=!@%%d!&set !v!=
)
)
:chone
cls
echo; 原资料目录情况：
for /l %%a in (1,1,!n!) do for %%b in ("!@%%a!") do echo;%%a:%%~b：!@%%~b!
echo;
echo; 将转换!user!为主目录如下:
for /l %%a in (1,1,!n!) do for %%b in ("!@%%a!") do echo;%%a:%%~b：!%%~b!
set y=
echo;
echo;非常重要，请三思！确定吗？
set /p in=输入y确认（如果子目录不存在会自动建立），或n修改目录，输入相应数字修改其中一项，其它键退出。请输入:
if /i "!in!" equ "y" goto :zh
if /i "!in!" equ "n" goto :ag
if defined @!in! (
for %%a in (!@%in%!) do (
echo;%%a=!%%a!
echo;B 恢复原来目录；R恢复新目录；
set/p %%a=或者改为：
if /i "!%%a!" equ "b" set %%a=!@%%a!
if /i "!%%a!" equ "r" for %%b in ("!@%%a!") do set %%a=!user!%%~nxb
goto :chone
)
)
goto :eof
:zh
for /l %%a in (1,1,!n!) do for %%b in ("!@%%a!") do (
if exist "!@%%~b!" xcopy "!@%%~b!" "!%%~b!" /i /q /h /r /y 2>nul
set %%~b=!%%~b:\=\\!
)
(for /f "skip=70 tokens=1* delims=:" %%a in ('findstr /n .* "%~f0"') do (
if "%%b" equ "REGEDIT4" set y=y
if defined y echo;%%b
))>"%temp%\%~n0.reg"
regedit.exe /s "%temp%\%~n0.reg"
del /q "%temp%\%~n0.reg"
echo 转换完成，重启后生效。
pause
goto :eof

REGEDIT4

[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders]
"Cache"="!共享文档!"
"Desktop"="!桌面!"
"Favorites"="!常用资料!"
"Personal"="!我的文档!"
"My Music"="!音乐!"
"My Pictures"="!图片!"
"My Video"="!视频!"
"Recent"="!打开记录!"
"History"="!历史记录!"
"Cookies"="!Cookies数据!"

[HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\User Shell Folders]
"Cache"="!共享文档!"
"Desktop"="!桌面!"
"Favorites"="!常用资料!"
"Personal"="!我的文档!"
"My Music"="!音乐!"
"My Pictures"="!图片!"
"My Video"="!视频!"
"Recent"="!打开记录!"
"History"="!历史记录!"
"Cookies"="!Cookies数据!"

[HKEY_CURRENT_USER\Identities\{F4E98C86-4D9A-463F-920C-1DF555C3B434}\Software\Microsoft\Outlook Express\5.0]
"Store Root"="!电子邮件!"

[HKEY_USERS\.DEFAULT\Software\Microsoft\Windows\CurrentVersion\Explorer\Shell Folders]
"Desktop"="!桌面!"
"Cache"="!共享文档!"
"Download Directory"="!下载目录!"

[HKEY_CURRENT_USER\Environment]
"TEMP"="!临时文件!"
"TMP"="!临时文件!"
复制代码

[ 本帖最后由 netbenton 于 2009-10-16 18:08 编辑 ]

zhouyongjun

这个很有用，以前装完系统都要去改，曾经也想写一个
现在全部用GHOST，很久没装系统，也不用修改这个了