[文本处理] [分享]利用鲁大师组件生成日志并提取硬件信息/附精简脚本

yakeyun

一：硬件信息提取脚本

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"
taskkill /f /t /IM ComputerZService.exe 1>nul 2>nul
taskkill /f /t /IM ComputerzService_x64.exe 1>nul 2>nul
taskkill /f /t /IM hdw_disk_scan.exe 1>nul 2>nul
taskkill /f /t /IM Display3DEx.exe 1>nul 2>nul
if exist .\LDS_CS\LuDaShi\Log\*.* (del .\LDS_CS\LuDaShi\Log\*.*)
Start /min .\LuDaShi\ComputerZService.exe HardwareDll.dll

echo 硬件信息获取中，请稍等...
timeout -t 1 >nul
:top
echo %time%_获取硬件信息中，请稍等...
set "keyword=GetBatteryJson"
(type ".\LuDaShi\log\ComputerZ_HardwareDll.log" | find /i "!keyword!" || (goto top)) 

cls

for /f "tokens=*" %%a in ('powershell -Command "(Get-WmiObject -Class Win32_OperatingSystem | Select-Object -ExpandProperty Caption)"') do set "OS=%%a"

set top=[硬件参数]
chcp 65001 >nul
set DiskNumber=0
set AudioNumber=0
set MemoryNumber=0
set Order=findstr /i /l /c:"[overviewinfowrapper] CPUName :" /c:"[memory] SpdOverview." /c:"[gpuprocesser] VideoAdapter" /c:"[motherboard] GetMotherboardInfo:" /c:"[monitor] find primary monitor" /c:"[disk] ModelNumber" /c:"[network_card] GetNetworkInfo: NetworkParams.strDescription" /c:"[uldsdbhelper] Match: 6, GetDeviceName: Vendor=10EC" "LuDaShi\Log\ComputerZ_HardwareDll.log"
for /f "tokens=9-12 delims=]:=" %%a in ('%Order%') do (
    set str=%%a
    set str=!str:~1,4!
    if "!str!"=="CPUN" (
        set CPUName=%%b
    ) else if "!str!"=="GetM" (
        set MotherboardInfo=%%b
    ) else if "!str!"=="GetN" (
        for /f "tokens=2 delims=[" %%i in ("%%b") do (
            if not defined _%%i set /a NetworkNumber+=1
            set Network%%i=%%d
            set _%%i=true
        )
    ) else if "!str!"=="Mode" (
        set Disk!DiskNumber!Number=%%c
        set /a DiskNumber+=1
    ) else if "!str!"=="Mult" (
        for /f "tokens=2 delims=@" %%i in ("%%b") do set Audio!AudioNumber!Number=%%i
        set /a AudioNumber+=1
    ) else if "!str!"=="SpdO" (
        for /f "tokens=2 delims=. " %%i in ("%%a") do set Memory!MemoryNumber!Name=%%d
        set /a MemoryNumber+=1
    ) else if "!str!"=="Vide" (
        set VideoAdapter=%%b
    ) else if "!str!"=="find" (
        set monitor=%%b
    )
)
(
echo %top%
echo SysBet=%OS%
set CPUName
set MemoryNumber
set MemoryNumber=
set Memory
set VideoAdapter
set MotherboardInfo
set monitor
set DiskNumber
set DiskNumber=
set Disk
set NetworkNumber
set NetworkNumber=
set Network
)>sysinfo.ini
echo.
echo.
type sysinfo.ini
timeout -t 2 >nul
taskkill /f /t /IM ComputerZService.exe 1>nul 2>nul
taskkill /f /t /IM ComputerzService_x64.exe 1>nul 2>nul
taskkill /f /t /IM hdw_disk_scan.exe 1>nul 2>nul
::del sysinfo.ini
::del LuDaShi\log\ComputerZ_HardwareDll.log
echo.

PAUSE>nul
exit
复制代码

下载链接：https://sanli.lanzoue.com/b0fp21yve
密码:6u3k

二、鲁大师组件精简脚本

@echo off
setlocal enabledelayedexpansion
cd /d "%~dp0"

title 鲁大师文件精简工具 by.SanLi
color 07
::mode con: cols=80 lines=25
chcp 936 >nul
echo,①请拷贝老版本鲁大师”LuDaShi“目录，到本目录，然后回车执行获取文件列表 & pause
(for /f "tokens=* delims=, " %%f in ('dir /a /s /b %targetPath%\LuDaShi\*.*') do echo %%f)>"lds_list.txt"
echo,②请删除老版本鲁大师目录，或者修改”LuDaShi“文件夹名称为其它。回车继续 & pause
echo,③请拷贝新版本鲁大师”LuDaShi“目录，到本目录，然后回车执行获取文件列表 & pause
(for /f "tokens=* delims=, " %%f in ('dir /a /s /b %targetPath%\LuDaShi\*.*') do echo %%f)>"del_list.txt"
title 鲁大师文件精简精简中，请稍等...
set keywords=del_list.txt
set target=lds_list.txt

for /f "tokens=*" %%a in (%keywords%) do (
    findstr /C:%%a %target% >nul
    if not !errorlevel! equ 0 (
    echo y | del "%%a"
    echo 删除文件：%%a
)
)
title 鲁大师文件精简工具 by.SanLi
endlocal
echo,④继续精简，删除空目录
set "del_dir=%~dp0\LuDaShi\"
for /f "delims=" %%s in ('dir /ad/s/b "%del_dir%" ^|sort /r') do rd "%%s" 2>nul
echo,& echo,精简完毕，目标目录为”LuDaShi“文件夹 &echo,
pause
复制代码

三、附上精简列表[lds_list.txt]，方便直接调用：
D:\Desktop\LDS_CS_NEW\LuDaShi\ComputerZ.dat
D:\Desktop\LDS_CS_NEW\LuDaShi\ComputerZ.set
D:\Desktop\LDS_CS_NEW\LuDaShi\ComputerZService.exe
D:\Desktop\LDS_CS_NEW\LuDaShi\ComputerZTray.exe
D:\Desktop\LDS_CS_NEW\LuDaShi\ComputerZ_HardwareDll.dll
D:\Desktop\LDS_CS_NEW\LuDaShi\ComputerZ_x64.sys
D:\Desktop\LDS_CS_NEW\LuDaShi\CustDev.dat
D:\Desktop\LDS_CS_NEW\LuDaShi\DataMgr.dll
D:\Desktop\LDS_CS_NEW\LuDaShi\DataMgr_x64.dll
D:\Desktop\LDS_CS_NEW\LuDaShi\HardwareEx_x64.dll
D:\Desktop\LDS_CS_NEW\LuDaShi\HWCaches.dat
D:\Desktop\LDS_CS_NEW\LuDaShi\log
D:\Desktop\LDS_CS_NEW\LuDaShi\Monitors.dat
D:\Desktop\LDS_CS_NEW\LuDaShi\motherboard.dat
D:\Desktop\LDS_CS_NEW\LuDaShi\NetBridge.dll
D:\Desktop\LDS_CS_NEW\LuDaShi\netul.dll
D:\Desktop\LDS_CS_NEW\LuDaShi\netul64.dll
D:\Desktop\LDS_CS_NEW\LuDaShi\Perfmon.dll
D:\Desktop\LDS_CS_NEW\LuDaShi\sites.dll
D:\Desktop\LDS_CS_NEW\LuDaShi\SiteUIHelper.dll
D:\Desktop\LDS_CS_NEW\LuDaShi\Utils
D:\Desktop\LDS_CS_NEW\LuDaShi\log\ComputerZ_HardwareDll.log
D:\Desktop\LDS_CS_NEW\LuDaShi\Utils\dll_service.exe

yakeyun

回复 1# yakeyun

占楼占用，其它提取项目可以自行添加，最终会在本地生成一个配置文件，方便用其它语言写硬件检测工具时直接调用。
其[sysinfo.ini]格式类容如下：

[硬件参数]
SysBet=Microsoft Windows 11 家庭中文版
CPUName=英特尔 Core i5-8600T @ 2.30GHz 六核
MemoryNumber=1
Memory0Name=英睿达 DDR4 2133MHz 8GB
VideoAdapter=Intel(R) UHD Graphics 630 ( 1 GB / 华硕 )
MotherboardInfo=华硕 PRIME B365M-K
monitor= 惠科 HKC0000 ( 23.6 英寸  )
DiskNumber=1
Disk0Number= 影驰 GALAX T0240A (固态硬盘)
NetworkNumber=2
Network0= 瑞昱 Realtek RTL8852BE WiFi 6 802.11ax PCIe Adapter / Azurewave
Network1= 瑞昱 RTL8168/8111/8112 Gigabit Ethernet Controller / 华硕