[文件操作] 【已解决】批处理:帮忙改一下重命名文件的脚本啊

001011

下面的这个脚本，原先设计的改变jpg的文件名。现在的一批文件夹里面同时有两种格式  jpg和tif   请帮忙改一下叫吧   感谢
原先求助的帖子链接：http://www.bathome.net/thread-25445-1-1.html

@echo off&setlocal enabledelayedexpansion
set "mypath=E:\成品\1"
for /r "%mypath%" %%a in (.) do (
  set /a n=0
  for /f "delims=" %%b in ('dir /a-d /b "%%~dpna\*.jpg" 2^>nul') do (
     set /a n+=1&set "num=00!n!"
     ren "%%~dpna\%%b" "%%~na-!num:~-3!.jpg"
  )
)
复制代码

canyuexiaolang

好歹也是二级士官了，难道一点都没学么。

@echo off&setlocal enabledelayedexpansion
set "mypath=E:\成品\1"
for /r "%mypath%" %%a in (.) do (
  set /a n=0
  for /f "delims=" %%b in ('dir /a-d /b "%%~dpna\*.jpg" 2^>nul ^& dir /a-d /b "%%~dpna\*.wma" 2^>nul') do (
     set /a n+=1&set "num=00!n!"
     echo ren "%%~dpna\%%b" "%%~na-!num:~-3!%%~xb"
  )
)
pause
复制代码

gawk

@echo off
setlocal enabledelayedexpansion
set "mypath=E:\成品\1"
for /r "%mypath%" %%a in (.) do (
    set n=0
    for /f "delims=" %%b in ('dir /a-d /b "%%~dpna\" 2^>nul') do (
        set /a n+=1
        set "num=00!n!"
        ren "%%~dpna\%%b" "%%~na-!num:~-3!%%~xb"
    )
)
复制代码

001011

非常感谢  不是没学  只是按照我所学的测试了几次 都没有成功
我再努力

CrLf

个人比较喜欢 set /a n+=1001 来代替 set /a n+=1&set "num=00!n!"
仅适用低于 %06d 的格式