[文件操作] 【已解决】文件夹中有以下规率的图片，是否可以批处理建文件夹放在一起吗？

228630386

文件夹中有很多类似以下规率的图片，是否可以批处理建文件放在一起吗？将第二条下划线前名称一致新建文件夹2H17CBCL_BARDEAEX将图片移动到前缀相同的文件夹中，如此类推。
2H17CBCL_BARDEAEX_1.jpg
2H17CBCL_BARDEAEX_2.jpg
2H17CBCL_BARDEAEX_3.jpg
2H17CBCL_BARDEAEX_4.jpg
2H17CBCL_BARDEAEX_5.jpg
2H17CBCL_BARDEAEX新建文件夹移入上图片

1H18SBLL_AAEKGREY_1.jpg
1H18SBLL_AAEKGREY_2.jpg
1H18SBLL_AAEKGREY_3.jpg
1H18SBLL_AAEKGREY_4.jpg
1H18SBLL_AAEKGREY_5.jpg
1H18SBLL_AAEKGREY_6.jpg
1H18SBLL_AAEKGREY新建文件夹移入上图片

aloha20200628

回复 1# 228630386

@echo off &for /f "tokens=1-2* delims=_" %%a in ('dir /b/a-d *_*_*.jpg') do (
	if not exist "%%a_%%b" md "%%a_%%b"
	move /y "%%a_%%b_%%c" "%%a_%%b\"
)
pause&exit/b
复制代码

ShowCode

回复 1# 228630386

@echo off
for /f "tokens=1-2* delims=_" %%a in ('dir /b /a-d *_*_*.jpg') do (
    md "%%a_%%b" 2>nul
    move /y "%%a_%%b_%%c" "%%a_%%b\"
)
复制代码

228630386

回复 2# aloha20200628


    可以了，非常感谢！

228630386

回复 3# ShowCode


       可以了，非常感谢！

aloha20200628

确实可以不用延迟变量...

77七

@echo off
cd /d "%~dp0"
for /f "tokens=1-2 delims=_" %%a in ('dir /b /a-d "*_*_*.jpg"') do (
	if exist "%%a_%%b_*.jpg" (
		md "%%a_%%b" 2>nul
		move "%%a_%%b_*.jpg" "%%a_%%b\"
	)
)
pause
复制代码