[系统相关] 【已解决】批处理获取最后一个剩余空间大于200G的分区，变量延迟应该放在哪个位置？

踏沙行

目的：获取硬盘最后一个剩余空间大于200G的分区，并赋值给全局变量Div

@echo off
for /f "skip=1 tokens=1-3" %%a in ('wmic logicaldisk get caption^,drivetype^,freespace') do (
	if "%%b"=="3" (
		set "size=%%c"
Setlocal enabledelayedexpansion
		set "size=!size:~,-9!"
		if !size! geq 200 (
			set "Div=%%a"

)
endlocal
))

	echo %Div%,%size%

pause
复制代码

在上例中，Setlocal enabledelayedexpansion和endlocal这一对语句，应该怎么放置才最正确呢？
尝试分别放在for语句外面，或者放在每一层括号相对的位置，结果都不正确，只有把setlocal放在括号外，而endlocal话在括号内才正确。但是这样位置并不对应啊

Batcher

@echo off
Setlocal enabledelayedexpansion
for /f "skip=1 tokens=1-3" %%a in ('wmic logicaldisk get caption^,drivetype^,freespace') do (
    if "%%b"=="3" (
        set "size=%%c"
        set "size=!size:~,-9!"
        if !size! geq 200 (
            set "Div=%%a"
        )
    )
)
echo !Div!,!size!
pause
复制代码

这样会有什么错误吗？

WHY

@echo off
for /f "tokens=1-2" %%a in ('wmic logicaldisk where "drivetype='3' and freespace > 214748364800" get caption^,freespace^|find ":"') do (
    set "caption=%%a" & set "size=%%b"
)
	echo;%caption% %size%
pause
复制代码

踏沙行

回复 3# WHY
太感谢了