批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程
[批处理文件精品]批处理版照片整理器[批处理文件精品]纯批处理备份&还原驱动在线第三方下载
返回列表 发帖

[转贴] VBScript脚本设置JDK+Tomcat环境变量

  1. '=================================================================================
  2. ' 名称:Tomcat5.5.20 + jdk1.5.0_06 + struts1.2 系统环境变量设置程序
  3. ' 功能:本程序自动设置 TOMCAT_HOME, CATALINA_HOME, JAVA_HOME, CLASSPATH, PATH等环
  4. '       境变量如果您以前已经设置过相关环境变量,本程序将覆盖相关设置,如果用到了
  5. '       Struts,将将相关文件复制到 %TOMCAT_HOME%\Common\lib 下面。
  6. ' 作者:HLDGAOFENG
  7. ' 日期:2008-09-17
  8. '=================================================================================
  9. ' 修改这两个常量为你自己的路径,如果为空,将在运行时提示你选择路径。
  10. ' --------------------------------------------------------------------------------
  11. ' TOMCAT HOME
  12. Const TOMCAT_HOME = ""
  13. ' JDK HOME
  14. Const JAVA_HOME = ""
  15. ' --------------------------------------------------------------------------------
  16. ' 定义相关变量
  17. Dim sTomcatHome
  18. Dim sJavaHome
  19. Dim sClassPath
  20. Dim sPath
  21. ' 创建 Shell 对象,以便操作系统环境变量
  22. Dim wsh, envSystem, shell, selFolder, selFolderItem
  23. Set wsh = WScript.CreateObject("WScript.Shell")
  24. Set envSystem = wsh.Environment("system")
  25. Set shell = CreateObject("Shell.Application")
  26. ' 如果没有指定 TOMCAT_HOME 则弹出浏览目录窗口让用户选择一个
  27. If TOMCAT_HOME = "" Then
  28.     Set selFolder = shell.BrowseForFolder(0, "请选择 TOMCAT_HOME 目录:" & _
  29.     vbCrLf & "如:C:\apache-tomcat-5.5.20", 0, ssfDRIVES)
  30.     If selFolder Is Nothing Then WScript.Quit
  31.     Set selFolderItem = selFolder.Self
  32.     sTomcatHome = selFolderItem.Path
  33. Else
  34.     sTomcatHome = TOMCAT_HOME
  35. End If
  36. ' 如果没有指定 JAVA_HOME 则弹出浏览目录窗口让用户选择一个
  37. If JAVA_HOME = "" Then
  38.     Set selFolder = shell.BrowseForFolder(0, "请选择 JAVA_HOME 目录:" & _
  39.     vbCrLf & "如:C:\Program Files\Java\jdk1.5.0_06", 0, ssfDRIVES)
  40.     If selFolder Is Nothing Then WScript.Quit
  41.     Set selFolderItem = selFolder.Self
  42.     sJavaHome = selFolderItem.Path
  43. Else
  44.     sJavaHome = JAVA_HOME
  45. End If
  46. ' CLASS_PATH 一般配置。(*)我不太清楚要用到struts的其它包,如果用到,自己将相关包加到里面吧。
  47. ' .;d:\struts\commons-logging.jar;d:\struts\antlr.jar;d:\struts\jakarta-oro.jar;d:\struts\commons-digester.jar;D:\struts\commons-validator.jar;D:\struts\struts.jar;D:\struts\commons-beanutils.jar
  48. sClassPath = ".;" & _
  49.              "%JAVA_HOME%\lib\tools.jar;" & _
  50.              "%JAVA_HOME%\lib\dt.jar;" & _
  51.              "%JAVA_HOME%\lib\mysql-connector-java-3.0.14-production-bin.jar;" & _
  52.              "%CATALINA_HOME%\common\lib\servlet-api.jar;" & _
  53.              "%CATALINA_HOME%\common\lib\struts.jar;"
  54. ' 得到原来的 path 系统环境变量,再加上 %CATALINA_HOME%\common\lib;%JAVA_HOME%\bin;
  55. sPath = envSystem("PATH")
  56. If InStr(1, LCase(sPath), "%catalina_home%\common\lib") < 1 Then
  57.     sPath = "%CATALINA_HOME%\common\lib;" & sPath
  58. End If
  59. If InStr(1, LCase(sPath), "%java_home%\bin") < 1 Then
  60.     sPath = "%JAVA_HOME%\bin;" & sPath
  61. End If
  62. ' 再次请用户确认之后再进行修改
  63. If MsgBox("正准备将您的 JAVA_HOME 系统环境变量设置为:" & vbCrlf & _
  64.     sJavaHome & vbCrlf & vbCrlf & _
  65.     "正准备将您的 CATALINA_HOME,TOMCAT_HOME 系统环境变量设置为:" & vbCrlf & _
  66.     sTomcatHome & vbCrlf & vbCrlf & _
  67.     "正准备将您的 CLASSPATH 系统环境变量设置为:" & vbCrlf & _
  68.     sClassPath & vbCrlf & vbCrlf & _
  69.     "正准备将您的 PATH 系统环境变量设置为:" & vbCrlf & _
  70.     sPath & vbCrlf & vbCrlf & _
  71.     "您确定要继续吗?", vbYesNo + vbQuestion + vbDefaultButton2, "收集信息完成,正准备设置环境变量……") <> vbYes Then
  72.     WScript.Quit
  73. End If
  74. ' 设置系统环境变量
  75. envSystem("TOMCAT_HOME") = sTomcatHome
  76. envSystem("CATALINA_HOME") = sTomcatHome
  77. envSystem("JAVA_HOME") = sJavaHome
  78. envSystem("CLASSPATH") = sClassPath
  79. envSystem("PATH") = sPath
  80. MsgBox "环境变量已经设置成功!", vbinformation
  81. set wsh = nothing
复制代码


http://dongbian.blog.51cto.com/2694115/701486

返回列表