[文本处理] 批处理获取汉英混合字符串的字节

BatHome

批处理简单获取字符串的字节数

::获取字符串的字节数
::code by youxi01@cmd_xp
@echo off
setlocal enabledelayedexpansion
if "%1"=="" goto :help
call :test "%~1"
echo %1的字节有：%len%
pause>nul

:test
set "var=%~1"
for /l %%i in (0 1 200) do (
   set "var_=!var:~%%i,1!"
   if "!var_!"=="" goto :eof
   if !var_! gtr Z (set /a len+=2) else set /a len+=1
)
goto :eof

:help
echo.&echo ==========================求字符串的字节数=================
echo [使用格式]    %~nx0 "字符串"
echo [使用示例]    %~nx0 "好人123"
echo ============================--------=================================
cmd /k
复制代码

随风

如何删除本帖?

[此贴子已经被作者于2007-10-26 14:03:11编辑过]

somebody

呵呵，这代码怎么看啊```
再说，这代码有不准确的地方...判断不了全角字符..

youxi01

呵呵，虽然判断不了 全角字符，但是对于普通的 汉字 和 E文却可以“识别”
当写一些简单的程序的时候（如，曾经写过的，进程端口查询，在那个里面，这个就有大作用了，呵呵，PS：个人喜欢程序的整体性，能用一个批处理完成的，就会尽量用一个批处理文件完成...)

keen

修正字符串大于200后；修正连续使用本程序两次以上，len值计算错误，主要没有进行len变量清零。
修正楼主的代码：

::获取字符串的字节数
::code by youxi01@cmd_xp
@echo off
if "%1"=="/?" goto help
if "%1"=="" goto :help
call :test "%~1"
echo %1的字节有：%len%

:test
set "var=%~1"&set len=0
:lp
set "var1=%var:~0,1%"
if %var1% gtr Z (set /a len+=2) else set /a len+=1
set "var=%var:~1%"
if defined var goto lp
goto :eof

:help
echo.&echo ==========================求字符串的字节数=================
echo [使用格式]    %~nx0 "字符串"
echo [使用示例]    %~nx0 "好人123"
echo ============================--------=================================
cmd /k
复制代码

defanive

这样岂不是更好？

::获取字符串的字节数
::code by Defanive
@echo off
setlocal enabledelayedexpansion
if "%1"=="" goto :help
call :test "%~1"
echo %1的字节有：%len%
pause>nul

:test
echo."%~1">"%temp%\lb.tmp"
for /f %%a in ("%temp%\lb.tmp") do set /a len=%%~za-4
del /f /q "%temp%\lb.tmp"
goto :eof

:help
echo.&echo ==========================求字符串的字节数=================
echo [使用格式]    %~nx0 "字符串"
echo [使用示例]    %~nx0 "好人123"
echo ============================--------=================================
cmd /k
复制代码

plp626

切换到chcp 437代码页下，一个中文字符成了两个字符；求字节数等价于求字符个数，用strlen函数

话说，这么久了，我们才意识到代码页的本质，计算机基础知识甚是贫乏。