[文件操作] 批处理操作文件夹升级版

andrew3000

批处理操作文件夹

上次已经发帖询问了一次，http://www.bathome.net/thread-24302-1-2.html
本以为可以交差，但是又有新的要求提出，自己对照着改动了下代码，还是没有达到预期的效果，所以，

再次发帖求助下。



在同一级目录下，有N个文件夹，文件夹名称有如下规律

1）文件夹名称，一般形式采用单个大写字母+数字+“--中文”的形式。
   如： C025--参考工具书
        D146.35--海洋起源
        X443.234.4--航天工程

   文件夹特殊形式：
   1.英文大写字母+“-”+数字+“--中文”
     如：T-1--建筑史
         B-3--批处理代码

   2.由于版本的问题，此版本中包含上一版本中遗留的问题，也就是此版本对于上一版本的改动有明确标注，文件夹名称格式有如下两种情况：
   a.使用[]
     b.使用{}
   如： [A253.34]--环境
        {B346.28}--家畜
        [T-34]--种植
        {U-56}--技术


2）文件夹名称中，字母+数字的部分有类似于如下的规律
   A0，A01，A012，A013，A013.1,....
            A02，A023，A025，A025.7，....
     A1，A13，A135，A135.6,.....

3）如果文件夹名称中带小数点，规律是每个三个数字带个小数点，如：A015.273.4，最多会出现两个小

数点。

4）文件夹名称中的中文各不相同。

5）在对文件夹进行操作时，忽略掉{}及[]这类符号，按照其中包含的文件夹名称进行排序归类。

最终用批处理处理的文件夹结构树如下：

├─A-1--批处理
├─A-2--论坛
├─A-3--求学
├─A0--为何
│  ├─A01--有时
│  │  ├─A012--学习
│  │  └─[A013]--批处理
│  │      └─A013.1--感到
│  └─A02--很吃力
│      ├─A023--是因为
│      └─{A025}--资质
│          └─A025.7--愚钝
│              ├─A025.7.3--还是
│              └─A025.7.4--因为
└─A1--不够
    └─[A13]--聪明
        └─A135--苍天
            └─{A135.6}--求解

tmplinshi

@echo off
setlocal enabledelayedexpansion

for /f "tokens=*" %%a in (' dir /a:d /b *--* ') do (

        rem 把文件名中的“--”替换成“|”
        set FullName=%%a
        set "FullName=!FullName:--=|!"

        rem 用“|”分割左右字符
        for /f "tokens=1,2 delims=|" %%a in ("!FullName!") do (                
                set name_left=%%a
                set name_right=%%b
        )

        rem 去掉 []{}-
        for /f "delims=[]{}" %%a in ("!name_left!") do (
                set name_left_clean=%%a
                set name_left_clean=!name_left_clean:-=!
        )

        rem ============================
        rem 把“--”前面的字符，再次以第一个“.”进行分解
        rem ============================
        rem
        for /f "tokens=1,* delims=." %%i in ("!name_left_clean!") do (
                set dir1=%%i
                set dir2=%%j
        )

        rem ============================
        rem 计算第一个“.”前面的字符个数
        rem ============================
        rem
        set str=!dir1!
        
        rem -------------- 计算字符个数 --------------
        set len=0

        for %%a in (2048 1024 512 256 128 64 32 16) do (
                if "!str:~%%a!" neq "" (
                        set /a len += %%a
                        set str=!str:~%%a!
                )
        )
        set str=!str!fedcba9876543210
        set /a len += 0x!str:~16,1!
        rem -------------------------------------------

        rem ============================
        rem 构建文件夹
        rem ============================
        rem
        set L=!dir1:~0,1!
        set d1=.
        for /l %%a in (1 1 !len!) do (
                set d1=!d1!\!L!!dir1:~1,%%a!
        )

        set d2=
        if defined dir2 (
                set _str=!dir1!
                for %%a in (!dir2:.^=,!) do (
                        set d2=!d2!\!_str!.%%a
                        set _str=!_str!.%%a
                )
        )

        set final_dir=!d1!!d2!

        rem ============================
        rem 创建文件夹，并移动文件夹
        rem ============================
        rem
        md "!final_dir!" 2>nul
        move "%%a" "!final_dir!"

        rem ============================
        rem 显示结果
        rem ============================
        rem
        echo "%%a"
        echo         md "!final_dir!"
        echo         move "%%a" "!final_dir!"
        echo ----------------------------------------
)

echo,
echo 完成！请按任意键退出...
pause >nul
复制代码

运行批处理后的目录树结构：

├─A0
│  ├─A0--为何
│  ├─A01
│  │  ├─A01--有时
│  │  ├─A012
│  │  │  └─A012--学习
│  │  └─A013
│  │      ├─A013.1
│  │      │  └─A013.1--感到
│  │      └─[A013]--批处理
│  └─A02
│      ├─A02--很吃力
│      ├─A023
│      │  └─A023--是因为
│      └─A025
│          ├─A025.7
│          │  ├─A025.7--愚钝
│          │  ├─A025.7.3
│          │  │  └─A025.7.3--还是
│          │  └─A025.7.4
│          │      └─A025.7.4--因为
│          └─{A025}--资质
├─A1
│  ├─A-1--批处理
│  ├─A1--不够
│  └─A13
│      ├─A135
│      │  ├─A135--苍天
│      │  └─A135.6
│      │      └─{A135.6}--求解
│      └─[A13]--聪明
├─A2
│  └─A-2--论坛
└─A3
    └─A-3--求学

andrew3000

回复 2# tmplinshi


    多谢版主大大，代码运行后和我最终想要的结构树还有些差距，还是用笨办法TC一个一个的操作吧。。。。不过这段代码够我研究一阵子的了。。。

terse

@echo off&setlocal enabledelayedexpansion
for /f "tokens=1* delims=-" %%a in ('dir /ad /b *--*') do (
    for /f "tokens=1* delims=-" %%i in ("%%b") do (
        if "%%j" == "" (
           set s=%%a&set name=%%a--%%b
        ) else set s=%%a-%%i&set name=%%a-%%b
    )
    for /f "delims=[{}]" %%i in ("!s!") do (
        if "!s!" neq "%%i" set s=%%i
    )
      set len=1&set s1=!s!
      for %%i in (32 16 8 4 2 1) do (
          if "!s1:~%%i!" neq "" (
             set /a "len+=%%i"
             set "s1=!s1:~%%i!"
          )
      )
      set f=
      for /l %%i in (2 1 !len!) do (
          set i=!s:~,%%i!
          if "!i:~-1!" neq "." (
             if "!i:~-1!" neq "-" set f=!f!!i!\
          ) 
      )
      md "!f!" 2>nul
      move "!name!" "!f!"
)
pause
复制代码

andrew3000

回复 4# terse


    非常抱歉，工作忙有段时间没上来了。。。您写的代码运行了一下，提示报错。。。“系统找不到指定的文件”。。。而且，即使是有个别的文件夹移动成功了，也和最终想要的文件树有些许差异。。。

terse

可能当时测试范围小导致有考虑不到的情况
先说测试情况
未有 你说的找不到文件的提示
除非你的文件夹不带有--
运行代码前

:.
├─A-1--批处理
├─A-2--论坛
├─A-3--求学
├─A0--为何
├─A01--有时
├─A012--学习
├─A013.1--感到
├─A02--很吃力
├─A023--是因为
├─A025.7--愚钝
├─A025.7.3--还是
├─A025.7.4--因为
├─A1--不够
├─A135--苍天
├─[A013]--批处理
├─[A13]--聪明
├─{A025}--资质
└─{A135.6}--求解
复制代码

运行后

:.
├─A-1
│  └─A-1--批处理
├─A-2
│  └─A-2--论坛
├─A-3
│  └─A-3--求学
├─A0
│  ├─A0--为何
│  ├─A01
│  │  ├─A01--有时
│  │  ├─A012
│  │  │  └─A012--学习
│  │  └─A013
│  │      ├─A013.1
│  │      │  └─A013.1--感到
│  │      └─[A013]--批处理
│  └─A02
│      ├─A02--很吃力
│      ├─A023
│      │  └─A023--是因为
│      └─A025
│          ├─A025.7
│          │  ├─A025.7--愚钝
│          │  ├─A025.7.3
│          │  │  └─A025.7.3--还是
│          │  └─A025.7.4
│          │      └─A025.7.4--因为
│          └─{A025}--资质
└─A1
    ├─A1--不够
    └─A13
        ├─A135
        │  ├─A135--苍天
        │  └─A135.6
        │      └─{A135.6}--求解
        └─[A13]--聪明
复制代码

andrew3000

回复 6# terse


    谢了，代码作为学习资料研究下，对于我来说，可以学到好多知识，但运行后与想要的文件夹树结构有些许出入，还是用TC操作吧。。