【练习-020】批处理根据输入列出组合

batman · 发表于 2008-9-6 21:49:57

要生成个临时文件b.bat：

@echo off&setlocal enabledelayedexpansion
set /p num=请输入字符：
set "s=abcdefghijklnmopqrstuvwxyz"&set "nums=%num%"
:lp
set /a n+=1
set "str1=%str1% %n%"
set "ss=%ss%str%n%"&set "k=%k%)"
set "_%n%=%num:~,1%"&set "num=%num:~1%"
if defined num goto lp
echo ^@echo off^&setlocal enabledelayedexpansion>b.bat
for /f "skip=1 delims=" %%a in (%~fs0) do (
set /a x+=1
if !x! equ 9 goto loop
if !x! equ 1 (
echo set "num=%nums%">>b.bat
) else (
if !x! neq 2 if !x! neq 6 echo %%a>>b.bat
)
)
:loop
set "a=%%%%%s:~,1%"&set "b=%ss:~,4%"&set "c=%ss:~4,4%"
set "str=!str!^!_%a%^!"
if "%c%" equ "" set "c=flag"
echo for %a% in (^^^!%b%^^^!) do (set "%c%=^!%b%:%a%=^!">>b.bat
set "s=%s:~1%"&set "ss=%ss:~4%"
if defined ss goto loop
echo echo !str!>>b.bat
echo %k%>>b.bat
echo pause^>nul>>b.bat
endlocal&b

复制代码

[ 本帖最后由 batman 于 2008-9-6 22:06 编辑 ]

terse · 发表于 2008-9-7 13:53:46

想给多点分怎么总是错误啊

pusofalse · 发表于 2008-9-7 16:55:27

terse前辈是不是输入空格了 abad 要这样的。

caruko · 发表于 2011-5-21 15:02:11

效率还可以，但不支持重复字符。
7个字符，5040组合，用时不到15秒。

@echo off&SETLOCAL ENABLEDELAYEDEXPANSION
set "str=a b c d e f g"
set time1=!time!
for %%i in (%str%) do (
set /a n+=1,_%%i=n
)
echo, !str!
for /l %%a in (1,1,10000000) do (
set "last="&set "flag="&set "pos=0"
for %%b in (!str!) do (
set /a pos+=1
if defined last (
set /a n1=_%%b,n2=_!last!
if !n1! gtr !n2! set flag=!last! !pos!
set "last=%%b"
) else (
set "last=%%b"
)
)
if not defined flag call :end %%a
for /f %%b in ("!flag!") do for %%c in (!str!) do if !_%%c! gtr !_%%b! set "th=%%c"
for /f "tokens=1,3" %%b in ("!flag! !th!") do (
set "temp=!str:%%b=#!"
set "temp=!temp:%%c=%%b!"
set "str=!temp:#=%%c!"
)
set "ppos="&set "cut1="&set "cut2="&set "array="
for %%b in (!str!) do (
set /a ppos+=1
for /f "tokens=2" %%c in ("!flag!") do (
if !ppos! geq %%c (
set "cut2=!cut2! %%b"
) else (
set "cut1=!cut1! %%b"
)
)
)
for %%i in (!cut2!) do (
set "array=%%i !array!"
for %%j in (!array!) do (
if %%i gtr %%j (
set "array=!array:%%i=#!"
set "array=!array:%%j=%%i!"
set "array=!array:#=%%j!"
)
)
)
set str=!cut1! !array!
echo,!str!
)
:end
echo,一共%1个排列. !time1!--^>!time!
pause>nul&exit

复制代码

wankoilz · 发表于 2011-5-21 18:19:26

本帖最后由 wankoilz 于 2011-5-22 09:05 编辑

既然老帖被挖出来了，俺也来凑热闹。
支持重复字符，我这里测试8个字母40320种组合耗时近4秒：

@echo off&setlocal enabledelayedexpansion
set/p s=请输入，用一个空格分开:
echo %time%
set f1=a.txt
set f2=b.txt
>!f1! echo !s:~,1!&set s=!s:~1!
set len=1
for %%a in (%s%) do (
(for /f %%b in (!f1!) do (
set tmp=%%b
for /l %%c in (0,1,!len!) do echo !tmp:~,%%c!%%a!tmp:~%%c!
))>!f2!
set t=!f1!
set f1=!f2!
set f2=!t!
set/a len+=1
)
echo %time%
start %f1%&del/f %f2%
pause

复制代码

CrLf · 发表于 2011-5-21 19:04:25

本帖最后由 zm900612 于 2011-5-22 13:16 编辑

【该思路已有先例，523066680较早提出】
我认为for嵌套递归始终是最快的方案，所以构思了一个基于for /l递归的新思路，唯一的缺陷是for嵌套理论上限62层[A-Za-z0-9]，本代码由于作者偷懒，功能不够强大，仅兼容低于10层，而且不能有重复项...

@echo off&setlocal enabledelayedexpansion
set str= a b c d e f g
set t=%time%
for %%a in (%str%) do (
set /a n+=1,"tmp+=^!tmp"
set "echo=%%!n! !echo!"
)
::初始化
set "for=for /f %%1 in ("^^!tmp1:%%2 =^^!") do (set /a z+=1)&echo %echo%"
for /l %%a in (2 1 %n%) do (
set /a last=%%a-1
set "for=for %%%%a in (^!tmp%%a^!) do ((set tmp!last!=^!tmp%%a: %%%%a = ^!)&!for!)"
)
::为str构建相应层数的for嵌套
set tmp%n%=%str%
%for%
::执行组装而成的for嵌套
echo 共有%z%种组合开始于%t% 结束于%time%
pause

复制代码

caruko · 发表于 2011-5-21 19:13:13

楼上是字符插入的方法啊。

CrLf · 发表于 2011-5-21 19:22:54

22# caruko

？？
不懂...

CrLf · 发表于 2011-5-21 19:24:26

反正5040种组合耗时3秒，应该算不错的成绩了

wankoilz · 发表于 2011-5-21 21:06:01

楼上是字符插入的方法啊。
caruko 发表于 2011-5-21 19:13

是字符插入法。

CrLf · 发表于 2011-5-21 21:22:30

你们怎么会认为是字符插入呢？这段代码和我所理解的字符插入的概念一点关系都没有呀，看来原有的注释太少，弄详细点：

@echo off&setlocal enabledelayedexpansion
set str= a b c d e f g
set t=%time%
for %%a in (%str%) do (
set /a n+=1,"tmp+=^!tmp"
set "echo=%%!n! !echo!"
)
::初始化
set "for=for /f %%1 in ("^^!tmp1:%%2 =^^!") do (set /a z+=1)&echo %echo%"
::定义最里层的for
for /l %%a in (2 1 %n%) do (
set /a last=%%a-1
set "for=for %%%%a in (^!tmp%%a^!) do ((set tmp!last!=^!tmp%%a: %%%%a = ^!)&!for!)"
rem 定义for嵌套，一层包一层...
)
::为str构建相应层数的for嵌套
set tmp%n%=%str%
%for%
::执行组装而成的for嵌套，改成echo !for!就明白了
echo 共有%z%种组合开始于%t% 结束于%time%
pause

复制代码

CrLf · 发表于 2011-5-21 21:27:35

那个%for%运行起来就是这个效果：

@echo off&setlocal enabledelayedexpansion&set tmp5=a b c de f
for %%5 in (!tmp5!) do (
set tmp4=!tmp5:%%5 =!
for %%4 in (!tmp4!) do (
set tmp3=!tmp4:%%4 =!
for %%3 in (!tmp3!) do (
set tmp2=!tmp3:%%3 =!
for %%2 in (!tmp2!) do (
set tmp1=!tmp2:%%2 =!
for /f "delims=" %%1 in ("!tmp1:%%2=!") do (
echo %%5 %%4 %%3 %%2 %%1
)
)
)
)
)
pause

复制代码

很明显是最土的办法...只是我改进思路后，在执行之前可以自动定义层数，然后用一个变量存储了整个for嵌套，实际运行的代码就是这样子：

@echo off&setlocal enabledelayedexpansion&set tmp5=a b c de f
for %%5 in (!tmp5!) do ((set tmp4=!tmp5:%%5 =!)&for %%4 in (!tmp4!) do ((set tmp3=!tmp4:%%4 =!)&for %%3 in (!tmp3!) do ((set tmp2=!tmp3:%%3 =!)&for %%2 in (!tmp2!) do ((set tmp1=!tmp2:%%2 =!)&for /f "delims=" %%1 in ("!tmp1:%%2=!") do echo %%5 %%4 %%3 %%2 %%1 ))))
pause

复制代码

CrLf · 发表于 2011-5-21 21:31:13

噢，发现27楼代码就是6楼代码，只是21楼代码是对这种思路的改进

wankoilz · 发表于 2011-5-22 09:02:29

本帖最后由 wankoilz 于 2011-5-22 09:03 编辑

我是用的字符插入法，呵呵。
楼上构造for嵌套虽然不错，但效率还是不及20楼。
把21楼代码的%for%改成(%for%)>a.txt，且去掉for中的set/a z+=1 之后效率有所提升，测试8个字符40320个组合耗时近8秒。

plp626 · 发表于 2011-5-22 09:39:54

要速度就不能call，那么6楼的思路是最快的，

为了短小，我们可以构造一个“制造函数的函数”来制造6楼那个代码，从而支持可变字符个数的排列

16楼和21楼的思路就是如此。。。

		自动登录	找回密码
密码			注册

[新手上路]批处理新手入门导读	[视频教程]批处理基础视频教程	[视频教程]VBS基础视频教程	[批处理精品]批处理版照片整理器
[批处理精品]纯批处理备份&还原驱动	[批处理精品]CMD命令50条不能说的秘密	[在线下载]第三方命令行工具	[在线帮助]VBScript / JScript 在线参考

【练习-020】批处理根据输入列出组合

来个另类的

评分

回复 17楼的帖子

浏览过的版块

【练习-020】批处理根据输入列出组合

来个另类的

评分

回复 17楼 的帖子

浏览过的版块

回复 17楼的帖子