[转贴] VBS脚本类构造函数与Default关键字使用介绍

find

很多人并不知道 VBS 中还有个 Default 关键字，更不用说知道 Default 关键字的用法。
其实 MSDN 的 VBScript 文档中关于 Function 和 Sub 语句的部分提到过 Default 关键字：

Default
Used only with the Public keyword in a Class block to indicate that the Function procedure is the default method for the class. An error occurs if more than one Default procedure is specified in a class.

Default 只能在 Class 语句块中与 Public 关键字一起使用来表明函数过程是类的默认方法。如果类中一个以上的过程被定义为 Default，那么会出现错误。
一个简单的例子：

Class MyClass
Public Default Function SayHello(name)
SayHello = "Hello, " & name
End Function
End Class
Set o = New MyClass
MsgBox o("demon")
复制代码

很多面向对象的语言都能使用构造函数来初始化类的对象，但是 VBS 却没有构造函数的概念，只是提供了一个类初始化事件来初始化对象：

Class TestClass
' Setup Initialize event.
Private Sub Class_Initialize
MsgBox("TestClass started")
End Sub
' Setup Terminate event.
Private Sub Class_Terminate
MsgBox("TestClass terminated")
End Sub
End Class
' Create an instance of TestClass.
Set X = New TestClass
' Destroy the instance.
Set X = Nothing
复制代码

虽然看起来很像构造函数，但是却不能带参数，没有办法像其他语言那样用特定的参数来初始化对象。
有了 Default 关键字之后，我们可以模拟实现构造函数的功能：

'Author: Demon
'Date: 2011/09/29
'Website: http://demon.tw
Class Rectangle
Private height, width
Public Default Function Construtor(h, w)
height = h : width = w
Set Construtor = Me
End Function
Public Property Get Area
Area = height * width
End Property
End Class
'看起来是不是很像构造函数呢
Set r = (New Rectangle)(6, 8)
MsgBox r.Area
复制代码

转自：http://www.jb51.net/article/28682.htm

Demon

垃圾脚本之家

麻烦你注明原出处好么

http://demon.tw/programming/vbs-default-keyword.html