[注册表类] pe中通过批处理如何准确获取本地磁盘上所有操作系统版本及引导模式

dong3626

pe中
通过批处理
如何准确获取
本地磁盘上
所有（可能有多个系统，或者多个硬盘）
操作系统版本及引导模式


比如：
提取操作系统版本信息

相关命令：
reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "DisplayVersion"
DisplayVersion    REG_SZ    21H2
reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "ProductName"
ProductName    REG_SZ    Windows 10 IoT Enterprise LTSC 2021


各路大神，不吝赐教！！

谢谢

holley

回复 1# dong3626

@echo off
for /f "tokens=3"  %%i in ('reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "DisplayVersion"') do (
 set pgPath2=%%i
)

for /f "tokens=1,2,*"  %%a in ('reg query "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v "ProductName"') do (
 set pgPath1=%%c
)

@echo 当前系统版本为：%pgPath1% %pgPath2%
pause
复制代码

yyz219

回复  dong3626
holley 发表于 2023-4-6 10:33

    感谢分享

dong3626

回复  dong3626
holley 发表于 2023-4-6 10:33

    pe中，不是在本地系统中

WHY

@echo off
for %%i in (C D E F G H I J K L M N O P Q R S T U V W X Y Z) do (
    if /i "%%i:" == "%SystemDrive%" (
        echo;%%i:
        call :xxx "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion"
    ) else if exist "%%i:\Windows\System32\Config\Software" (
        echo;%%i:
        reg Load HKLM\WINPE "%%i:\Windows\System32\Config\Software" >nul
        call :xxx "HKLM\WINPE\Microsoft\Windows NT\CurrentVersion"
        reg Unload HKLM\WINPE >nul
    )
)
pause & exit

:xxx
for /f "tokens=1,2*" %%i in ('reg query "%~1" /t REG_SZ') do (
    if /i "%%i" == "DisplayVersion" (
        echo;%%k
    ) else if /i "%%i" == "ProductName" (
        echo;%%k
    )
)
复制代码