batman

原帖由 pusofalse 于 2008-8-28 16:52 发表
4　set /a 可以如此连写：set /a a+=1,b+=a,c+=b　，当然前提是开启了变量延迟
不必开启变量延迟啊，set/a 的特性就是这样。

多谢指正，已修改。

yslyxqysl

 
@echo off
setlocal ENABLEDELAYEDEXPANSION
:input
set /p num=请输入：
for /l %%i in (1 1 %num%) do (
for /l %%p in (1 1 %num%) do (
set /a tempnum+=1
if !tempnum! lss 10 set /p tp= <nul
set /p tp=!tempnum! <nul
)
echo.
)
pause
goto input
复制代码

[ 本帖最后由 yslyxqysl 于 2008-8-29 18:43 编辑 ]

batman

&&看来螺旋矩阵确实难住了众位新手，同时高手们都不肯冒然出手，
所以只有本人来抛砖引玉了：
----------------------------------------------------------------------------------
首先做下解题说明：
     其实解此题的关键是在找规律，这个螺旋矩阵最大的规律就是在
行、列值的递增递减上，我们就将x变量设为行将y变量设为列，于是
一个y+ x+ y- x-的循环呈现在我们面前，而同时从上一步跳到下一步
的临界值也在变化，不难看出这是个递减的变化，所以只要我们掌握
了以上两点规律，解题的思路便会清晰起来：

@echo off&setlocal enabledelayedexpansion
set /p var=请输入螺旋阵级数(9级内)：
set /a x=1,y=1,total=var*var,tt=1,n=0,m=1,num=var+1
:begin
set /a num-=1,n+=1,m+=1
set "s=y+x+y-x-"&set "ss=%num%%num%%n%%m%"&set "gl=lsslssgtrgtr"
:again
set /a %s:~,2%=1,tt+=1
if %tt% lss 10 set "tt= %tt%"
if not defined _%x%%y% set "_%x%%y%=%tt%"
if !%s:~,1%! %gl:~,3% %ss:~,1% goto again
set "s=%s:~2%"&set "ss=%ss:~1%"&set "gl=%gl:~3%"
if defined s goto again
if %tt% lss %total% goto begin
set "_11= 1"
for /l %%a in (1,1,%var%) do (
    for /l %%i in (1,1,%var%) do (
        set /p=!_%%a%%i! <NUL
    )
    echo.
)
pause>nul
复制代码

ps:期望各位高手贴出更完美的方案。
----------------------------------------------------------------------------------

terse

刚在联盟那边贴了
和batman 兄的代码比较还是不够精炼
本不想贴了但还是献个丑哦
我看到  if %p% equ 0 就可结束  更改下

@echo off&setlocal enabledelayedexpansion
set/p p=输入阶数:
set/a n+=1,o=p
:lp
    set/a b+=2
    for /l %%i in (%n% 1 %p%) do set/a a+=1&set %n%%%i=!a!
    set/a n+=1
    for /l %%i in (%n% 1 %p%) do set/a a+=1&set %%i%p%=!a!
    set/a m=p-1,t+=1
    for /l %%i in (%m% -1 %t%) do set/a a+=1&set %p%%%i=!a!
    set/a p-=1,s+=1
    for /l %%i in (%p% -1 %n%) do set/a a+=1&set %%i%s%=!a!
    if %b% gtr %o% (
    for /l %%i in (1 1 %o%) do (
    for /l %%j in (1 1 %o%) do if !%%i%%j! lss 10 (set /p = !%%i%%j! <nul)else set /p =!%%i%%j! <nul
    echo.)
    pause>nul)else goto lp
复制代码

[ 本帖最后由 terse 于 2008-8-29 02:21 编辑 ]

shqf

代码竟是如此短啊！可怜我还是难以理解其精妙之处。除了佩服，只剩穷顶。

[ 本帖最后由 shqf 于 2008-8-29 08:22 编辑 ]

everest79

骗分

@echo off&Setlocal EnableDelayedExpansion
Set /p N=num:
Set /a ALL=N*N,w=0,h=w,s=h,c=s,l=n-1
For /l %%a in (1,1,%all%) Do (Set _o!h!!w!=%%a
if !c! EQU 0 (call :c w + GEQ 1 "l-s") else  if !c! EQU 1 (call :c h + GEQ 2 "l-s"
) else if !c! EQU 2 (call :c w - LEQ 3 "s") else  if !c! EQU 3 call :c h - LEQ "0,s+=1" "s+1")
for /f "tokens=1,2 delims==" %%a in ('set _o^|sort') do (
Set/P=%%b	<nul&Set /a count+=1,1/^(count%%%N%^)2>nul||echo.)
pause >nul&goto :eof
:c
Set /a %1%2=1,tmp=%~5
if !%1! %3 %tmp% Set /a %1=tmp,c=%~4
goto :eof
复制代码

keen

1-6：

@echo off
set /p num=请输入要操作的数，范围是1-9：
set sum4=1
for /l %%i in (1 1 %num%) do (
     set /a sum1=%%i*%%i,sum2=sum1*%%i,sum3+=%%i,sum4*=%%i,sum5+=sum1,sum6+=sum2
)
echo\
echo %num%的平方是：%sum1%
echo %num%的立方是：%sum2%
echo 从1到%num%的和：%sum3%
echo 从1到%num%的积：%sum4%
echo 从1到%num%的平方和：%sum5%
echo 从1到%num%的立方和：%sum6%
echo\&pause
复制代码

keen

第7题：

@echo off&setlocal enabledelayedexpansion
set /p num=请输入要操作的数，范围是1-9：
echo\&echo %num%行%num%列数列：
for /l %%i in (1 1 %num%) do (
    for /l %%j in (1 1 %num%) do (
         set /a sum7+=1&set sum7= !sum7!&set /p=!sum7:~-2! <nul
)
echo\
)
echo\&pause
复制代码

xmaoh234

pp 是立方，你写的是平方。。。。。

keen

既然设定整个代码不断循环，就要把tempnum在下一次循环时，清零。要么就不要进行循环。

keen

看了19楼的代码，原来是通过定位坐标的方式，形成螺旋阵列。

我知道还有通过坐标定位的另一种方式，只是不知道，具体怎么写。

坐标定位，好像是：
1-1 1-2 1-3 1-4
2-1 2-2 2-3 2-4

继续学习，继续研究！

netbenton

@echo off&Setlocal EnableDelayedExpansion
Set /p k=19内阶数:
Set /a all=k*k,t1=1,h1=1,sk=k,ck=k,m=1,n=1,x=0,y=1,a=1

set str1=n sk 1 0 t1 1
set str2=m ck 0 -1 sk -1
set str3=n h1 -1 0 ck -1
set str0=m t1 0 1 h1 1

for /l %%a in (1,1,!all!) do (
        set #!m!.!n!=%%a
        set/a m+=x,n+=y
        for %%b in (!a!) do (
                for /f "tokens=1-6" %%c in ("!str%%b!") do (
                        if !%%c! equ !%%d! set/a x=%%e,y=%%f,%%g+=%%h,a+=1,a=a%%4
)        )        )

for /l %%a in (1,1,!k!) do (
        set str=
        for /l %%b in (1,1,!k!) do (set one=   !#%%a.%%b!&set str=!str!!one:~-4!)
        echo !str!
)
pause

hanyeguxing

使用对角分割解螺旋方阵：

@echo off
:s
setlocal enabledelayedexpansion&cls
set/p n=输入阶数:
if %n% gtr 46340 goto:s
set/a k=n*n&set k= !k!
for /l %%a in (1,1,11) do if not "!k:~%%a,1!"=="" set q=%%a&set "s=!s! "
for /l %%a in (1,1,%n%) do (
        for /l %%b in (1,1,%n%) do (
                set/a k=n+1-%%a
                if %%b geq %%a if %%b leq !k! set/a "p=4*(n-%%a)*%%a-4*n+7*%%a+%%b-3"
                if %%b leq %%a if %%b gtr !k! set/a "p=4*(n-%%a)*%%a-2*n+5*%%a-%%b-1"
                if %%b gtr %%a if %%b gtr !k! set/a "p=4*(n-%%b)*%%b-2*n+%%a+3*%%b-1"
                if %%b lss %%a if %%b leq !k! set/a "p=4*(n-%%b)*%%b-%%a+%%b+1"
                set p=%s%!p!&set/p"=!p:~-%q%! "<nul
        )
        echo;
)
pause&endlocal&goto:s
复制代码

JS版：

<script>
hy(20);
function hy( n)
{ var i,j; 
document.write("<body bgcolor=#008000><center><table border=1 bgcolor=#B0E2FF bordercolor=#fff000> ");
for(i=1;i<=n;i++){document.write("<tr>");
for(j=1;j<=n;j++){
var Han=4*(n-i)*i-4*n+7*i+j-3;
var Ye=4*(n-j)*j-2*n+i+3*j-1;
var Gu=4*(n-i)*i-2*n+5*i-j-1;
var Xing=4*(n-j)*j+-i+j+1;
document.write("<td>"+((i<=j&&i+j<=n+1)?Han:(i<j&&i+j>n+1)?Ye:(i>=j&&i+j>n+1)?Gu:Xing)+"</td>");} document.write("</tr>");}
document.write("</table> ");
}
</script>
复制代码

[ 本帖最后由 hanyeguxing 于 2011-2-8 11:15 编辑 ]

Hello123World

1# batman
1-6题：

@echo off & setlocal enabledelayedexpansion
Set /p a=请输入要操作的数（1-9）：
Set /a b=%a%*%a%
Set /a c=%a%*%a%*%a%
Set e=1
For /l %%i in (1 1 %a%) do (Set /a d+=%%i & Set /a e*=%%i 
Set f=%%i & Set /a f*=!f! & Set /a g+=!f!
Set f=%%i
Set /a h=!f!*!f!*!f! & Set /a m+=!h!
)
Echo %a%的平方：%b%
Echo %a%的立方：%c%
Echo 1到%a%的和：%d%
Echo 1到%a%的积：%e%
Echo 1到%a%的平方和：%g%
Echo 1到%a%的立方和：%m%
pause
复制代码

Hello123World

第7题格式上有点问题：

@echo off&Setlocal EnableDelayedExpansion
For /l %%i in (1 1 16) do (Set a=%%i
Set /p =!a! <nul
Set /a b=!a!%%4
If !b!==0 Echo\) 
pause
复制代码