[日期时间] 批处理计算星期为什么只有2012年2月20日显示不正常？

andersen12

我是根据W的值来计算星期几的，只有到了2012年2月20日显示不正常，明明是星期一，算出的值缺是2，前后几天都是正常，请教高人指点啊！

@echo off

set /a y = %date:~0,4%
if %date:~5,1% EQU 0 set /a m = %date:~6,1%
if %date:~5,1% NEQ 0 set /a m = %date:~5,2%
if %date:~8,1% EQU 0 set /a d = %date:~9,1%
if %date:~9,1% NEQ 0 set /a d = %date:~8,2%
if %m% EQU 1 set /a m = 13
if %m% EQU 2 set /a m = 14

set /a w = (d + 2*m+3*(m+1)/5+y+y/4-y/100+y/400) - ((d + 2*m+3*(m+1)/5+y+y/4-y/100+y/400)/7)*7 + 1

set /a yy = (y - 4*(y/4))
if %m% EQU 13 if %yy% EQU 0 set /a w = w -2
if %m% EQU 14 if %yy% EQU 0 set /a w = w -2
if %m% EQU 13 if %yy% NEQ 0 set /a w = w - 1
if %m% EQU 14 if %yy% NEQ 0 set /a w = w - 1
if %w% EQU -1 set /a w = 6
if %w% EQU 0 set /a w = 7

@echo %w%
复制代码

applba

居然有人这么做……

CrLf

那两句 if neq 的判断没有必要，反而有逻辑错误，应写成：

if %date:~5,1% EQU 0 (set m=%date:~6,1%) else set m=%date:~5,2%
if %date:~8,1% EQU 0 (set d=%date:~9,1%) else set d=%date:~8,2%
复制代码

或者按惯例直接写成一句：

set /a m=1%date:~5,2%-100,d=1%date:~8,2%-100
复制代码

另，也写过日期转星期的函数，如下：

:::::::::::::::weeks 日期转星期函数::::::::::::::::::
:: 用法：                                          ::
::  call :weeks Date retvar                        ::
::        %1  Date    要计算的日期，不判断是否合法 ::
::                    格式（YYYYMMDD）             ::
::        %2  retvar  用于保存星期（1~7）的变量名  ::
:::::::::::::::::::::::::::::::::::::::::::::::::::::

:weeks Date retvar   ###### 公式算法
setlocal disabledelayedexpansion&set "date=%~1"
set /a m=1%date:~4,2%-100,m+=!(m/3)*12,w=(7%date:~6,2%+2*m+3*(m+1)/5+(y=%date:~,4%-m/13)+y/4-y/100+y/400)%%7+1
set "%~2=%w%"
复制代码

applba

明明是星期二

andersen12

谢谢版主，问题解决了！