[系统相关] 批处理怎么获取操作系统型号

jshuanya

求批处理怎么获取操作系统型号的语句，网上看到很多都不能识别现在的win 10 ，win 11了。

gfd

ver
wmic os
wmic os get Caption

jshuanya

ver
wmic os
wmic os get Caption
gfd 发表于 2024-1-19 14:05

能否直接导出其中的操作系统，最好是包含多少位的，是32位还是64位

gfd

回复 3# jshuanya


    http://www.bathome.net/thread-68226-1-1.html

gfd

回复 3# jshuanya

@echo off
setlocal enabledelayedexpansion

for /f "tokens=1* delims=:=" %%a in ('"wmic os get Caption,InstallDate,OSArchitecture,Version /Format:List"') do (
    IF /I "%%a"=="Caption" set Caption=%%b
    IF /I "%%a"=="InstallDate" set InstallDate=%%b
    IF /I "%%a"=="OSArchitecture" set OSArchitecture=%%b
    IF /I "%%a"=="Version" set Version=%%b
)
echo Windows_信息：%Caption%%Version% 【%OSArchitecture%】 安装日期：%InstallDate:~0,4%年%InstallDate:~4,2%月%InstallDate:~6,2%日_%InstallDate:~8,2%点%InstallDate:~10,2%分%InstallDate:~12,2%秒
echo.
pause
复制代码

jshuanya

回复 5# gfd

牛，非常好用。

hfxiang

把5楼的脚本变换了一下（只变了for的表述形式，本质完成一样）

@echo off
for /f "tokens=* delims=:=" %%a in ('"wmic os get Caption,InstallDate,OSArchitecture,Version /Format:List"^|findstr ^=') do set "%%~a"
echo Windows_信息：%Caption%%Version% 【%OSArchitecture%】 安装日期：%InstallDate:~0,4%年%InstallDate:~4,2%月%InstallDate:~6,2%日_%InstallDate:~8,2%点%InstallDate:~10,2%分%InstallDate:~12,2%秒
echo.
pause
复制代码

jshuanya

把5楼的脚本变换了一下（只变了for的表述形式，本质完成一样）
hfxiang 发表于 2024-1-21 16:06

    也可以用哦。谢谢。