[挑战] 批处理寻找所有条件里相同的数字

flyinspace

假设有如下数字：

2190717
219117
2199817
2190517
2191417
21921917

为了大量数据统计的需要，我用一句话生成类似的数据
for /l %%i in (1,1,100) do echo 219%%i17>>1.txt

在这堆数据里，都有 219 的前缀和 17 的后缀，而中间的数据是随机的。

现在，我们的题目来了：
       利用批处理，找出 219 的前缀 和  17 的后缀，并将去掉后的结果输出到2.txt

输出的结果类似：
1
2
3
……
100

      前提：219 和 17在题目中是未知的，所以我们需要找出这2个未知的数据。。（这也是这里的难点）

pusofalse

有意思的题目，好好想想。。。

batman

写了个删除前缀的（后缀亦然），效率不怎么高：

@echo off&setlocal enabledelayedexpansion
set /p str=<1.txt
:lp
for /f "delims=" %%i in ('findstr "%var%%str:~,1%" 1.txt') do set /a n+=1
if not defined num set "num=%n%"
if "%n%" equ "%num%" (
   set "var=%var%%str:~,1%"&set "str=%str:~1%"
   set "n=0"&goto lp
)
for /f "delims=" %%i in (1.txt) do (
    set "str=%%i"
    echo !str:%var%=!
)
pause>nul
复制代码

pusofalse

@echo off&setlocal enabledelayedexpansion
set /p str=<a.txt
set /a n=-1
:loop
set/a n+=1
for /f "delims=" %%a in (a.txt) do (
     set "var=%%a"
     if "!var:~%n%,1!" neq "!str:~%n%,1!" set "x=%n%"
     set "str=%%a"
)
if not defined x goto loop
for /f "delims=" %%i in (a.txt) do (
     set "var=%%i"
     echo !var:~%x%!
)
pause
复制代码

也来一个，同样只是去掉前缀。输出结果跟batman版主的代码有点出入。

batman

思维定向了，一直想先把前缀提出来，pusofalse版主的代码证明了并不要提出来。

pusofalse

再修改下，能正确输出1，2，3、、、、100。

@echo off&setlocal enabledelayedexpansion
cd.>a.txt
set/a r=%random%,d=!random!,n=-1
for /l %%a in (1 1 100) do set "_!random!!random!=%r%%%a%d%"
for /f "tokens=2 delims==" %%i in ('set _') do echo>>a.txt %%i
set /p str=<a.txt
:loop
set/a n+=1,m+=1
for /f "delims=" %%a in (a.txt) do (
     set "var=%%a"
     if "!var:~%n%,1!" neq "!str:~%n%,1!" if not defined x set "x=%n%"
     if "!var:~-%m%,1!" neq "!str:~-%m%,1!" if not defined y set "y=%m%"
     set "str=%%a"
)
for %%a in (x y) do if not defined %%a goto loop
set/a y-=1
for /f "delims=" %%i in (a.txt) do (
     set "var=%%i"
     echo !var:~%x%,-%y%!
)
pause>nul
复制代码

[ 本帖最后由 pusofalse 于 2008-10-17 18:28 编辑 ]

youxi01

我在思考一个问题，或者询问楼主：
在这里，究竟是人工识别前缀还是要求自动识别？

flyinspace

原帖由 youxi01 于 2008-10-17 19:16 发表
我在思考一个问题，或者询问楼主：
在这里，究竟是人工识别前缀还是要求自动识别？

当然是自动识别前缀和后缀来呀。。

若是人工识别，这个题目就没有难度了。。

这个是对字符串知识的一次总结。。

随风

:

@echo off&setlocal enabledelayedexpansion
set /p var=<a.txt
set q=%var:~0,1%
set h=%var:~-1%
for /f "delims=:" %%a in ('findstr /n "." a.txt') do set /a z=%%a
:loop
for /f "delims=:" %%a in ('findstr /n "^%q%" a.txt') do set /a x=%%a
if %x% equ %z% (
   set /a m+=1
   set "q=!q!!var:~1,1!"
   set "var=!var:~1!"
   goto loop
)
:loop2
for /f "delims=:" %%a in ('findstr /n "%h%$" a.txt') do set /a x=%%a
if %x% equ %z% (
   set /a j+=1&set var=!var:~0,-1!
   set h=!var:~-1,1!!h!
   goto loop2
)
for /f "delims=" %%a in (a.txt) do (
   set "str=%%a"
   echo !str:~%m%,-%j%!
)
pause
复制代码

namejm

　　既然前缀和后缀是未知的，又怎么找得出来呢？楼主提供的条件让人不解，难道是说，如果前缀和后缀重复的次数达到一定次数之后，就要把这些数据过滤掉？

zqz0012005

和JM有相同的疑问，假如有下面的数据：
2190717
2190117
2190117
2193117
2191117
这要比较很多组才能判断出正确的前缀和后缀吧？效率很难保证

youxi01

同楼上
个人感觉，在这方面，机器的效率还是比不上人脑的

batman

我觉得楼主的意思还是表明清楚了，这个每行的前缀和后缀也是能通过程度自动判断出来
的，但用纯批处理来完成这样一个过程必定存在效率问题，因为用批肯定是要进行逐字符
判断的，当遇到大型的文本时，这样的处理将会慢得不可形容。所以，这样的题目其实际
价值并不会太大。。。

namejm

　　楼主的意思并没有表明清楚，因为楼主并没有说清楚什么样的字符串才算前缀，什么样的字符串才算后缀，既然前缀后缀的含义都没有交代清楚，又怎么能让程序判断哪些是前缀哪些是后缀呢——楼主已经注明了，219和17仅仅是举例，它们是未知的，是需要通过程序来判断，这是问题的关键。

wxcute

@echo off
setlocal enabledelayedexpansion
call :loop n-1 fx
call :loop -n lx
set/a fx=fx,lx=lx+1
for /f "delims=" %%i in (1.txt) do (
     set "var=%%i"
     echo !var:~%fx%,%lx%!
)
pause
goto :eof
:loop
set/a n+=1
set/a m=%1
for /f "delims=" %%a in (1.txt) do (
     set "var=%%a"
     if not "!str!"=="" if not "!str:~%m%,1!"=="!var:~%m%,1!" set "%2=%m%"
     set "str=%%a"
)
if not defined %2 goto loop
set n=
复制代码