[文件操作] 求助批处理如何将文件按修改时间特定年代归入分类文件夹？

youxianwei

求助如何将目录下文件按修改时间特定年代归入分类文件夹？比如2000~2008夹，2009~2017夹，2018~2022夹。。。。。？最好根据用户需要自己自定义设定不同年代划分文件夹

idwma

@echo off&setlocal enabledelayedexpansion
set a=2000~2008 2009~2017 2018~2022
for /f "delims=" %%i in ('dir /b/s /a-d') do (
    for %%j in (%a%) do (
        if not exist "%%j" md "%%j"
        for /f "tokens=1,2 delims=~" %%k in ("%%j") do (
            set d=%%~ti
            set d=!d:~0,4!
            if !d! geq %%k if !d! leq %%l if not "%%i"==%0 move "%%i" "%%j"
        )
    )
)
pause
复制代码

qixiaobin0715

@echo off
set NewFolders=2000~2008 2009~2017 2018~2022
md %NewFolders% 2>nul
setlocal enabledelayedexpansion
for %%a in (%NewFolders%) do (
    set str=%%a
    for /l %%b in (!str:~,4!,1,!str:~-4!) do set _%%b=%%a
)

for /f "delims=" %%i in ('dir /b /a-d') do (
    if not "%%i"=="%~nx0" (
        set n=%%~ti
        for %%j in (_!n:~,4!) do move "%%i" "!%%j!"
    )
)
pause
复制代码

youxianwei

回复 2# idwma


    谢谢您，代码可行

youxianwei

回复 3# qixiaobin0715


    您好，运行出错，test文件都变了，并且没有移入文件夹中

qixiaobin0715

回复 5# youxianwei
有样学样，套用了2楼的“if not "%%i"==%0”这一句，环境有异，就出错了。已修改。