批处理新手入门导读[视频教程]批处理基础视频教程[视频教程]VBS基础视频教程
[批处理文件精品]批处理版照片整理器[批处理文件精品]纯批处理备份&还原驱动在线第三方下载
返回列表 发帖

[文本处理] 【已解决】我用了FOR嵌套怎么才能结束子循环的情况下不影响外边的循环

本帖最后由 miqilaosu 于 2019-6-21 09:54 编辑
  1. @echo off
  2. setlocal enabledelayedexpansion
  3. for /f "delims=" %%i in ('type 1.txt') do (
  4. set n=1
  5. call set "var=%%i"
  6. for /l %%a in (1,1,99) do (
  7. call set "var1=%%var:~0,!n!%%"
  8. call set "var2=%%var:~!n!,!n!%%"
  9. if !var1!==!var2! (
  10. echo,!var1!.
  11. ::跳出子循环
  12. ) else (
  13. set /a n+=1
  14. if !var2!=="" ::if跳出子循环
  15. )
  16. )
  17. )
  18. )
  19. pause
复制代码
是这样的,第一个::跳出子循环的地方我想直接跳出子循环外边的循环继续,第二个我想做个判断!var2!==""的时候跳出子循环,但是发现不能用GOTO 不然就直接全跳出的,查了半天没找到方法,请问各位大神怎么才能实现

本帖最后由 WHY 于 2019-6-18 22:29 编辑

批处理 for 循环里面只能 goto 到循环外部,不能在 for 循环内部 goto
这样应该可以:
  1. @echo off
  2. setlocal enabledelayedexpansion
  3. for /f "delims=" %%i in ('type 1.txt') do (
  4.     set "var=%%i"
  5.     for /l %%a in (1,1,99) do (
  6.         set "var1=!var:~0,%%a!"
  7.         set "var2=!var:~%%a!"
  8.         if "!var1!" == "!var2!" (echo;!var1!)
  9.     )
  10. )
  11. pause
复制代码
或者试试 call :标签
  1. @echo off
  2. setlocal enabledelayedexpansion
  3. for /f "delims=" %%i in ('type 1.txt') do (
  4.     call :GetString "%%i"
  5. )
  6. pause & goto :EOF
  7. :GetString
  8. set "var=%~1"
  9. for /l %%a in (1,1,99) do (
  10.     set "var1=!var:~0,%%a!"
  11.     set "var2=!var:~%%a!"
  12.     if "!var1!" == "!var2!" (echo;!var1!&goto :EOF)
  13. )
复制代码
1

评分人数

    • miqilaosu: 太利害了,第一种方法没太看懂,我自己在多 ...技术 + 1

TOP

返回列表