[文件操作] [分享]批处理每隔10秒打开一个文件

Batcher

【问题描述】

我要每隔10秒打开一个文件，有必要用for吗？

:Loop
start "" "%~dp0.智胜.bat"
start "" "%~dp0.加达.bat"
start "" "%~dp0.体育.bat"
start "" "%~dp0.一号.bat"
Ping -n 10 127.1
goto Loop
复制代码

他会一次性打开全部打开
等待10秒又全部打开

Batcher

【解决方案】

test_1.bat
请参考Q-04把bat文件保存为ANSI编码：
https://mp.weixin.qq.com/s/Koje4FufWxWBs7ioDy_LJA

@echo off
for %%i in (智胜 加达 体育 一号) do (
    start "" "%~dp0.%%i.bat"
    timeout /nobreak /t 3 >nul
)
复制代码

bat1152

这样多简单，你们为什么非要用很难的for命令？

@echo off
:loop
ping -n 10 127.1>nul
start 要打开的文件
goto loop
复制代码

yakeyun

回复 2# Batcher

老大”bat1152“是老熟人，之前大号要申请管理，后面因为刷经验被封号。现在这个是小号，感觉又开始往网盘诱导和水经验了。

ANSL(2)

回复 4# yakeyun
呜呜~我的大号不知道为什么被封了!
BAt1152=Cmd1152

Batcher

【问题描述】



我想让显示会动的秒数倒计时，能不能把第二个for挪到ping后面？

【解决方案】

test_2.bat

@echo off
for %%i in (智胜 加达 体育 一号) do (
    start "" "%~dp0.%%i.bat"
    for /l %%a in (9 -1 0) do (
        echo %%a秒后继续
        ping -n 2 127.0.0.1 >nul
    )
)
复制代码

Batcher

test_3.bat
这个倒计时效果更酷一些

@echo off
for /f %%i in ('echo prompt $H ^| cmd') do (
    set "KeyBackspace=%%i"
)
for %%i in (智胜 加达 体育 一号) do (
    start "" "%~dp0.%%i.bat"
    set /p =倒计时继续：<nul
    for /l %%a in (9 -1 0) do (
        set /p =%%a<nul
        set /p =%KeyBackspace%<nul
        ping -n 2 127.0.0.1 >nul
    )
    echo,
)
复制代码