[系统相关] [已解决]批处理等待某个进程结束后再执行另下一步

wbance

这段代码是我从知道里另一个问题上复制下来的。请高手帮我改一下。

@echo off
set taskname=calc.exe


echo.%taskname%未运行，
echo.等待%taskname%运行...
echo.
echo.
goto :loop1
:loop1
for /f %%a in ('tasklist.exe /FI "IMAGENAME eq %taskname%" /FI "STATUS eq RUNNING" /FO TABLE /NH^|find.exe /i "%taskname%"') do (
echo.发现%taskname%正在运行，
echo.等待%taskname%运行结束...
echo.
echo.
goto :loop2
)
ping 127.1 -n 2 >nul 2>nul
goto :loop1


:loop2
for /f %%a in ('tasklist.exe /FI "IMAGENAME eq %taskname%" /FI "STATUS eq RUNNING" /FO TABLE /NH^|find.exe /i "没有"') do (
echo.%taskname%未运行，
echo.等待%taskname%运行...
echo.
echo.
goto :loop1
)
ping 127.1 -n 2 >nul 2>nul
goto :loop2
复制代码

第一个loop是检测是否允许，如果运行，则提示已运行，然后跳转到第二个loop检测是否终止运行，如果终止运行，跳回第一个loop如此循环检测。
把这一段意思改成：如果运行，则提示已运行，然后跳转到第二个loop检测是否终止运行，如果终止运行，则进行下一步，也就是 shutdown -r -t 02 -f

[ 本帖最后由 wbance 于 2011-3-18 21:55 编辑 ]

hanyeguxing

把第三个goto :loop1
改成需要的命令

wbance

不行啊
你说的是不是这个意思？

@echo off
set taskname=calc.exe


echo.%taskname%未运行，
echo.等待%taskname%运行...
echo.
echo.
goto :loop1
:loop1
for /f %%a in ('tasklist.exe /FI "IMAGENAME eq %taskname%" /FI "STATUS eq RUNNING" /FO TABLE /NH^|find.exe /i "%taskname%"') do (
echo.发现%taskname%正在运行，
echo.等待%taskname%运行结束...
echo.
echo.
goto :loop2
)
ping 127.1 -n 2 >nul 2>nul
goto :loop1


:loop2
for /f %%a in ('tasklist.exe /FI "IMAGENAME eq %taskname%" /FI "STATUS eq RUNNING" /FO TABLE /NH^|find.exe /i "没有"') do (
echo.%taskname%未运行，
echo.等待%taskname%运行...
echo.
echo.
goto :loop3
)
ping 127.1 -n 2 >nul 2>nul
goto :loop2
:loop3
md 1
复制代码

[ 本帖最后由 wbance 于 2011-3-18 21:46 编辑 ]

wbance

括起来了  嘿嘿。。

hanyeguxing

@echo off
set taskname=calc.exe
:a
set a=
tasklist|find /i "%taskname%">nul 2>nul&&set b==||set a==
if "%a%%b%"=="==" goto:b
ping 127.1 -n 2 >nul
goto:a
:b
echo;已结束进程&pause
复制代码

[ 本帖最后由 hanyeguxing 于 2011-3-18 21:53 编辑 ]

wbance

谢谢斑竹。问题解决  O(∩_∩)O谢谢