[系统相关] [已解决]批处理怎么实现连续ping一个ip，不通则自动关机

522235677

因为服务器上接了UPS，停电后不好自动执行自动关机，所以想到这个方法。曾经小弟我写这么简单的功能，都是手到擒来的，如今多年不接触批处理，这么简单的功能都写不出来了……老了……
就想连续ping，如果1分钟内连续ping不通指定的IP，或者说连续ping60次都不通，就执行shutdown关机命令。

最后，感谢大佬们的帮助

Batcher

回复 1# 522235677

@echo off
ping -n 60 192.168.0.123
if errorlevel 1 (
    shutdown /s /f /t 0
)
复制代码

522235677

回复 2# Batcher


    感谢老大帮忙，但是我测试发现，如果ping 60次全部都是“请求超时”的话，那errorlevel 就是1，但是实际返回的是“无法访问目标主机”，这样就识别不了了

正在 Ping 192.168.10.144 具有 32 字节的数据:
来自 192.168.10.220 的回复: 无法访问目标主机。
来自 192.168.10.220 的回复: 无法访问目标主机。
来自 192.168.10.220 的回复: 无法访问目标主机。

zhaolu133

if not errorlevel 0   也可以吧

522235677

回复 4# zhaolu133


    不行哦，ping通 或者  无法访问目标主机
%errorlevel% 都是 0

went

只要ping成功一次就不关机

@echo off 
for /l %%i in (1,1,60) do (
	ping /n 1 192.168.10.220 | findstr /i ttl && ( echo success %%i & goto :e )
	echo failed %%i
)
shutdown /s /t 0
:e
pause&exit
复制代码

522235677

回复 6# went


    感谢大佬帮助，我也写了个土方法

@echo off & title ping 群晖，不通则关机
mode con cols=60 lines=10
:loop
ping -n 3 192.168.10.230|findstr /i /c:"来自 192.168.10.230 的回复"
if errorlevel 1 (
    shutdown -s
    pause
    exit
)
goto :loop
复制代码