[文本处理] [已解决]批处理如何批量文本替换？

mrhxn

一大堆KSC文件：
karaoke.tag('歌名', '爱是你我');
karaoke.tag('缩写', 'ASNW');
karaoke.tag('歌手', '刀郎');
karaoke.tag('字数', '4');
karaoke.tag('语种', '国语');
karaoke.tag('歌类', '男人');
karaoke.tag('电影', 'false');
karaoke.tag('风格', '流行');
karaoke.tag('流行', 'true');
karaoke.tag('音量', '80');
karaoke.tag('声道', '0');
karaoke.tag('语音', '0');
karaoke.tag('流行', 'true');
karaoke.tag('介质', 'true');
karaoke.tag('时间', '2009-9-17');
karaoke.tag('歌星拼音', 'DL');
karaoke.mtvmode :=true;
karaoke.videofilename := '';
karaoke.audiofilename := '*.wav';
karaoke.XSDVideoMode := 4;
karaoke.CommonVideo := '刀郎-爱是你我.mpg';
.......
现在的问题是KSC文件中的这行 karaoke.tag('歌类', '男人'); 需要将男人改为固定字符，而男人是变化的,也可能是其它的,比如乐队
请问如何处理？另外,如果男人是固定的,我可以处理:

@echo off
setlocal disabledelayedexpansion
set "old=男人"
set "new=女人"
(for /f "delims=" %%k in ('dir /a /b *.ksc') do (
  for /f "delims=" %%a in ('findstr /n .* %%k') do (
  set var=%%a
  setlocal enabledelayedexpansion
  if "!var:*:=!"=="" (echo;) else (
    set var=!var:*:=!
    echo;!var:%old%=%new%!
  )
  endlocal
))>"#%%k"
)
pause
复制代码

vsbat

将男人改为固定字符

@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in (1.ksc) do (
set "t=%%i"
set "t=!t:男人=指定字符!"
echo !t!>>result.txt
)
pause
复制代码

mrhxn

原帖由 vsbat 于 2010-3-10 23:48 发表
将男人改为固定字符
@echo off
setlocal enabledelayedexpansion
for /f "delims=" %%i in (1.ksc) do (
set "t=%%i"
set "t=!t:男人=指定字符!"
echo !t!>>result.txt
)
pause

问题是这个男人是可变的.不过还是谢谢帮忙

batman

我说两种方法吧：
第一种：如果所有ksc文件的格式都是一样的，即“歌类”都在第6行：

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /a-d /b /s *.ksc') do (
     set /a n=0
    ( for /f "delims=" %%b in (%%a) do (
           set /a n+=1
           if !n! neq 6 (
              echo %%b                 
              ) else (
              echo karaoke.tag('歌类', '固定字符');
             )
      ))>%%a
)
复制代码

第二种：如果“歌类”不是都在第6行

@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /a-d /b /s *.ksc') do (
    ( for /f "delims=" %%b in (%%a) do (
          set "str=%%b"
          if "!str:歌类=!" neq "!str!" (
             echo karaoke.tag('歌类', '固定字符');
             ) else (
             echo %%b
         )
      ))>%%a
)
          
复制代码

mrhxn

原帖由 batman 于 2010-3-11 09:42 发表
我说两种方法吧：
第一种：如果所有ksc文件的格式都是一样的，即“歌类”都在第6行：@echo off&setlocal enabledelayedexpansion
for /f "delims=" %%a in ('dir /a-d /b /s *.ksc') do (
     set /a n=0
    ( ...

第二种不能运行，一闪而过，正好需要第二种，谢谢帮忙。

BatCoder

原帖由 mrhxn 于 2010-3-11 11:04 发表
第二种不能运行，一闪而过，正好需要第二种，谢谢帮忙。

你就需要这种不能运行的？

mrhxn

原帖由 BatCoder 于 2010-3-11 13:24 发表

你就需要这种不能运行的？

笑话，我是请求帮忙。意思是正需要这样的处理，却不能运行。只是感谢朋友的帮忙。

test2010

@echo off
for %%A in (*.ksc) do (
    (for /f "usebackq delims=, tokens=1,*" %%a in ("%%A") do (
        if /i "%%a"=="karaoke.tag('歌类'" (
            echo karaoke.tag('歌类', '固定字符'^);
        ) else (
            if "%%b"=="" (echo %%a) else echo %%a,%%b
        )
    )) > ksc.tmp
    move ksc.tmp "%%A"
)
pause
复制代码

mrhxn

原帖由 test2010 于 2010-3-11 18:47 发表
@echo off
for %%A in (*.ksc) do (
    (for /f "usebackq delims=, tokens=1,*" %%a in ("%%A") do (
        if /i "%%a"=="karaoke.tag('歌类'" (
            echo karaoke.tag('歌类', '固定字符'^);
    ...

可以实现!谢谢est2010 batman vsbat 热心帮忙解决.