[文件操作] 批处理能不能把文件的名字前面分别加上前缀？

asd2813457

例如有这些Excel文件:
宿州.xlsx
淮北.xlsx
亳州.xlsx
芜湖.xlsx
淮南.xlsx
黄山.xlsx
一共 6个Excel文件,分别将他们重命名成:
收入-1.宿州.xlsx
收入-2.淮北.xlsx
收入-3.亳州.xlsx
收入-4.芜湖.xlsx
收入-5.淮南.xlsx
收入-6.黄山.xlsx
其中的"收入"希望相关代码能简单点,方便后面跟换,至于12345的排序是固定死的,后续基本不用动
麻烦各位大神了

qixiaobin0715

@echo off&setlocal enabledelayedexpansion
set var=宿州.xlsx 淮北.xlsx 亳州.xlsx 芜湖.xlsx 淮南.xlsx 黄山.xlsx
for %%a in (%var%) do (
    set /a n+=1
    ren "%%a" "收入-!n!.%%a"
)
pause
复制代码

lancer

想加什么前缀就加什么前缀，还可以选择文件格式

@echo off
title 批量增加文件名前缀
echo.
echo 本批处理可批量增加文件的文件名前缀，只处理一级目录
echo.
:AA
set "str=%~dp0"
set /p "str=输入路径（直接回车，则默认批处理所在路径）："
cd /d "%str%"
echo. &echo 当前路径为 %str%
echo.
:S
echo.&set /p strtemp3= 请输入要添加前缀的文件类型（例如*.mp4）：
echo.&set /p strtemp2= 请输入要添加前缀的文件名字符串（不变则直接回车）：
for /f "delims=" %%a in ('dir /a-d /b %strtemp3%') do (
    echo 正在修改文件 %%a 为 %strtemp2%%%a
    ren "%%~a" "%strtemp2%%%a"
)
echo.
echo 修改完成！！！
echo.
echo ===============================================================
echo.& echo 【1】……更换路径
echo.& echo 【2】……继续在当前目录替换
echo.
set /p "xuan= 请选择【1】或【2】："
echo.
if %xuan% equ 1 goto AA else(
    if %xuan% equ 2 goto S
)
echo. & pause
复制代码

asd2813457

回复 2# qixiaobin0715


    谢谢,很好用