[系统相关] [代码征集]批处理dll文件备份

youxi01

随着系统的运行，系统文件夹中的dll文件越来越多,很多病毒也"混水摸鱼",藏身其中.....

本代码需要完成的功能:
1、每天可以将dll文件的信息备份成一个列表，主要包括文件名，修改时间；
2、能够将新生成的dll文件与“标准dll文件列表（如无，代码初次运行时，自动将第一次运行结果作为标准dll文件表）”对比，找出其中的不同点；
3、可以选择是否以当前dll文件列表覆盖原来的dll文件列表文件

随风

应该是指的 windows\system32  目录下的吧?
不知道要不要子目录里的?

随风

我来抛砖
只备份C:\WINDOWS\system32下的dll和exe文件列表，不含子目录
:

@echo off&setlocal enabledelayedexpansion
for /l %%i in (1 1 40) do set "k40= !k40!"
set ml=C:\WINDOWS\system32&set "butong=!ml!\于标准文件不同的文件列表.txt"
set biaozu=%ml%\标准dll文件列表.txt&set "duibi=%ml%\新dll文件列表.txt"
if not exist "%biaozu%" (set wjm=%biaozu%) else (set wjm=%duibi%)
for %%i in ("%ml%\*.dll" "%ml%\*.exe") do (
  set str=%%i%k40%
  echo !str:~0,40! %%~ti>>%wjm%
)
if exist %duibi% (
for /f "tokens=1,2* delims=:" %%i in (%biaozu%) do set "%%i%%j%%k=a"
for /f "tokens=1,2* delims=:" %%i in (%duibi%) do (
   if not "!%%i%%j%%k!"=="a" (
     set you=bb&echo %%i:%%j:%%k
  echo %%i:%%j:%%k>>%butong%
))) else (echo\&echo %biaozu% 已经建立&echo\&pause&exit)
if defined you (
   echo\&echo 以上是于 %biaozu% 不同的文件
   echo\&echo 并以写入到%butong%中.
)
echo\
echo  请选择是否将新建的dll文件列表,覆盖原来的“标准dll文件列表”.
echo\&set /p xuan= [ 覆盖 y ，不覆盖 n ] 
if /i "!xuan!"=="y" (
  del/q "%biaozu%"
  ren "%wjm%" "标准dll文件列表.txt"
) else (del/q "%wjm%")
if defined you start "" "%butong%"
复制代码

[ 本帖最后由 随风 于 2007-12-7 14:55 编辑 ]