pusofalse

@echo off&setlocal enabledelayedexpansion&set n=-1
for /f "delims=" %%a in (1.txt) do (
set/a n+=1
set flag=
call :lp %%a
if not defined flag echo %%a
)
:lp
if "%1" equ "" set/a n+=1
set m=skip=%n%
if "%m%" equ "skip=0" set "m="
for /f "%m% delims=" %%a in (2.txt) do if "%1" neq "" (echo %1&echo %%a&set flag=a&goto :eof) else echo %%a
if "%1" equ "" pause

[ 本帖最后由 pusofalse 于 2008-7-25 16:55 编辑 ]

batman

原帖由 youxi01 于 2008-7-25 08:23 发表
不过有个疑问就是：效率是不是会非常低呢？特别是遭遇大文件时
根据代码的意思，似乎是查询两个文件行号一样的时候就分别写入到文件里

这样的话，要是第二个文件有1W行岂不是要比对1W次？这样，明显有9999次是没 ...

我想在这里应该不有去考虑极端情况，比如特殊字符处理什么的。

batman

既然这种最高效的方法也出来了(只可惜是版主级做出来的)，下面就贴出本人的第二种方法：

@echo off
set "n=-1"&set "flag=a"
:begin
set /a n+=1
if %n% equ 0 (set "m=") else (set "m=skip=%n%")
for /f "%m% delims=" %%i in (1.txt) do echo %%i&if defined flag goto next
set no=a
:next
for /f "%m% delims=" %%i in (2.txt) do echo %%i&goto begin
if not defined no set "flag="&goto begin
pause>nul
复制代码

pusofalse

为了减少不必要的调用，修改如下。

 
@echo off&set n=-1
for /f "delims=" %%a in (1.txt) do (
set/a n+=1
set flag=
if not defined faith call :lp %%a
if not defined flag echo %%a
)
:lp
if "%1" equ "" set/a n+=1
set m=skip=%n%
if "%m%" equ "skip=0" set "m="
for /f "%m% delims=" %%a in (2.txt) do if "%1" neq "" (echo %1&echo %%a&set flag=a&goto :eof) else echo %%a
set faith=faith
if "%1" equ "" pause
复制代码

batman

再次提示：
第三种方法可就本题而言来解(不考虑行数太多的情况)

浅默

@echo off
for /f "tokens=1* delims=:" %%i in ('findstr /n .* 1.txt') do set _%%i=%%j
for /f "tokens=1* delims=:" %%k in ('findstr /n .* 2.txt') do set _%%k.%%k=%%l
for /f "tokens=1* delims==" %%i in ('set _ ') do echo %%j
pause
要是就本题的几行上面的还行

namejm

　　把两个文本的相同行交叉合并，需要考虑以下两种情况：
　　1、两个文本的行数相同；
　　2、两个文本的行数不同。

　　如果两个文本行数相同，则可以省略对文本行数的判断，但考虑到效率高低，需要使用临时文件，则可使用如下代码：

@echo off
findstr .* 1.txt>_1.txt
setlocal enabledelayedexpansion
for /f "delims="  %%i in (2.txt) do (
    set /a num+=1
    echo !num!:%%i
    findstr /b /i "!num!:" _1.txt
)
del /q _1.txt
pause
复制代码

　　如果两个文本行数不同，则需要判断行数谁多谁少，从而减少对比次数，演示代码如下：

@echo off
:: 生成临时文件，主要是为了获得 行数:行内容 格式的文本
findstr /n .* 1.txt>_1.txt
findstr /n .* 2.txt>_2.txt

:: 获取各自的总行数
for /f "delims=:" %%i in (_1.txt) do set num_1=%%i
for /f "delims=:" %%i in (_2.txt) do set num_2=%%i

:: 比较行数谁多谁少
set num=%num_1%
set file_1=_1.txt&set file_2=_2.txt
if %num_1% geq %num_2% (
    set num=%num_2%
    set file_1=_2.txt&set file_2=_1.txt
)

:: 以行数少的文本为标准，交叉输出两文本的同行内容
for /f "tokens=1* delims=:" %%i in (%file_1%) do (
    echo %%i:%%j
    findstr /b /i "%%i:" %file_2%
)

:: 对多出的行内容，一次性输出，减少了对比次数，从而提高效率
more +%num% %file_2%
del /q _1.txt _2.txt
pause
复制代码

　　如果不动用临时文件，要么需要设置大量的变量，严重消耗系统内存；要么需要用 if 语句对行号进行机械对比，严重影响效率；如果使用 set 排序方案，则要求每个文本的总行数不能超过9行，并且不能保证某个文件的行内容总是排在两行中的第一行或第二行。
　　注：以上代码都没有考虑特殊字符。

pusofalse

jm厉害，考虑这么全面。

batman

最后给出本人的第三个方案，生成临时文件且通用性不很强，
解题思路和上面的完思路不同：

@echo off&setlocal enabledelayedexpansion
set "num=0"
for %%a in (1.txt 2.txt) do (
    for /f "delims=" %%i in (%%a) do (
        set /a n+=1
        if !n! gtr !num! set "num=!n!"
        set /p=%%i <nul>>temp.txt
    )
    echo.>>temp.txt&set "n=0"
)
:lp
set /a n+=1
for /f "tokens=%n%" %%i in (temp.txt) do echo %%i
if %n% neq %num% goto lp
del /q temp.txt&pause>nul
复制代码

keen

我的，有点晚：

@echo off&setlocal enabledelayedexpansion
set m=-1
for /f %%i in (1.txt) do set /a m+=2&set _!m!=%%i
for /f %%j in (2.txt) do set /a n+=2&set _!n!=%%j
if %m% gtr %n% (set max=%m%) else (set max=%n%)
for /l %%k in (1 1 %max%) do (
    if defined _%%k call,echo %%_%%k%%
)
pause
复制代码

keen

batman就是强！
我的跟batman的第一种方法（15楼）基本一样了。
batman的第二种方法（见18楼），更是高手典范。

batman

呵呵，本人最老的一道题也被你们翻出来了，加油，有这股劲就对了!

netbenton

 
@echo off&setlocal enabledelayedexpansion
for /f "delims="  %%a in (1.txt) do (set /a n+=1&set #!n!=%%a)
for /f "delims=" %%a in (2.txt) do (
    set/a m+=1
    echo %%a
    if defined #!m! for %%b in (!m!) do echo !#%%b!
)
set/a m+=1
for /l %%a in (!m!,1,!n!) do echo !#%%a!
复制代码

everest79

一百行以内

@echo off
for /f "tokens=1* delims=[]" %%a in ('find /v /n "" ?.txt^|findstr /b "\[[0-9]\]"^|sort') do echo.%%b >>out.txt
for /f "tokens=1* delims=[]" %%a in ('find /v /n "" ?.txt^|findstr /b "\[[0-9][0-9]\]"^|sort') do echo.%%b >>out.txt

pause
复制代码

netbenton

楼上的不一定会交替的吧？
有可能会这样的
a.txt  行
b.txt  行
b.txt  行
a.txt  行