[分享]PotPlayer一键下载提取的批处理

327025010

在此先感谢群里给为帮助，已经完成应该有很多不足，望提出，非常感谢各位的指教。

目录下有个Bin文件夹内有
7z
7z.dll
md5
wget

附件大小限制，丢到卡饭一份
http://bbs.kafan.cn/forum.php?mod=viewthread&tid=1768682&page=1&extra=#pid32540523

@Echo off & cd %~dp0
:MenuA
Set Select=Error
Cls & Color 07
Echo.
Echo.┏	[1] Potplayer Dev 测试版
Echo.┃
Echo.┣	[2] Potplayer Public 正式版
Echo.┃
Echo.┣	[*] 清理下载文件夹	[回车] 查看文件夹
Echo.┃
Echo.┃
Set /p Select=┗	选项%Error% ：
Set Error=
	IF /I %Select%==1 Set Version=Dev&Goto MenuB
	IF /I %Select%==2 Set Version=Public&Goto MenuB
	IF /I %Select%==* Rd /s /q "Temp" & Cls Goto MenuA

	IF /I %Select%==Error (
	Color 07 & Cls & Start Versions & Goto MenuA
	)
	Cls & Set Error=（重新输入） & Goto MenuA

:MenuB
Set Select=Error
Cls & Color 07
Echo.
Echo.┏	[1] 常用解码组件
Echo.┃
Echo.┣	[2] 额外解码组件
Echo.┃
Echo.┃
Set /p Select=┗	选项%Error%：
Set Error=
	IF /I %Select%==1 Set Decoder=Common&Goto Potplayer
	IF /I %Select%==2 Set Decoder=Extra&Goto Potplayer

	IF /I %Select%==Error (
	Cls & Set Error=（重新输入） & Goto MenuB
	)
	Cls & Set Error=（重新输入） & Goto MenuB

:Potplayer
Call :Count
Set VersionShow=PotPlayer %VersionDate% %Decoder% 任务完成。
Set Download=%Version%%Decoder%
IF EXIST "Temp\PotPlayerSetup.exe" (Move Temp\PotPlayerSetup.exe Temp\PotPlayer%Version%.exe)
IF EXIST "Temp\PotPlayer%Version%.exe" (
	IF EXIST "Temp\PotPlayer%Version%" (
		IF /I "%MD5A%"=="%MD5B%" (
			IF EXIST "Versions\PotPlayer %Version% %VersionDate% %Decoder%.7z" (
				Set VersionShow=PotPlayer %VersionDate% %Decoder% 已存在未执行任何操作。
				Color 0C
				Goto End
			) ELSE (Goto Compression)
		) ELSE (Goto Compression)
	) ELSE (
	Call :7z
	Goto Potplayer
	)
) ELSE (
	IF /I %Download%==DevCommon (
		Cls
		Echo.
		Echo. 1-1 测试版更新已启动（常用解码组件）
		Echo.
		Bin\wget -P Temp "http://get.daum.net/PotPlayer/Beta/PotPlayerSetup.exe"
		Bin\wget -P Temp "http://get.daum.net/PotPlayer/v2/Module/FFmpeg/FFmpegMininum.dll"
	)
	IF /I %Download%==DevExtra (
		Cls
		Echo.
		Echo. 1-2 测试版更新已启动（额外解码组件）
		Echo.
		Bin\wget -P Temp "http://get.daum.net/PotPlayer/Beta/PotPlayerSetup.exe"
		Bin\wget -P Temp "http://get.daum.net/PotPlayer/Codec/OpenCodecSetup.exe"
	)
	IF /I %Download%==PublicCommon (
		Cls
		Echo.
		Echo. 2-1 正式版更新已启动（常用解码组件）
		Echo.
		Bin\wget -P Temp "http://get.daum.net/PotPlayer/v2/PotPlayerSetup.exe"
		Bin\wget -P Temp "http://get.daum.net/PotPlayer/v2/Module/FFmpeg/FFmpegMininum.dll"
	)
	IF /I %Download%==PublicExtra (
		Cls
		Echo.
		Echo. 2-2 正式版更新已启动（额外解码组件）
		Echo.
		Bin\wget -P Temp "http://get.daum.net/PotPlayer/v2/PotPlayerSetup.exe"
		Bin\wget -P Temp "http://get.daum.net/PotPlayer/Codec/OpenCodecSetup.exe"
	)
	Move Temp\PotPlayerSetup.exe Temp\PotPlayer%Version%.exe
	Call :7z
	Goto Potplayer
)

:Count
	Findstr /I "[" "Temp\PotPlayer%Version%\History\Chinese(SimplIFied).txt" > "Temp\History" 2>Nul
	(FOR /l %%a in (1 1 1) do Set /P Examine1=)<"Temp\History"
	(FOR /l %%a in (1 1 2) do Set /P Examine2=)<"Temp\History"
		Set VersionDate=%Examine1: =%
		Set VersionDate=%VersionDate:/=%
		Set VersionDate=%VersionDate:~13,6%
		Set VersionCount=%Examine1: =%
		Set VersionCount=%VersionCount:~0,11%
		Set VersionDatePublic=%Examine2: =%
		Set VersionDatePublic=%VersionDatePublic:~0,11%
		Set VersionCountPublic=%Examine2: =%
		Set VersionCountPublic=%VersionCountPublic:/=%
		Set VersionCountPublic=%VersionCountPublic:~13,6%
	Bin\MD5 -n Temp\PotPlayer%Version%.exe > Temp\MD5
	(FOR /l %%a in (1 1 1) DO Set /P MD5A=)< Temp\MD5
	Bin\MD5 -n "Versions\PotPlayer %Version% %VersionDate%.exe" > Temp\MD5
	(FOR /l %%a in (1 1 1) DO Set /P MD5B=)< Temp\MD5
	Goto :eof

:7z
	Call :Count
	Bin\7z x Temp\PotPlayer%Version%.exe -y -oTemp\PotPlayer%Version%
	Bin\7z x Temp\OpenCodecSetup.exe -y -oTemp\OpenCodecSetup
	Goto :eof

:Compression
	Call :Count
	RD /S /Q "Temp\PotPlayer"
	MD Temp\PotPlayer
	MD Temp\PotPlayer\Skins
	MD Temp\PotPlayer\IconPack
		Copy Temp\PotPlayer%Version%\ATextOut.dll Temp\PotPlayer
		Copy Temp\PotPlayer%Version%\CMDLine.txt Temp\PotPlayer
		Copy Temp\PotPlayer%Version%\D3DCompiler_43.dll Temp\PotPlayer
		Copy Temp\PotPlayer%Version%\d3dx9_43.dll Temp\PotPlayer
		Copy Temp\PotPlayer%Version%\DesktopHook.dll Temp\PotPlayer
		Copy Temp\PotPlayer%Version%\DesktopHook64.dll Temp\PotPlayer
		Copy Temp\PotPlayer%Version%\DesktopHook64.exe Temp\PotPlayer
		Copy Temp\PotPlayer%Version%\DTDrop.exe Temp\PotPlayer
		Copy Temp\PotPlayer%Version%\ffcodec.dll Temp\PotPlayer
		Copy Temp\PotPlayer%Version%\GameCaptureHook.dll Temp\PotPlayer
		Copy Temp\PotPlayer%Version%\GameCaptureHook64.dll Temp\PotPlayer
		Copy Temp\PotPlayer%Version%\License.txt Temp\PotPlayer
		Copy Temp\PotPlayer%Version%\PotPlayer.dll Temp\PotPlayer
		Copy Temp\PotPlayer%Version%\PotIcons.dll Temp\PotPlayer
		Copy Temp\PotPlayer%Version%\PotPlayerMini.exe Temp\PotPlayer
		Copy Temp\PotPlayer%Version%\PotPlayerMiniXP.exe Temp\PotPlayer

	MD Temp\PotPlayer\AviSynth
		Xcopy /E /Y Temp\PotPlayer%Version%\AviSynth Temp\PotPlayer\AviSynth

	MD Temp\PotPlayer\PxShader
		Xcopy /E /Y Temp\PotPlayer%Version%\PxShader Temp\PotPlayer\PxShader

	MD Temp\PotPlayer\History
		Copy Temp\PotPlayer%Version%\History\English.txt Temp\PotPlayer\History
		Copy Temp\PotPlayer%Version%\History\Chinese(Simplified).txt Temp\PotPlayer\History

	MD Temp\PotPlayer\Language
		Copy Temp\PotPlayer%Version%\Language\English.ini Temp\PotPlayer\Language
		Copy Temp\PotPlayer%Version%\Language\Chinese(Simplified).ini Temp\PotPlayer\Language

	MD Temp\PotPlayer\Module
		Copy Temp\PotPlayer%Version%\Module\qscl.dll Temp\PotPlayer\Module
		Copy Temp\PotPlayer%Version%\Module\MediaInfo.dll Temp\PotPlayer\Module
		Copy Temp\PotPlayer%Version%\Module\QuickSync.dll Temp\PotPlayer\Module
		Copy Temp\PotPlayer%Version%\Module\tak_deco_lib.dll Temp\PotPlayer\Module

	MD Temp\PotPlayer\Module\Bass
		Xcopy /E /Y Temp\PotPlayer%Version%\Module\Bass Temp\PotPlayer\Module\Bass

	MD Temp\PotPlayer\Module\FFmpeg

		IF /I %Decoder%==Common (
		Copy Temp\FFmpegMininum.dll Temp\PotPlayer\Module\FFmpeg
		Copy Temp\OpenCodecSetup\Module\FFmpeg\FFmpegMininum.dll Temp\PotPlayer\Module\FFmpeg
		)

		IF /I %Decoder%==Extra (
			IF EXIST "Temp\OpenCodecSetup.exe" (
				IF NOT EXIST "Temp\OpenCodecSetup" (Call :7z)
			) ELSE (
			Cls
			Echo.
			Echo. 未发现额外解码组件 正在下载。
			Echo.
			Bin\wget -P Temp "http://get.daum.net/PotPlayer/Codec/OpenCodecSetup.exe"
			Call :7z
			)
		Xcopy /E /Y Temp\OpenCodecSetup\Module Temp\PotPlayer\Module
		)

	MD Temp\PotPlayer\Module\RealCodec
		Xcopy /E /Y Temp\PotPlayer%Version%\Module\RealCodec Temp\PotPlayer\Module\RealCodec

	MD Versions
	Copy "Temp\PotPlayer%Version%.exe" "Versions\PotPlayer %Version% %VersionDate%.exe"
	Bin\7z a -t7z "Versions\PotPlayer %Version% %VersionDate% %Decoder%.7z" ".\Temp\*PotPlayer\" -mx=9 -mmt

:End
	Call :Count
	Cls
	IF Exist "Versions\PotPlayer Public %VersionCountPublic%.exe" (Set PublicExamine=已存在，无需更新。) Else (Set PublicExamine=不存在，可以更新。)

	IF /I %Version%==Dev (
	Echo.
	Echo.┏	测试版 %VersionCount% %VersionShow%
	Echo.┃
	Echo.┣	正式版 %VersionDatePublic% Potplayer %VersionCountPublic% %PublicExamine%
	Echo.┃
	Echo.┣	正式版判断是由《版本更新信息》生成，绝大多数时候正确。
	Echo.┃
	Echo.┗	任意键返回主菜单
	)

	IF /I %Version%==Public (
	Echo.
	Echo.┏	正式版 %VersionCount% %VersionShow%
	Echo.┃
	Echo.┗	任意键返回主菜单
	)
	Echo.							Common	常用解码组件
	Echo.							Extra	额外解码组件
Pause >Nul & Cls & Goto MenuA
复制代码